自定义功能区IRibbonUI对象丢失的处理办法

问题描述

在自定义功能区时，当定义的功能区按钮运行宏被中断时，会发生功能区IRibbonUI对象丢失，从而导致自定义的功能区按钮失效报错或者功能区不能正常刷新。
我刚开始接触设计自定义功能区时，遇到这种情况让我很是头疼，我起初都不知道发生了什么，为什么会报错，后来经过反复的尝试搜索关键词及反复调试，终于找到问题所在。
但是解决问题也是让人头疼的一件事情，后来偶然搜到一贴，让我找到了一种全新的思路，作为一个非科班出身的我，大概花费了两个周左右的事件琢磨这个问题（因为在上班，只能抽一些琐碎时间来做这些），以下是我解决这个问题的思路及具体方法。

解决思路

利用指针（虽然我模糊的记得大学VC课程有讲过这个概念，但是我真的清除这是个什么东西以及他的原理），将功能区初始时的IRibbonUI对象存储起来，当变量丢失时，再将其从指针中取出并赋值给相应变量

我所用的详细代码

以下时功能区设计的示例代码，是利用软件Office RibbonX Editor编写的

<!--  利用Office RibbonX Editor编写的功能区代码，其中功能区加载时回调需要设置属性 onLoad="onLoad_name"  -->
<customUI xmlns="http://schemas.microsoft.com/office/2009/07/customui" onLoad = "onLoad_name">
	<ribbon>
	<tabs>
   
    <tab idMso="TabHome"> 
        <group idMso="GroupCells"> 
            <button idMso="InserCellstMenu" enabled="false" />
            <button idMso="TableDeleteRowsAndColumnsMenu" enabled="false" />
        </group>
    </tab>
    
	</tabs>
	</ribbon>
</customUI>

以下是功能区IRibbonUI对象存储到指针，并在对象丢失时提取指针的方法

Option Explicit

Public rbUI As IRibbonUI    '声明功能区Ribbon对象
Public Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByRef destination As Any, ByRef source As Any, ByVal length As Long)
'↑ 声明指针变量

'*** 功能区加载时回调属性OnLoad ，需要再利用Office RibbonX Editor中设置对应的初始化语句
'*** 以下代码在打开文件时，会保存 ribbon 对象变量到指针中
'Callback for customUI.onLoad
    Sub onLoad(Ribbon As IRibbonUI)
        Set rbUI = Ribbon     '设置Ribbon变量
        SaveSetting "CustomeUI", ThisWorkbook.Name, "RibbonPointer", ObjPtr(Ribbon) '指针写入注册表中
    End Sub

'*** 当功能区 IRibbonUI对象丢失时，调用以下过程从指针中获取  IRibbonUI对象
    Function GetRibbon() As Object
        'If Not rbUI Is Nothing Then Set GetRibbon = rbUI: Exit Function       '如果功能区对象不是空值，那么跳出过程
        Dim objRibbon As Object
        Dim lngRibPointer As LongPtr
        lngRibPointer = GetSetting("CustomeUI", ThisWorkbook.Name, "RibbonPointer") '从注册表找到指针位置
        CopyMemory objRibbon, lngRibPointer, LenB(lngRibPointer)            '将指针内容复制给变量 objRibbon
        Set GetRibbon = objRibbon                           '将指针内容复制给参数 GetRibbon
        Set objRibbon = Nothing
    End Function
    
'在需要刷新功能区时，调用以下过程进行功能区刷新
    Sub UpRibbon()
        Application.ScreenUpdating = False
        If rbUI Is Nothing Then Set rbUI = GetRibbon    'if rbUI丢失，调用参数GetRibbon，从注册表中提取功能区数据
        rbUI.Invalidate                   '刷新功能区
        Application.ScreenUpdating = True
    End Sub
    
'*** 删除Ribbon对象的指针 '关闭文件时，调用此程序删除指针
    Sub DeleteOnjPtr()
      On Error Resume Next
      DeleteSetting "CustomeUI", ThisWorkbook.Name
    End Sub