实体类自动生成Swagger@ApiModelProperty(“$1“)注解

情况1 : 还未生成的实体类

可以修改Generate POJOs.groovy  达到实体类加@ApiModelProperty注解的效果

不会使用Generate POJOs.groovy 的可以去百度下很多文章有详细图解。

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.leader.park.common.core.domain.entity"   // 此处指定包路径，也就对应实体类中的package com.topex.admin.entity;
typeMapping = [    // 此处指定对应的类型映射，如下：数据库中bigint对应生成java的Long，int|tinyint生成Integer...
                   (~/(?i)bigint/)                      : "Long",
                   (~/(?i)int|tinyint/)                 : "Integer",
                   (~/(?i)float|double|decimal|real/): "java.math.BigDecimal",
                   (~/(?i)date|datetime|timestamp/)       : "java.util.Date",
                   (~/(?i)time/)                     : "java.sql.Time",
                   (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    new PrintWriter(new OutputStreamWriter(new FileOutputStream( new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields) }
}

def generate(out, className, fields) {   
    out.println "package $packageName"
    out.println ""
    out.println ""
    out.println "import lombok.Data;"     // 因为我使用了lombok插件，使用到了Data注解，所以在引包时加了这一行
    out.println "import io.swagger.annotations.ApiModelProperty;"   // 同上，使用了swagger文档，所以引入到需要的注解
    out.println ""
    out.println "@Data"
    out.println "public class $className {"
    out.println ""
    int i = 0
    fields.each() {   // 遍历字段，按下面的规则生成
        // 输出注释，这里唯一的是id特殊判断了一下，如果判断it.name == id, 则多添加一行@Id
        if (it.name == "id") {
            if (!isNotEmpty(it.commoent)) {
                out.println "\t/**"
                out.println "\t * 主键id"
                out.println "\t */"
                out.println "\t@ApiModelProperty(value = \"主键id\", position = ${i})"
            }
            out.println "\t@Id"
        }
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent}"
            out.println "\t */"
            out.println "\t@ApiModelProperty(value = \"${it.commoent}\", position = ${i})"
        }
        if (it.annos != "") out.println "  ${it.annos}"
        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
        i++
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        fields += [[
                           name : javaName(col.getName(), false),
                           type : typeStr,
                           commoent: col.getComment(),
                           annos: ""]]
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

情况2 : 项目实体类已创建不好重建的时候 可以使用工具 swagger tools

File-Settings-Pluginss输入：swagger tools下载重启idea

快捷键实体类Alt+insert，选择SwaggerAnnotation即可一键生成@ApiModelProperty

 swagger tools支持三种注释情况如下：

 

 

 情况3 : 项目实体类注释很简单是一行 无法使用swagger tools

如下：

/** 部门ID */
private Long deptId;

解决方法可使用正则表达式全部替换

快捷键ctrl+r弹出替换代码功能，选中Regex（此项为使用正则表达式功能）

\/\*\*([^\n]*)\*\/       @ApiModelProperty("$1")