修改本机固定ip地址脚本

一.设置须知

ip set address 设置ip地址

name=网络适配器名称

addr=IPV4地址

mask=IPV4子网掩码

gateway=IPV4默认网关

netsh interface ip set address name="Wi-Fi" source=static addr=192.168.1.222 mask=255.255.255.0 gateway=192.168.1.1 1

ip set dns 设置dns服务器

netsh interface ip set dns name="Wi-Fi" source=static addr=114.114.114.114 register=PRIMARY validate=no

netsh interface ip add dns name="Wi-Fi" addr=8.8.8.8 validate=no

netsh interface ip set wins name="Wi-Fi" source=static addr=none 

二.脚本

@echo off 
 
:: BatchGotAdmin 
:------------------------------------- 
REM --> Check for permissions 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" 
 
REM --> If error flag set, we do not have admin. 
if '%errorlevel%' NEQ '0' ( 
 goto UACPrompt 
) else ( goto gotAdmin ) 
 
:UACPrompt 
 echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs" 
 echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs" 
 
 "%temp%\getadmin.vbs" 
 exit /B 
 
:gotAdmin 
 if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" ) 
 pushd "%CD%" 
 CD /D "%~dp0" 
:-------------------------------------- 

echo 设置自动ip请按1

echo 设置固定ip请按2

echo 请选择,或按q退出

set /p shu= 


if "%shu%"=="1" cls&goto ONE
if "%shu%"=="2" cls&goto TWO
if "%shu%"=="q" exit

:ONE
echo 正在设置自动获得IP地址，请稍等……

netsh interface ip set address name="Wi-Fi" source=dhcp

netsh interface ip set dns name="Wi-Fi" source=dhcp 

echo 设置成功，按任意键退出
pause
exit

:TWO
echo 请输入网关数字(n=?) 例:n=8 即设置成192.168.8.1
set /p n= 

echo 正在设置您的固定IP地址请稍等……

netsh interface ip set address name="Wi-Fi" source=static addr=192.168.%n%.222 mask=255.255.255.0 gateway=192.168.%n%.1 1

echo 正在设置您的DNS，请稍等……

netsh interface ip set dns name="Wi-Fi" source=static addr=114.114.114.114 register=PRIMARY validate=no

netsh interface ip add dns name="Wi-Fi" addr=8.8.8.8 validate=no

netsh interface ip set wins name="Wi-Fi" source=static addr=none 

echo 设置成功，按任意键退出
pause
exit