黑猴子的家：Hive 数据导入

1、向表中装载数据（Load）

1）语法

hive>load data [local] inpath '/opt/module/datas/student.txt' [overwrite] 
into table student [partition (partcol1=val1,…)];

（1）load data:表示加载数据
（2）local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表
（3）inpath:表示加载数据的路径
（4）into table:表示加载到哪张表
（5）student:表示具体的表
（6）overwrite:表示覆盖表中已有数据，否则表示追加
（7）partition:表示上传到指定分区

2）实操案例

（1）创建一张表

hive (default)> create table student(id string, name string) 
                row format delimited fields terminated by '\t';

（2）加载本地文件到hive

hive (default)> load data local inpath '/opt/module/datas/student.txt' 
                into table default.student;

（3）加载HDFS文件到hive中

上传文件到HDFS

hive (default)> dfs -put /opt/module/datas/student.txt /user/victor/hive;

加载HDFS上数据

hive (default)> load data inpath '/user/victor/hive/student.txt' 
                into table default.student;

（4）加载数据覆盖表中已有的数据

上传文件到HDFS

hive (default)> dfs -put /opt/module/datas/student.txt /user/victor/hive;

加载数据覆盖表中已有的数据

hive (default)>load data inpath '/user/victor/hive/student.txt' 
               overwrite into table default.student;

2、通过查询语句向表中插入数据（Insert）

1）创建一张分区表

hive (default)> create table student(id string, name string) 
partitioned by (month string) 
row format delimited fields terminated by '\t';

2）基本插入数据

hive (default)> insert into table student partition(month='201801') 
values('1004','wangwu');

3）基本模式插入（根据单张表查询结果）

hive (default)> insert overwrite table student partition(month='201802') 
select id, name from student where month='201801';

4）多插入模式（根据多张表查询结果）

hive (default)> from student
             insert overwrite table student partition(month='201803')
             select id, name where month='201801'
             insert overwrite table student partition(month='201804')
             select id, name where month='201801';

3、查询语句中创建表并加载数据（as select）

根据查询结果创建表（查询的结果会添加到新创建的表中）

hive (default)> create table if not exists student3 as select id, name from student;

4、创建表时通过location指定加载数据路径

1）创建表，并指定在hdfs上的位置

hive (default)> create table if not exists student5(
             id int, name string
             )
             row format delimited fields terminated by '\t'
             location '/user/hive/warehouse/student5';

2）上传数据到hdfs上

hive (default)> dfs -put /opt/module/datas/student.txt  
/user/hive/warehouse/student5;

3）查询数据

hive (default)> select * from student5;

5、import数据到指定hive表中

先用export导出后，再将数据导入。

hive (default)> import table student2 partition(month='201709') 
from '/user/hive/warehouse/export/student';