由于工作需要,必须先连接设备WiFi查看日志,再把信息拿出来发给别人。设备WiFi必须静态IP才能正常读取,而连接公司WiFi要切到动态IP才能联网,所以就写了个小脚本方便工作。
@echo off
rem 获取管理员权限,不然无法设置ip
%1 %2
ver|find "5.">nul&&goto :Admin
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof
:Admin
rem 设置字体颜色
color 3
title 设置上网环境
echo ☆☆☆☆请选择WiFi☆☆☆☆
echo 夜X仪(静态IP)=========》按1键
echo XXX_5G(动态IP)=======》按2键
rem 设置一个外部读取的变量
set/p n=请输入:
if /i "%n%" equ "1" goto guding
if /i "%n%" equ "2" goto zidong
: guding
rem 连接WiFi:Wifi-夜X仪
netsh wlan connect Wifi-夜X仪
rem 设置WiFi的静态ip、mask地址、网关
netsh interface ipv4 set address name="WLAN" source=static addr=192.168.XXX.XXX mask=255.255.255.0 gateway=192.168.XXX.1
rem 设置静态DNS
netsh interface ipv4 set dns name="WLAN" source=static addr=114.114.114.114 register=PRIMARY
goto end
rem 连接XXX_5G的WiFi,设置动态ip和DNS
: zidong
netsh wlan connect XXX_5G
netsh interface ipv4 set address name = "WLAN" source = dhcp
netsh interface ipv4 set dns name = "WLAN" source = dhcp
goto end
:end
echo ☆☆☆☆☆☆☆☆本机当前IP配置如下☆☆☆☆☆☆☆☆☆☆☆☆
rem 查看IP的主机信息,DNS信息,物理地址信息,DHCP服务器信息等
ipconfig /all
echo ☆☆☆☆☆☆☆☆设置成功!感谢使用☆☆☆☆☆☆☆☆☆☆☆☆
rem 关闭窗口
rem exit
pause