GAMS系列分享2-GAMS基础知识-运输问题线性规划

本文链接：https://blog.csdn.net/qq_34194377/article/details/105170430

为了尽快对GAMS有一个较全面的认识，先来熟悉一下经典的运输问题线性规划问题。就我知道的，好多参考资料都是以此为GAMS的入门，当时我自己在初学的时候也是首先理解的这个例子。

1 学习这个例子的两种打开方式：

1.1，在GAMS中model.libraries中搜索某trnsport，然后点击运行就可以了。（运行先爽一下）

1.2，直接复制下面的代码，执行就行了

2 如何较深入学习这个例子

1 学习这个例子的两种打开方式：

1.1，在GAMS中model.libraries中搜索某trnsport，然后点击运行就可以了。（运行先爽一下）

1.2，直接复制下面的代码，执行就行了

$Title  A Transportation Problem (TRNSPORT,SEQ=1)
$Ontext

This problem finds a least cost shipping schedule that meets
requirements at markets and supplies at factories.


Dantzig, G B, Chapter 3.3. In Linear Programming and Extensions.
Princeton University Press, Princeton, New Jersey, 1963.

This formulation is described in detail in:
Rosenthal, R E, Chapter 2: A GAMS Tutorial. In GAMS: A User's Guide.
The Scientific Press, Redwood City, California, 1988.

The line numbers will not match those in the book because of these
comments.

$Offtext


  Sets
       i   canning plants   / seattle, san-diego /
       j   markets          / new-york, chicago, topeka / ;

  Parameters

       a(i)  capacity of plant i in cases
         /    seattle     350
              san-diego   600  /

       b(j)  demand at market j in cases
         /    new-york    325
              chicago     300
              topeka      275  / ;

  Table d(i,j)  distance in thousands of miles
                    new-york       chicago      topeka
      seattle          2.5           1.7          1.8
      san-diego        2.5           1.8          1.4  ;

  Scalar f  freight in dollars per case per thousand miles  /90/ ;

  Parameter c(i,j)  transport cost in thousands of dollars per case ;

            c(i,j) = f * d(i,j) / 1000 ;

  Variables
       x(i,j)  shipment quantities in cases
       z       total transportation costs in thousands of dollars ;

  Positive Variable x ;

  Equations
       cost        define objective function
       supply(i)   observe supply limit at plant i
       demand(j)   satisfy demand at market j ;

  cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j)) ;

  supply(i) ..   sum(j, x(i,j))  =l=  a(i) ;

  demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

  Model transport /all/ ;

  Solve transport using lp minimizing z ;

  Display x.l, x.m ;