02.01.04.tiptop：组件篇（4fd+4gl 新增：查询+输入框 hard-code方式）

已于 2024-02-03 21:19:07 修改
阅读量531 收藏 10
点赞数 15
分类专栏： 鼎捷tiptop 5.3 文章标签： 开发语言
于 2024-02-01 11:49:40 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_26730689/article/details/135970618
版权

本页目录：

  • 1、开窗查询程序
  • 2、配置
  • 3、测试

开窗查询程序

画面档

  • q_apa10.4fd
<?xml version="1.0" encoding="UTF-8" ?>
<ManagedForm databaseName="ds" gstVersion="22800" name="Root" uid="{d773f83d-0000-4000-9784-d57674278765}">
  <AGSettings/>
  <Record additionalTables="" joinLeft="" joinOperator="" joinRight="" name="s_apy" order="" uid="{e5fa620e-0000-4000-893a-f6ac57956817}" where="">
    <RecordField colName="" fieldIdRef="1" name="check" sqlTabName="" table_alias_name="" uid="{f8218c5c-0000-4000-a478-dfc71f3e3377}"/>
    <RecordField colName="apyslip" fieldIdRef="2" fieldType="NON_DATABASE" name="one" sqlTabName="apy_file" sqlType="VARCHAR" table_alias_name="" uid="{561af4fa-0000-4000-afa5-b84165a61ea8}"/>
  </Record>
  <Form gridHeight="11" gridWidth="22" name="q_apy" spacing="normal" text="Qry Document Type">
    <Grid gridHeight="11" gridWidth="22" lstrcomment="false" name="gr3730" posX="0" posY="0">
      <Table gridHeight="11" gridWidth="20" lstrcomment="false" name="s_apy" posX="1" posY="0" totalRows="10">
        <CheckBox aggregateColName="" aggregateName="" aggregateTableAliasName="" aggregateTableName="" colName="" fieldId="1" gridHeight="1" gridWidth="6" lstrcomment="false" lstrtext="false" lstrtitle="false" name="check" notNull="true" posX="0" posY="0" required="true" sqlTabName="" sqlType="CHAR" tabIndex="1" table_alias_name="" title="Sel" valueChecked="Y" valueUnchecked="N" widget="CheckBox"/>
        <Edit aggregateColName="" aggregateName="" aggregateTableAliasName="" aggregateTableName="" colName="apyslip" fieldId="2" fieldType="NON_DATABASE" gridHeight="1" gridWidth="11" length="1" lstrcomment="false" lstrtitle="false" name="one" noEntry="true" posX="6" posY="0" sqlTabName="apy_file" sqlType="VARCHAR" tabIndex="2" table_alias_name="" title="Document" widget="Edit"/>
      </Table>
    </Grid>
  </Form>
  <DiagramLayout>
    <![CDATA[AAAAAgAAAEwAewA1ADYAMQBhAGYANABmAGEALQAwADAAMAAwAC0ANAAwADAAMAAtAGEAZgBhADUALQBiADgANAAxADYANQBhADYAMQBlAGEAOAB9QCQAAAAAAABATYAAAAAAAAAAAAAAAAAAAQAAAEwAewBlADUAZgBhADYAMgAwAGUALQAwADAAMAAwAC0ANAAwADAAMAAtADgAOQAzAGEALQBmADYAYQBjADUANwA5ADUANgA4ADEANwB9AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAQAAAEwAewBmADgAMgAxADgAYwA1AGMALQAwADAAMAAwAC0ANAAwADAAMAAtAGEANAA3ADgALQBkAGYAYwA3ADEAZgAzAGUAMwAzADcANwB9QCQAAAAAAABAQoAAAAAAAAAAAAAAAAAAAQ==]]>
  </DiagramLayout>
</ManagedForm>

# 注意：输入框带搜索按钮主要参数是：
  - widget:buttonedit
  - image type:select file
  - image:zoom
  - action:CONTROLP
  • 放到：/u1/topprod/tiptop/qry/4fd
# 使用sftp
cd /u1/topprod/tiptop/qry/4fd
put q_apa10.4fd
# 使用ssh
cd /u1/topprod/tiptop/qry/4fd
r.f2 q_apa10 2 c

后台程序

  • q_apa10.4gl
收展 
# Program name  : q_apa10.4gl
# Description   : 單據彈頭第一個字母查詢
# Date & Author : 2023/05/24 DKLi 2665252078@qq.com
# 調用：q_apa10(TRUE, FALSE) 第一個參數是true是復選，是false是單選
DATABASE ds
 
GLOBALS "../../config/top.global"
 
DEFINE   ma_qry   DYNAMIC ARRAY OF RECORD
         check    LIKE type_file.chr1,
         apyslip  LIKE apy_file.apyslip
END RECORD
DEFINE   ma_qry_tmp   DYNAMIC ARRAY OF RECORD
         check        LIKE type_file.chr1,
         apyslip      LIKE apy_file.apyslip
END RECORD
 
DEFINE   mi_multi_sel     LIKE type_file.num5     #是否需要複選資料(TRUE/FALSE).
DEFINE   mi_need_cons     LIKE type_file.num5     #是否需要CONSTRUCT(TRUE/FALSE).
DEFINE   ms_cons_where    STRING     #暫存CONSTRUCT區塊的WHERE條件.
DEFINE   mi_page_count    LIKE type_file.num10     #每頁顯現資料筆數.
DEFINE   ms_ret1          STRING
 
FUNCTION q_apa10(pi_multi_sel,pi_need_cons)
   DEFINE   pi_multi_sel   LIKE type_file.num5,
            pi_need_cons   LIKE type_file.num5
 
   WHENEVER ERROR CALL cl_err_msg_log
 
   OPEN WINDOW w_qry WITH FORM "qry/42f/q_apa10" ATTRIBUTE(STYLE="create_qry")
 
   CALL cl_ui_locale("q_apa10")
 
   LET mi_multi_sel = pi_multi_sel
   LET mi_need_cons = pi_need_cons
 
   IF NOT (mi_multi_sel) THEN
      CALL cl_set_comp_visible("check",FALSE)
   END IF

   IF (mi_multi_sel) THEN
      CALL cl_set_comp_font_color("apyslip", "red")
   END IF
 
   CALL apa10_qry_sel()
 
   CLOSE WINDOW w_qry
 
   IF (mi_multi_sel) THEN
      RETURN ms_ret1
   ELSE
      RETURN ms_ret1
   END IF
END FUNCTION
 
##################################################
# Description  	: 畫面顯現與資料的選擇.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: none
# Return   	: void
# Memo        	:
# Modify   	:
##################################################
FUNCTION apa10_qry_sel()
   DEFINE   ls_hide_act      STRING
   DEFINE   li_hide_page     LIKE type_file.num5,     #是否隱藏'上下頁'的按鈕.
            li_reconstruct   LIKE type_file.num5,     #是否重新CONSTRUCT.預設為TRUE.
            li_continue      LIKE type_file.num5      #是否繼續.
   DEFINE   li_start_index   LIKE type_file.num10, 
            li_end_index     LIKE type_file.num10
   DEFINE   li_curr_page     LIKE type_file.num5
   DEFINE   li_count         LIKE ze_file.ze03,
            li_page          LIKE ze_file.ze03
 
 
   LET mi_page_count = 100
   LET li_reconstruct = TRUE
 
   WHILE TRUE
      CLEAR FORM
 
      LET INT_FLAG = FALSE
      LET ls_hide_act = ""
 
      LET ms_cons_where = " 1=1"
      IF (li_reconstruct) THEN
         MESSAGE ""
 
         IF (mi_need_cons) THEN
            CONSTRUCT BY NAME ms_cons_where ON apyslip
 
            ON ACTION controlg
               CALL cl_cmdask()
 
            ON IDLE g_idle_seconds
               CALL cl_on_idle()
               CONTINUE CONSTRUCT
 
            ON ACTION about
               CALL cl_about()
 
            ON ACTION help
               CALL cl_show_help()
            END CONSTRUCT
 
            IF (INT_FLAG) THEN
               LET INT_FLAG = FALSE
               EXIT WHILE
            END IF
         END IF
 
         CALL apa10_qry_prep_result_set()
         # 2003/07/14 by Hiko : 如果沒有設定'每頁顯現資料筆數',則預設為所有資料一起顯現.
         IF (mi_page_count = 0) THEN
            LET mi_page_count = ma_qry.getLength()
         END IF
         # 2003/07/14 by Hiko : 如果所設定的'每頁顯現資料筆數'超過/等於所有資料,則要隱藏'上下頁'的按鈕.
         IF (mi_page_count >= ma_qry.getLength()) THEN
            LET ls_hide_act = "prevpage,nextpage"
         END IF

 
         LET li_start_index = 1
 
         LET li_reconstruct = FALSE
      END IF
 
      LET li_end_index = li_start_index + mi_page_count - 1
 
      IF (li_end_index > ma_qry.getLength()) THEN
         LET li_end_index = ma_qry.getLength()
      END IF
 
      CALL apa10_qry_set_display_data(li_start_index, li_end_index)
 
      LET li_curr_page = li_end_index / mi_page_count
 
      IF (li_end_index MOD mi_page_count) > 0 THEN
         LET li_curr_page = li_curr_page + 1
      END IF
 
      SELECT ze03 INTO li_count FROM ze_file WHERE ze01 = 'qry-001' AND ze02 = g_lang
      SELECT ze03 INTO li_page  FROM ze_file WHERE ze01 = 'qry-002' AND ze02 = g_lang
 
      MESSAGE li_count CLIPPED || " : " || ma_qry.getLength() || "  " || li_page CLIPPED || " : " || li_curr_page
 
      IF (mi_multi_sel) THEN
         CALL apa10_qry_input_array(ls_hide_act, li_start_index, li_end_index) RETURNING li_continue,li_reconstruct,li_start_index
      ELSE
         CALL apa10_qry_display_array(ls_hide_act, li_start_index, li_end_index) RETURNING li_continue,li_reconstruct,li_start_index
      END IF
 
      IF (NOT li_continue) THEN
         EXIT WHILE
      END IF
   END WHILE
END FUNCTION
 
##################################################
# Description  	: 準備查詢畫面的資料集.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: none
# Return        : void
# Memo        	:
# Modify        :
##################################################
FUNCTION apa10_qry_prep_result_set()
   DEFINE l_filter_cond STRING
   DEFINE   ls_sql   STRING,
            ls_where STRING
   DEFINE   li_i     LIKE type_file.num10
   DEFINE   lr_qry   RECORD
            check    LIKE type_file.chr1,
            apyslip  LIKE apy_file.apyslip
   END RECORD
 
 
   LET l_filter_cond = cl_get_extra_cond_for_qry('q_apa10', 'apy_file')
   IF NOT cl_null(l_filter_cond) THEN
      LET ms_cons_where = ms_cons_where,l_filter_cond
   END IF

   LET ls_sql = "SELECT 'N',substr(apa01,1,1) apyslip",
                " FROM apa_file ",
                " WHERE apaacti = 'Y' ",
                " AND apa42='N' ",
                " GROUP BY substr(apa01,1,1) ORDER BY substr(apa01,1,1)"
   DECLARE lcurs_qry CURSOR FROM ls_sql
 
   CALL ma_qry.clear()
 
   LET li_i = 1
 
   FOREACH lcurs_qry INTO lr_qry.*
      IF (SQLCA.SQLCODE) THEN
         CALL cl_err(ls_sql, SQLCA.SQLCODE, 1)
         EXIT FOREACH
      END IF

      LET ma_qry[li_i].* = lr_qry.*
      LET li_i = li_i + 1
   END FOREACH
END FUNCTION
 
##################################################
# Description  	: 設定查詢畫面的顯現資料.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: pi_start_index   LIKE type_file.num10    所要顯現的查詢資料起始位置
#               : pi_end_index     LIKE type_file.num10    所要顯現的查詢資料結束位置
# Return        : void
# Memo        	:
# Modify        :
##################################################
FUNCTION apa10_qry_set_display_data(pi_start_index, pi_end_index)
   DEFINE   pi_start_index   LIKE type_file.num10,
            pi_end_index     LIKE type_file.num10
   DEFINE   li_i             LIKE type_file.num10,
            li_j             LIKE type_file.num10
 
 
   CALL ma_qry_tmp.clear()
 
   FOR li_i = pi_start_index TO pi_end_index
      LET ma_qry_tmp[li_j+1].* = ma_qry[li_i].*
      LET li_j = li_j + 1
   END FOR
 
   CALL SET_COUNT(ma_qry_tmp.getLength())
 
END FUNCTION
 
##################################################
# Description  	: 採用INPUT ARRAY的方式來顯現查詢過後的資料.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: ps_hide_act      STRING    所要隱藏的Action Button
#               : pi_start_index   LIKE type_file.num10    所要顯現的查詢資料起始位置
#               : pi_end_index     LIKE type_file.num10    所要顯現的查詢資料結束位置
# Return   	: SMALLINT   是否繼續
#               : SMALLINT   是否重新查詢
#               : INTEGER    改變後的起始位置
# Memo        	:
# Modify   	:
##################################################
FUNCTION apa10_qry_input_array(ps_hide_act, pi_start_index, pi_end_index)
   DEFINE   ps_hide_act      STRING,
            pi_start_index   LIKE type_file.num10,
            pi_end_index     LIKE type_file.num10
   DEFINE   li_continue      LIKE type_file.num5,
            li_reconstruct   LIKE type_file.num5
   DEFINE   li_i             LIKE type_file.num5
 
   INPUT ARRAY ma_qry_tmp WITHOUT DEFAULTS FROM s_apy.* ATTRIBUTE(INSERT ROW=FALSE, DELETE ROW=FALSE,APPEND ROW=FALSE, UNBUFFERED)
      BEFORE INPUT
         CALL cl_set_act_visible("prevpage,nextpage,reconstruct",TRUE)
         IF (ps_hide_act IS NOT NULL) THEN
            CALL cl_set_act_visible(ps_hide_act, FALSE)
         END IF
      ON ACTION prevpage
         CALL GET_FLDBUF(s_apy.check) RETURNING ma_qry_tmp[ARR_CURR()].check
         CALL apa10_qry_reset_multi_sel(pi_start_index, pi_end_index)
 
         IF ((pi_start_index - mi_page_count) >= 1) THEN
            LET pi_start_index = pi_start_index - mi_page_count
         END IF
 
         LET li_continue = TRUE
 
         EXIT INPUT
      ON ACTION nextpage
         CALL GET_FLDBUF(s_apy.check) RETURNING ma_qry_tmp[ARR_CURR()].check
         CALL apa10_qry_reset_multi_sel(pi_start_index, pi_end_index)
 
         IF ((pi_start_index + mi_page_count) <= ma_qry.getLength()) THEN
            LET pi_start_index = pi_start_index + mi_page_count
         END IF
 
         LET li_continue = TRUE
 
         EXIT INPUT
      ON ACTION refresh
         CALL apa10_qry_refresh()
 
         LET pi_start_index = 1
         LET li_continue = TRUE
 
         EXIT INPUT
      ON ACTION reconstruct
         LET li_reconstruct = TRUE
         LET li_continue = TRUE
 
         EXIT INPUT
      ON ACTION accept
         IF ARR_CURR()>0 THEN
            CALL GET_FLDBUF(s_apy.check) RETURNING ma_qry_tmp[ARR_CURR()].check
            CALL apa10_qry_reset_multi_sel(pi_start_index, pi_end_index)
            CALL apa10_qry_accept(pi_start_index+ARR_CURR()-1)
         ELSE 
            LET ms_ret1 = NULL
         END IF 
         LET li_continue = FALSE
 
         EXIT INPUT
      ON ACTION cancel
         LET INT_FLAG = 0
         IF (NOT mi_multi_sel) THEN
            LET ms_ret1 = NULL
         END IF
 
         LET li_continue = FALSE
 
         EXIT INPUT

      ON ACTION exporttoexcel
         CALL cl_export_to_excel(ui.Interface.getRootNode(),base.TypeInfo.create(ma_qry),'','')
 
      ON IDLE g_idle_seconds
         CALL cl_on_idle()
         CONTINUE INPUT
 
      ON ACTION qry_string
         CALL cl_qry_string("detail")
 
      ON ACTION selectall
         FOR li_i = 1 TO ma_qry_tmp.getLength()
             LET ma_qry_tmp[li_i].check = "Y"
         END FOR
 
      ON ACTION select_none
         FOR li_i = 1 TO ma_qry_tmp.getLength()
             LET ma_qry_tmp[li_i].check = "N"
         END FOR
 
   END INPUT
 
   RETURN li_continue,li_reconstruct,pi_start_index
END FUNCTION
 
##################################################
# Description  	: 重設查詢資料關於'check'欄位的值.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: pi_start_index   LIKE type_file.num10    所要顯現的查詢資料起始位置	#No.FUN-680131 INTEGER
#               : pi_end_index     LIKE type_file.num10    所要顯現的查詢資料結束位置	#No.FUN-680131 INTEGER
# Return   	: void
# Memo        	:
# Modify   	:
##################################################
FUNCTION apa10_qry_reset_multi_sel(pi_start_index, pi_end_index)
   DEFINE   pi_start_index   LIKE type_file.num10, 
            pi_end_index     LIKE type_file.num10
   DEFINE   li_i             LIKE type_file.num10,
            li_j             LIKE type_file.num10
 
 
   FOR li_i = pi_start_index TO pi_end_index
      LET ma_qry[li_i].check = ma_qry_tmp[li_j+1].check
      LET li_j = li_j + 1
   END FOR
END FUNCTION
 
##################################################
# Description  	: 採用DISPLAY ARRAY的方式來顯現查詢過後的資料.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: ps_hide_act      STRING    所要隱藏的Action Button
#               : pi_start_index   LIKE type_file.num10    所要顯現的查詢資料起始位置
#               : pi_end_index     LIKE type_file.num10    所要顯現的查詢資料結束位置
# Return   	: SMALLINT   是否繼續
#               : SMALLINT   是否重新查詢
#               : INTEGER    改變後的起始位置
# Memo        	:
# Modify   	:
##################################################
FUNCTION apa10_qry_display_array(ps_hide_act, pi_start_index, pi_end_index)
   DEFINE   ps_hide_act      STRING,
            pi_start_index   LIKE type_file.num10,
            pi_end_index     LIKE type_file.num10
   DEFINE   li_continue      LIKE type_file.num5,
            li_reconstruct   LIKE type_file.num5

   DISPLAY ARRAY ma_qry_tmp TO s_apy.*
      BEFORE DISPLAY
         CALL cl_set_act_visible("prevpage,nextpage,reconstruct",TRUE)
         IF (ps_hide_act IS NOT NULL) THEN
            CALL cl_set_act_visible(ps_hide_act, FALSE)
         END IF
      ON ACTION prevpage
         IF ((pi_start_index - mi_page_count) >= 1) THEN
            LET pi_start_index = pi_start_index - mi_page_count
         END IF
 
         LET li_continue = TRUE
 
         EXIT DISPLAY
      ON ACTION nextpage
         IF ((pi_start_index + mi_page_count) <= ma_qry.getLength()) THEN
            LET pi_start_index = pi_start_index + mi_page_count
         END IF
 
         LET li_continue = TRUE
 
         EXIT DISPLAY
      ON ACTION refresh
         LET pi_start_index = 1
         LET li_continue = TRUE
 
         EXIT DISPLAY
      ON ACTION reconstruct
         LET li_reconstruct = TRUE
         LET li_continue = TRUE
         LET mi_need_cons = TRUE
 
         EXIT DISPLAY
      ON ACTION accept
         CALL apa10_qry_accept(pi_start_index+ARR_CURR()-1)
         LET li_continue = FALSE

         EXIT DISPLAY
      ON ACTION cancel
         LET INT_FLAG = 0
         IF (NOT mi_multi_sel) THEN
            LET ms_ret1 = NULL
         END IF
 
         LET li_continue = FALSE
 
         EXIT DISPLAY
      ON ACTION exporttoexcel
         CALL cl_export_to_excel(ui.Interface.getRootNode(),base.TypeInfo.create(ma_qry),'','')
      ON IDLE g_idle_seconds
         CALL cl_on_idle()
         CONTINUE DISPLAY

      ON ACTION qry_string
         CALL cl_qry_string("detail")
 
   END DISPLAY
   CALL cl_set_act_visible("accept,cancel", TRUE)
 
   RETURN li_continue,li_reconstruct,pi_start_index
END FUNCTION
 
##################################################
# Description   : 重設查詢資料.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter     : none
# Return        : void
# Memo          :
# Modify        :
##################################################
FUNCTION apa10_qry_refresh()
   DEFINE   li_i   LIKE type_file.num10
 
 
   FOR li_i = 1 TO ma_qry.getLength()
      LET ma_qry[li_i].check = 'N'
   END FOR
END FUNCTION
 
##################################################
# Description  	: 選擇並確認資料.
# Date & Author : {%格式為:xxxx/xx/xx by xxx}
# Parameter   	: pi_sel_index   LIKE type_file.num10    所選擇的資料索引	#No.FUN-680131 INTEGER
# Return   	: void
# Memo        	:
# Modify   	:
##################################################
FUNCTION apa10_qry_accept(pi_sel_index)
   DEFINE   pi_sel_index    LIKE type_file.num10
   DEFINE   lsb_multi_sel   base.StringBuffer,
            li_i            LIKE type_file.num10
 
   IF pi_sel_index = 0 THEN
      RETURN
   END IF
 
   IF (mi_multi_sel) THEN
      LET lsb_multi_sel = base.StringBuffer.create()
 
      FOR li_i = 1 TO ma_qry.getLength()
         IF (ma_qry[li_i].check = 'Y') THEN
            IF (lsb_multi_sel.getLength() = 0) THEN
               CALL lsb_multi_sel.append(ma_qry[li_i].apyslip CLIPPED)
            ELSE
               CALL lsb_multi_sel.append("|" || ma_qry[li_i].apyslip CLIPPED)
            END IF
         END IF
      END FOR
      LET ms_ret1 = lsb_multi_sel.toString()
   ELSE
      LET ms_ret1 = ma_qry[pi_sel_index].apyslip CLIPPED
   END IF
END FUNCTION
  • 放到：/u1/topprod/tiptop/qry/4gl
# 使用sftp
cd /u1/topprod/tiptop/qry/4gl
put q_apa10.4gl
# 使用ssh
cd /u1/topprod/tiptop/qry/4gl
r.c2  q_apa10s

配置

p_qry 新增开窗查询

在这里插入图片描述

p_link 新增连接

在这里插入图片描述

# 使用ssh
cd /u1/topprod/tiptop/qry/4gl
r.l2 qry

测试

4gl引用

# 調用：q_apa10(TRUE, FALSE) 第一個參數是true是復選，是false是單選
CONSTRUCT BY NAME tm.wc ON apyslip
      ON ACTION locale
         CALL cl_show_fld_cont()
         LET g_action_choice = "locale"
         EXIT CONSTRUCT
          ON ACTION CONTROLP
           CASE
            WHEN INFIELD(apyslip)
                 CALL q_apa10(TRUE, FALSE) RETURNING g_qryparam.multiret
                 DISPLAY g_qryparam.multiret TO apyslip
                 NEXT FIELD apyslip
           END CASE
      ON IDLE g_idle_seconds
         CALL cl_on_idle()
         CONTINUE CONSTRUCT
 
      ON ACTION help
         CALL cl_show_help()
 
      ON ACTION controlg
         CALL cl_cmdask()
 
      ON ACTION about
         CALL cl_about()
 
      ON ACTION exit
         LET INT_FLAG = 1
         EXIT CONSTRUCT
   END CONSTRUCT

   IF g_action_choice = "locale" THEN
      LET g_action_choice = ""
      CALL cl_dynamic_locale()
      CONTINUE WHILE
   END IF
DKLi1717
关注
  • 15
    点赞
  • 踩
  • 10
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
TIPTOP ERP 快捷键使用及其实现原理
李艺辉的专栏
04-09 8389
TIPTOP ERP 快捷键使用及其实现原理：①.4ad的cceleratorName属性；②.$TOP/config/4ad/语言别/tiptop.4ad；③.$TOP/config/4ad/语言别/系统别/程序.4ad
TIPTOP内置函数
在人间
12-17 9353
函式名称：cl_about 程序名称：cl_about.4gl 用途：程序信息 传入参数：none 回传值：none 用法：CALL cl_about() 函式名称：cl_anykey 程序名称：cl_anykey.4gl 用途：请按任何键继续 传入参数：p_sw Not used 回传值：none 用法：CALL cl_anykey() 函式名称：cl_autotime 程序名称：cl_
TIPTOPGP 公用程序（二）
勇不言败de小黑
04-22 4636
函式名称：cl_numfor3程序名称：cl_numfor3.4gl用途：将数值不须的小数位数不打印出传入参数：p_value 数值回传值：l_str FORMAT 后的数值，以CHAR 型态RETURN用法：LET a = cl_numfor3(amt,13)；PRINT a 函式名称：cl_on_idle程序名称：cl_on_idle.4gl用途：在ON I
TIPTOP ERP Program Life Cycle
李艺辉的专栏
04-14 6077
TIPTOP ERP Program Life Cycle:介绍TIPTOP ERP一个程序加载的过程，包括画面加载、title、UI Lable、action、参数初始化....
TIPTOP GP5.1excel 数据访问
kissguan的小屋
03-21 2148
相信许多公司虽然用上了tiptop erp系统，但是Excel在表格制作或者数据分析方面仍然起着举足轻重的作用。鼎新有自己的产生excel文件的方式，就是产生xml格式的excel文件，这种方式复杂，不直观，而且格式也不是微软默认的二进制格式的文件，要从excel文件中导入数据到tiptop数据库中就更无从谈起。        那么有没有其他的办法呢？        经过笔者对GDC的
Perl脚本实现tiptop数据导出EXCEL模板
四方木
10-18 415
【代码】Perl脚本实现tiptop数据导出EXCEL模板。
示波器桌面程序EasyScopeX-V1.01.02.01.21-CN
01-18
《深入理解示波器桌面程序EasyScopeX-V1.01.02.01.21-CN》 示波器是一种重要的电子测量仪器，它能够捕获并显示信号的电压变化，帮助工程师分析和诊断电路问题。在数字化时代，传统的物理示波器逐渐被虚拟示波器所...
SINAMICS_V90PN伺服驱动器_固件_V01.04.02.01.zip
04-30
4. 功能增强：V01.04.02.01可能引入了新的功能或特性，如更精细的电流和速度控制，以及更多的用户自定义选项，以满足多样化的需求。 5. 能效提升：通过优化算法和控制策略，新固件可能降低了驱动器的能耗，符合日益...
ERP系统信息化资料:LG02.01.01 核定岗位定员.doc
09-29
ERP系统信息化资料:LG02.01.01 核定岗位定员.doc
ERP系统信息化资料:LG02.01.02 人力资源需求计划.doc
09-29
ERP系统信息化资料:LG02.01.02 人力资源需求计划.doc
电子病历基本数据集WS 445.1-2014
10-14
电子病历基本数据集第4部分检查检验记录 电子病历基本数据集第5部分一般治疗处置记录 电子病历基本数据集第6部分助产记录 电子病历基本数据集第7部分护理操作记录 电子病历基本数据集第8部分护理评估与计划 电子病历...
02.02.03.tiptop：组件篇（4gl 查询：导出多个excle）
qq_26730689的博客
02-02 405
02.02.03.tiptop：组件篇（4gl 查询：导出多个excle）
02.01.02.tiptop：组件篇（4fd+4gl 新增：日期列）
qq_26730689的博客
02-01 385
02.01.02.tiptop：组件篇（4fd+4gl 新增：日期列）
【实习之T100开发】Genero FGL (TIPTOP4GL) 学习笔记（2）
萌宅鹿的技术小屋
01-22 3759
Genero FGL（TIPTOP4GL）学习笔记ARRAYARRAY的定义和方法显示数组内容 DISPLAY ARRAY数组内容输入 INPUT ARRAY控制段执行顺序 ARRAY ARRAY的定义和方法 Genero 的数组可以设定为一维，二维或多维数组，其计数从『1』开始。若未知数组所需要的长度，可以宣告为动态数组。 固定数组（Static Array）定义 ARRAY [ intconst [,intconst [,intconst] ] ] OF datatype 动态数组（Dynamic A
TIPTOP——p_qry动态查询程序介绍
【小冯子】的专栏
09-15 7016
一、p_qry动态查询程序介绍 在TIPTOP GP系统中，有两种查询程序： 1、hard-code       此类查询程序是由人工完成。       存在源代码档，目录是qry/4gl下。       任何查询都可以用此类方式完成。       程序编写比较繁琐，对于初学者不易掌握。 2、p_qry动态查询程序       此类查询程序是由系统完
tiptop 编译运行_TIPTOP_画面档修改说明
weixin_32348697的博客
12-29 587
第1页共5页TIPTOP画面档修改说明一、PER文件的UI(UserInterface用户接口)组成：TitleBar(标题栏)TopMenu(菜单栏)【非必要Section】定义画面中的TOPMENU结构。ToolBar(工具栏)【非必要Section】定义画面中的TOOLBAR结构。Page(页面)FieldDescription(域)RingMenu(响应按钮)【非必要Section】定...
Tiptop二次开发需要的工具及手册
大鱼
09-07 2182
Genero Studio 4GL官方开发手册.pdf：http：//download.csdn.net/detail/yihuiworld/4284370 tiptop程式错误代码查询手册：http：//download.csdn.net/detail/yihuiworld/4284354 tiptop gp 5.1数据库ds.sch：http：//download.csdn.net/det...
开发语言的基本构成。
luj_1768的博客
07-24 409
许多人都对设计一套自有知识产权的开发语言感兴趣。那么，如何按照功能模块设计开发语言？
开题报告达达宠物认领信息网站的设计与实现 已通过开题答辩的.docx
最新发布
07-25
宠物认领信息网站的主要目的是为寻找宠物的失主和寻找新家的宠物提供一个在线的信息交流平台。通过这个平台，失主可以发布失宠信息，寻找走失或遗弃的宠物；而救助人或组织则可以发布待领养的宠物信息，为那些无家可归的宠物寻找一个永久的归宿。 这样的网站通常会提供一个详细的宠物数据库，包括照片、品种、年龄、健康状况等信息，以便让失主能够方便地找到自己的宠物。同时，网站还会提供一些相关的服务，如失主与救助人之间的在线交流、宠物匹配推荐、领养手续办理等，以帮助双方顺利完成宠物的认领和领养过程。 宠物认领信息网站的目的在于提高失宠找到宠物的几率，减少流浪宠物的数量，并为那些无家可归的宠物提供一个温馨的新家。同时，网站还能促进社会对流浪宠物的关注和保护，提高人们的动物保护意识。
Csharp 正则表达式获取02.01.23 08:30:21
06-06
在 C# 中，您可以使用 `Regex` 类来处理正则表达式。以下是一个使用正则表达式获取 "02.01.23 08:30:21" 字符串的示例代码： ```csharp string input = "some text 02.01.23 08:30:21 some more text"; string pattern = @"\d{2}\.\d{2}\.\d{2}\s\d{2}:\d{2}:\d{2}"; Match match = Regex.Match(input, pattern); if (match.Success) { Console.WriteLine("Match found: " + match.Value); } else { Console.WriteLine("Match not found"); } ``` 输出结果为：`Match found: 02.01.23 08:30:21`。 在上面的代码中，首先定义了一个输入字符串 `input`，其中包含了需要匹配的文本。然后定义了一个正则表达式 `pattern`，该正则表达式与上文中的正则表达式相同。接着，使用 `Regex.Match` 方法进行匹配。如果匹配成功，则 `match.Success` 属性为 `true`，匹配的字符串可以通过 `match.Value` 属性获取。如果匹配失败，则 `match.Success` 属性为 `false`。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

DKLi1717

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值