M语言-数据类型

最新推荐文章于 2022-09-04 22:30:59 发布
最新推荐文章于 2022-09-04 22:30:59 发布
阅读量1.5k 收藏 8
点赞数 1
分类专栏： M语言与Cache数据库 文章标签： java 前端 javascript
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_35507234/article/details/126198335
版权

 

目录

1.字符串

2.数字

3.小数

4.对象

5.布尔类型

6.日期

        Cache ObjectScript是一种无类型语言，不必声明变量的类型。任何变量都可以有字符串、数值或对象值。

1.字符串

  • 最大字符串大小是可配置的。默认情况下启用长字符串，长字符串的最大字符串大小是3641144个字符，否则最大字符串大小为32767个字符。可在Management Portal的【系统管理】-【配置】-【系统配置】-【内存和启动】里面配置是否启用长字符串
// 输出字符串的最大长度
w $system.SYS.MaxLocalLength()
  • 字符串可以包含任何字符，包括空格和控制字符。
  • 字符串长度指的是字符数，而不是字节数
// 输出11
w $length("hello world")
  • 可以使用$c（$char缩写），来指定不可输入的字符
ClassMethod MyFunction10()
{
	set str = "abc"
	/// zzdump输出Ascall码
	zzdump str
	
	/// $c(0)代表空，$c(9)代表tab建（制表符）,$c(10)代表换行,$c(13)代表回车
	w "",!
	set str = "a"_$c(0)_"bb"_$c(9)_"c"_$c(10)_"d"_$c(13)_"e"
 
    // 输出结果为：a bb	   c
    //            d
    //            e
	w str
}
  • 如果要在字符串中包含引号字符（"），则需要两个“”，两个“”代表一个”
// 输出"
w """",!
 
// 输出""
w """"""

set str = "hello ""world"""
// 输出hello "world"
w str
  • 不包含任何值的字符串称为空字符串。它由两个引号表示。空字符串被视为已定义的值，它的长度是0。空字符串和$c(0)不同，如下所示：
ClassMethod MyFunction()
{
	set str = ""
	// 输出0
	w "空字符串长度："_$length(str),!
	
	set str = $c(0)
	// 输出1
	w "$c(0)字符串长度："_$length(str)
}
  • 可以使用连接运算符（_）将两个或多个字符串连接在一起。
// 输出helloworld!
w "hello"_"world"_"!"
  • 可以使用等于（=）和不等于（'=）运算符来比较两个字符串。字符串的比较区分大小写。如果字符串为数字，则只有包含规范形式的数字的字符串才等于其相应地数字（-0不是规范数字）
ClassMethod MyFunction()
{
	// 输出1
    w "hello" = "hello"

    // 输出0
    w "world" '= "world"

    // 输出0
    w "-8" = 8,!
    // 输出1
    w "8" = 008.00,!
    // 输出1
    w "-8" = -8

    // 输出0
    w "-0" = 0,!
    // 输出0
	w "-0" = -0
}
  • >、<、<=、或>=运算符不能用于字符串的比较。这些运算符将字符串视为数字，并始终执行数字比较。使用这些运算符进行比较时，将任何非数字字符串分配数值0
// 输出0
w "x" > 1
// 输出1
w "2x" > 1
// 输出0
w "x2x" > 1

2.数字

  • 数字前面和后面可以加0
// 输出9
w 0009.00
  • 字母E，用于科学计数法：
// 输出 35000000000
w 3.5E10
  • 数字前面可以加+和-。但是不能出现在除了科学计数法E之外的其他字符的后面
ClassMethod MyFunction14()
{
    // 输出-200
	w -2E2,!
    // 输出-.02
	w -2E-2,!
    // 输出-200
	w -2E+2,!
    // 输出200
	w 2E+2,!
    // 输出.02
	w 2E-2,!
}
  • Cache将数字转换为规范形式时，会将数字前面和后面的0去掉。使用$fn和$justify，将去掉的0恢复，并可以指定保留几位小数
// 输出.066
w 0.066000,!
	
//使用$fn和$justify，将去掉的0恢复，并可以指定保留几位小数
// 输出0.066
w $fn(.066, "N", 3),!
// 输出0.0660
w $justify(.066, "N", 4)
  • 对于算术运算、大于/小于运算，如果字符串是规范形式的数字，则在功能上与相应地数字相同
ClassMethod Number()
{
	set x = 0009.00
    // 输出1
	w "数字长度："_$length(x),!
	// 输出9
	w "数字值："_x,!
	// 输出1
	w "是否与9相等：",x=9,!
	// 输出10
	w "+1：",x+1,!
	
    // 定义数字字符串
	set y = "0009.00"
	// 输出7
	w "数字长度："_$length(y),!
	// 输出0009.00
	w "数字值："_y,!
	// 输出0
	w "是否与9相等：",y=9,!
	// 输出10
	w "+1：",y+1,!


    //输出1
    w "003"+3 = 6,!
    //输出1
	w "++-3" + -3 = -6,!
	
    //输出1
	w "003" > 2,!
    //输出1
	w "++-003" >= -3
}
  • 混合数字字符串：指的是以数字字符开头，后面跟一个或多个非数字字符的字符串。在进行数值或布尔运算时（等式运算除外），将会从前往后匹配，如果遇到不规范非数字字符，则停止匹配，后面的字符将会被忽略。
ClassMethod Command()
{
	// 输出24
	w "22 hello" + 2,!
	
	// 输出24
	w "+22/77" + 2,!
	
	// 输出24
	w "22.000" + 2,!
	
	// 输出24.5
	w "22.5.99" + 2,!
	
	// 输出24
	w "22.s.8" + 2,!
}
  • 非数字字符串：指的是再遇到数字字符串之前，遇到的非数字字符串的任何字符串，空格也被视为非数字字符串。数值和布尔运算通常会将非数字字符串解析为数值0
ClassMethod MyFunction()
{
	// 输出1
	w +"8" = 8,!
	
	// 输出1
	w +"+0008" = 8,!
	
	// 输出1
	w +"8 num" = 8,!
	
	// 输出1
	w +"num" = 0,!
	
	// 输出1
	w +"" = 0,!
}
  • 可以使用连接运算符（_）将多个数字连接起来。Cache会首先将每个数字转换为其规范形式，然后对结果执行字符串连接
ClassMethod MyFunction()
{
	// 输出1234
	w 12_34,!
	
	// 输出1234
	w 12_+34,!
	
	// 输出1234
	w 12_--34,!
	
	// 输出12.0134
	w 12.01_34,!
	
	// 输出.0134
	w 0.01_34,!
	
	// 输出1234.55
	w 12_0034.55,!
	
	// 输出12034
	w 12E1_34,!

    // 输出1212.3
	w 12_"12.3"
}

3.小数

  • 默认情况下，Cache使用$decimal表示浮点小数。它提供最高级别的精度，保留19位。
ClassMethod MyFunction2()
{
	// 输出.3333333333333333333
	w 1/3,!
	
	// 输出.3333333333333333333
	w $decimal(1/3),!
	
	// NAN表示非数字，输出0
	w $decimal("NAN"),!
	
	// INF表示无穷大，输出0
	w $decimal("INF"),!
}
  • $double表示双精度浮点小数。它的精度为53个二进制位，相等于只能保证小数后16位精度。支持特殊值INF（无穷大）和NAN（非数字）
ClassMethod MyFunction3()
{
	// 输出.33333333333333331482
	w $double(1/3),!
	
	// 输出NAN
	w $double("NAN"),!
	
	// 输出INF
	w $double("INF"),!
}

        从上面可以看出，在第17位时，开始不准确。

 

  • Cache中，最大整数范围为：-9223372036854775808和9223372036854775807。如果对最大整数增加值，则会进行四舍五入，将低位数字替换为0
ClassMethod MyFunction4()
{
	// 输出9223372036854775810
	w 9223372036854775807+1,!
	
	// 输出9223372036854775830
	w 9223372036854775807+23,!
	
	// 输出9223372036854775830
	w 9223372036854775807+25,!
	
	// 输出1
	w (9223372036854775807+23)=(9223372036854775807+25),!
}

4.对象

  • 通过%New命令，定义一个对象
Class Demo.Obj Extends %RegisteredObject
{

Property Name As %String;

/// d ##class(Demo.Obj).Command()
ClassMethod Command()
{
	// 定义对象，将对象的引用给obj变量
	set obj = ##class(Obj).%New()
	
    // 输出15@Demo.Obj
	w obj,!
}

}
  • 使用$isobject判断是否为对象
// 输出1
w $isobject(obj)

// 输出0
w $isObject("123")
  • 定义多个同一个对象时，会产生增加对象的内部引用计数
set obj = ##class(Obj).%New()
// 输出16@Demo.Obj
w obj,!
	
set obj2 = ##class(Obj).%New()
// 输出16@Demo.Obj
w obj2,!

/* 输出如下：
obj=<OBJECT REFERENCE>[15@Demo.Obj]
+----------------- general information ---------------
|      oref value: 16
|      class name: Demo.Obj
| reference count: 2
+----------------- attribute values ------------------
|               Name = ""
+-----------------------------------------------------
*/
zw obj2
  • 当对象的引用数量为0时，Cache会自动销毁该对象（调用%OnClose()方法，并将其从内存中移除）。OnClose()方法如下：
/// This callback method is invoked by the <METHOD>%Close</METHOD> method to 
/// provide notification that the current object is being closed.
/// 
/// <P>The return value of this method is ignored.
Method %OnClose() As %Status [ Private, ServerOnly = 1 ]
{
	Quit $$$OK
}

5.布尔类型

        在M语言中，布尔类型为1（true）和0（false）。

ClassMethod MyFunction()
{
	set num = 1
	// 输出true
	if (num) {
		w "true",!	
	}else{
		w "false",!
	}
	
	// 输出true
	if 0.5 {
		w "true",!	
	}else{
		w "false",!
	}
	
	// 输出true
	if "1 num" {
		w "true",!	
	}else{
		w "false",!
	}
	
	// 输出0
	w "007"=7,!
	
	// 输出0
	w "+007"=7,!
	
	// 输出1
	w +"007"=7,!
	
	// 输出false
	if "num" {
		w "true",!	
	}else{
		w "false",!
	}
}

6.日期

        Global中的日期和时间都是以数字的形式存储的。

  • ObjectScript没有内置的日期类型，但是它由很多函数，用于操作和格式化表示为字符串的日期值
  • $horolog（缩写$h）：包含了当前进程的本地日期和时间，以逗号（,）分隔。第一部分是日期的数字，它是从1840年12月31日开始计算的数字；第二部分是秒的数字，它是从午夜开始计算的。
ClassMethod MyFunction()
{
	// 输出66328,46923
	w $horolog,!
}
  • $now：返回当前日期的本地日期和时间，以小数秒为单位
// 输出66328,51253.643677
w $now(),!
  • $zdate（缩写$zd）:验证日期，并将其从数字格式转换为显示指定的日期格式
  • $zdateh（缩写$zdh）:将日期格式转换为时间格式

$zd(日期数字，格式）->日期

$zdh(日期，格式) -> 数字

// 输出08/07/2022
w $zdate($horolog),!
// 输出2022-08-07
w $zd($horolog, 3),!


// 输出66328
w $zdateh("08/07/2022"),!
// 输出66328
w $zdh("2022-08-07", 3),!
// T表示当天， 输出66328
w $zdh("T", 5),!
  • $ztime（缩写$zt）:验证时间，并将其从数字格式转换为显示指定的时间格式
  • $ztimeh（缩写$zth）:将时间格式转换为时间格式

$zt(时间数字，格式）->时间

$zth(时间，格式) -> 数字

// 输出14:27:02
w $ztime($p($horolog, ",", 2)),!
	// 输出02:27:02PM
w $zt($p($horolog, ",", 2), 3),!


// 输出52022
w $ztimeh("14:27:02"),!
// 输出52022
w $zth("02:27:02PM", 3),!
  • $zdatetime（缩写$zdt）:验证日期和时间，将数字转换为日期和时间

$zdt(日期和时间数字，格式）->日期和时间

$zdth(日期和时间，格式) ->日期和时间数字

// 输出08/07/2022 14:33:36
w $zdatetime($h),!
// 输出2022-08-07 14:33:36
w $zdt($h, 3),!

// 输出66328,52416
w $zdatetimeh("08/07/2022 14:33:36"),!
// 输出66328,52416
w $zdatetimeh("2022-08-07 14:33:36", 3),!
// 输出66328,0
w $zdth("T", 5),!
  • $zhorolog（缩写$zh）：返回启动Cache库以来，经过的秒数。
// 输出101268.602726
w $zhorolog,!
	
// 输出28.13016890888888889
w $zhorolog/3600,!

        $zhorolog还可以用于计算程序运行的时间：

set t1 = $zh
	
//等待2秒钟
hang 2
	
set t2 = $zh
	
// 输出2.000593
w t2 - t1

luckyliuqs
关注
  • 1
    点赞
  • 踩
  • 8
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
M 语言进阶手册.pdf
05-24
M 语言进阶手册.pdf
M(MUMPS)语言
11-02
M(MUMPS)语言教程。这个语言在国外医疗行业使用的非常多。
M语言基础知识
weixin_41557853的博客
03-05 3万+
一、M语言的开发环境是： IIS的web服务器、cache数据库。（或者直接上集成环境的ensemble里面就已经包含了cache数据库、studio开发环境）。这里的M语言，最重要的一点是里面能够直接通过对象的方式去操作数据库。创建一个对象就相当于创建了一张数据库的表。 二、M语言的调试方法、常用的特殊变量： 1、write ##class(ClassName[类名]).ClassMethod(...
M语言入门
Mr_Tengs的博客
08-12 1万+
M语言基础学习 M语言，是微软新Oslo发展和面向服务策略的一部分，外文名为M Language，“M”（代表Microsoft）,它是一种演算纸方式的编程语言。通过这种语言，用户可以用类似于数学公式的方式来编写算法，大大降低了编程所需的难度并节省了时间，从而让用户把主要的精力集中在算法的构思而不是编程上。 M Language常用的命令 1.1 set命令 给变量赋值,其它的写法:s 、S、se...
Power Query 系列 (05) - M 语言介绍
王敏的专栏
08-31 9858
M 语言或者叫 M 查询语言是 Power Query (简称为 PQ) 幕后的英雄。据说 Power Query Editor 可视化操作可以实现 PQ 80% 的功能，所以从操作层面来说，大部分人不用学习 M 语言，但学习和掌握 M 语言无疑是在数据处理的时候如虎添翼，而且，有一些 M 的基础也能加深对 PQ 操作步骤的理解，进而有可能对这些应用的步骤做一些优化和改善。总的来说，M 是一种值得...
M语言-命令
最新发布
云上道人的博客
09-04 2545
M语言：赋值命令
M语言基础简介
admin_str的博客
06-22 3696
一、 基本命令 COS中命令不多，我们先介绍最常用的。注意：所有COS命令不区分大小写，同时大部分都有缩写。既然COS不是强类型，那么我们不需要事先声明变量。我们就从设定变量开始： 设定变量 SET是设定变量的命令，缩写为S，语法为Set x=value。 例如，在Terminal里执行 Set x=“Hello, World” 如果需要同时将很多变量赋为相同的值，这是你可以Set (x,y,z)=value： Set (x,y,z) = “yes” 有时，你也会看到这样的写法：Set x=value1,
Go语言数据类型转换
01-08
Go语言数据类型转换需要注意只能显示转换。直接上代码吧  package main import ( fmt strconv unsafe _ unsafe //注掉一个包 ) func main() { //Golang中数据类型转换只能用显示转换T(v) var number int32 =...
go代码-Go 数据类型
07-16
在Go语言中，数据类型是编程的基础，它们定义了变量可以存储的数据种类。Go语言提供了丰富的数据类型，包括基本类型、复合类型以及特殊类型的接口。本文将深入探讨Go语言中的数据类型及其用法。 首先，Go语言有8种...
c#数据类型基础
09-06
C#数据类型基础 C#中的数据类型可以分为两种：值类型和引用类型。值类型包括简单值类型和复合型类型，简单值类型可以再细分为整数类型、字符类型、实数类型和布尔类型；而复合类型则是简单类型的复合，包括结构...
M语言常用用法及命令
07-18
M语言常用用法，命令，还有在开发过程遇到的问题给予总结
如何利用M语言编程简介
02-20
简单总结了Matlab的程序设计的基本概念，和基本用法。总结了常用的流程控制关键字及其用法
M语言query方法代码生成器
01-21
方便M语言开发者，避免在做查询时反复写query。同时具备方便的参数别名生成器。是M语言的编程好助手。
Caché数据库和M语言_mumps语言教程_ensemblecache_m语言医疗_医疗_cachem语言_
10-03
医疗M语言及Cache数据库，基于医院HIS系统及Ensemble
详解SQL Server中的数据类型
09-09
理解SQL Server中的数据类型及其特性至关重要，特别是在处理不同语言和字符集时。适当地选择数据类型不仅可以节省存储空间，还能避免在处理字符串时出现意外的截断或错误。在设计数据库结构时，应考虑数据的性质、...
M语言-运算符
云上道人的博客
08-15 1330
M语言-逻辑比较运算符
【Power BI ---M语言】M语言基础一
Babyfatliang的博客
03-11 1万+
M 语言学习的的实例 https://bengribaudo.com/blog/tag/power-query-m Power BI 中的M 语言的官方学习文档：https://docs.microsoft.com/en-us/powerquery-m/power-query-m-reference CSDN 上的相关链接：https://blog.csdn.net/zhonggu...
数据类型转换
m0_63797128的博客
11-13 411
自动类型转换 范围小的变量，可以直接赋值给类型大的变量。 public class emo{ public static void main (String [] args ){ short a = 8; int b; b = a; System.out.println(b); } } 表达式的自动类型转换 在表达式中小范围的变量会自动转换成当前大范围的变量类型再运算。 public class emo{ public static void ...
m语言常用函数和命令
热门推荐
书写人生
07-21 3万+
1.Set 设置变量  set s=3  2.write 输出变量  w s    3.kill  删除所有变量或一些指定的变量或所有变量除了指定的变量。  4.new  初始化变量。  5.Do(d):执行命令  6.Quit(q): 结束执行一个函数并返回一个值  7.$Horolog $Horolog 包含了时间和日期，它们由逗号分开。第一部分是日期的数字，它是从
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

luckyliuqs

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值