Hive中的多种优化方案

企业级优化

1、Fetch抓取

Fetch抓取是指，Hive中对某些情况的查询可以不必使用MapReduce计算。 在hive-default.xml.template文件中hive.fetch.task.conversion默认是more，在全局查找、字段查找、limit查找等都不走mapreduce。

把hive.fetch.task.conversion设置成none，然后执行查询语句，都会执行mapreduce程序。

<property>
    <name>hive.fetch.task.conversion</name>
    <value>more</value>
    <description>
      Expects one of [none, minimal, more].
      Some select queries can be converted to single FETCH task minimizing latency.
      Currently the query should be single sourced not having any subquery and should not have any aggregations or distincts (which incurs RS), lateral views and joins.
      0. none : disable hive.fetch.task.conversion
      1. minimal : SELECT STAR, FILTER on partition columns, LIMIT only
      2. more  : SELECT, FILTER, LIMIT only (support TABLESAMPLE and virtual columns)
    </description>
</property>

2、本地模式

Hive可以通过本地模式在单台机器上处理所有的任务。对于小数据集，执行时间可以明显被缩短。

但是这是有条件限制的：

• mr的最大输入数据量不能超过指定值
• 最大输入文件数不能超过指定值

否则，为yarn集群模式。

//开启本地mr
set hive.exec.mode.local.auto=true;  
//设置local mr的最大输入数据量，当输入数据量小于这个值时采用local  mr的方式，默认为134217728，即128M
set hive.exec.mode.local.auto.inputbytes.max=50000000;
//设置local mr的最大输入文件个数，当输入文件个数小于这个值时采用local mr的方式，默认为4
set hive.exec.mode.local.auto.input.files.max=10;

3、执行计划

格式：

EXPLAIN [EXTENDED | DEPENDENCY | AUTHORIZATION] query

案例：

--查看执行计划
hive (default)> explain select * from emp;
hive (default)> explain select deptno, avg(sal) avg_sal from emp group by deptno;
--查看详细执行计划
hive (default)> explain extended select * from emp;
hive (default)> explain extended select deptno, avg(sal) avg_sal from emp group by deptno;

4、表的优化

4.1 小表大表join

​ 将key相对分散，并且数据量小的表放在join的左边，这样可以有效减少内存溢出错误发生的几率；再进一步，可以使用map join让小的维度表（1000条以下的记录条数）先进内存。

新版的hive已经对小表JOIN大表和大表JOIN小表进行了优化。小表放在左边和右边已经没有明显区别。

这里可以通过查看执行计划验证，不管谁放在前面执行计划都一样，从而验证了hive的自动优化。

4.2 大表join大表

• 空key过滤

  ​ join超时是因为某些key对应的数据太多，而相同key对应的数据都会发送到相同的reducer上，从而导致内存不够。此时我们应该仔细分析这些异常的key，很多情况下，这些key对应的数据是异常数据，我们需要在SQL语句中进行过滤。例如key对应的字段为空。

  insert overwrite table jointable 
  select 
  *
  from(
  select n.* from nullidtable n
  left join bigtable o on n.id = o.id)
  t1
  where t1.id is not null
  
  --谓词下推
  insert overwrite table jointable select n.* from (select * from nullidtable where id is not null ) n  left join bigtable o on n.id = o.id;
  

• 空key转换

  ​ 虽然某个key为空对应的数据很多，但是相应的数据不是异常数据，必须要包含在join的结果中，此时我们可以表a中key为空的字段赋一个随机的值，使得数据随机均匀地分不到不同的reducer上。

  一定程度上也避免了数据倾斜的问题。

  insert overwrite table jointable
  select n.* from nullidtable n left join bigtable o on 
  nvl(n.id,rand()) = o.id;
  

• Sort Merge Bucket join(SMB)

  分桶join可以避免大量不必要的join操作，从而大大地降低计算时间。这也是由分桶的机制决定的，通过Key的hash值与桶数取模。

  桶的个数不能超过cpu核数

  --表一
  create table bigtable_buck1(
      id bigint,
      t bigint,
      uid string,
      keyword string,
      url_rank int,
      click_num int,
      click_url string)
  clustered by(id) 
  sorted by(id)
  into 6 buckets
  row format delimited fields terminated by '\t';
  load data local inpath '/opt/module/hive/datas/bigtable' into table bigtable_buck1;
  --表二
  create table bigtable_buck2(
      id bigint,
      t bigint,
      uid string,
      keyword string,
      url_rank int,
      click_num int,
      click_url string)
  clustered by(id)
  sorted by(id) 
  into 6 buckets
  row format delimited fields terminated by '\t';
  load data local inpath '/opt/module/hive/datas/bigtable' into table bigtable_buck2;
  

  设置参数

  set hive.optimize.bucketmapjoin = true;
  set hive.optimize.bucketmapjoin.sortedmerge = true;
  set hive.input.format=org.apache.hadoop.hive.ql.io.BucketizedHiveInputFormat;
  

  测试

  insert overwrite table jointable
  select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
  from bigtable_buck1 s
  join bigtable_buck2 b
  on b.id = s.id;
  

4.3 MapJoin

​ 如果不指定MapJoin或者不符合MapJoin的条件，那么Hive解析器会将Join操作转换成Common Join，即：在Reduce阶段完成join。容易发生数据倾斜。可以用MapJoin把小表全部加载到内存在map端进行join，避免reducer处理。

开启Mapjoin参数

set hive.auto.convert.join = true; 默认为true

大表小表的阈值设置（25M以下为小表）

set hive.mapjoin.smalltable.filesize=25000000;

对于left join，小表在前的话只能走reduce join。因为小表需要保留所有行的信息，而大表不会缓存并分发到各个节点，而是分布于多个mapTask,这样结果不全且不符合left join的逻辑，因此只能在reduce join中完成。

--小表在前mapjoin失效，走reduce
insert overwrite table jointable
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from smalltable s
left join bigtable  b
on s.id = b.id;

--走mapjoin
insert overwrite table jointable
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable  b
left join smalltable  s
on s.id = b.id;

4.4 Group by

默认情况下，Map阶段同一Key数据分发给一个reduce，当一个key数据过大时就会导致倾斜。

解决方案：

1.开启Map端聚合参数设置

--是否在Map端进行聚合，默认为True
set hive.map.aggr = true
--在Map端进行聚合操作的条目数目
set hive.groupby.mapaggr.checkinterval = 100000
--有数据倾斜的时候进行负载均衡（默认是false）
set hive.groupby.skewindata = true

当第三个选项设定为 true，生成的查询计划会有两个MR Job。

第一个MR Job中，Map的输出结果会随机分布到Reduce中，每个Reduce做部分聚合操作，并输出结果，这样处理的结果是相同的Group By Key有可能被分发到不同的Reduce中，从而达到负载均衡的目的；

第二个MR Job再根据预处理的数据结果按照Group By Key分布到Reduce中（这个过程可以保证相同的Group By Key被分布到同一个Reduce中），最后完成最终的聚合操作(虽然能解决数据倾斜，但是不能让运行速度的更快)。

4.5 Count(Distinct) 去重统计

​ 数据量大的情况下，由于COUNT DISTINCT操作需要用一个Reduce Task来完成，这一个Reduce需要处理的数据量太大，就会导致整个Job很难完成。一般COUNT DISTINCT使用先GROUP BY再COUNT的方式替换,但是需要注意group by造成的数据倾斜问题（比如count,可以先count group之后的数据,再sum）.

select count(distinct (id)) from bigtable;
--优化
select count(id) from (select id from bigtable group by id) a;

虽然会多用一个Job来完成，但在数据量大的情况下，这个绝对是值得的。

4.6 行列过滤

列处理：在SELECT中，只拿需要的列，如果有，尽量使用分区过滤，少用SELECT *。

行处理：在分区剪裁中，当使用外关联时，如果将副表的过滤条件写在join on后面，那么就会先全表关联，之后再过滤。

--先关联两张表，再用where条件过滤
select o.id from bigtable b
join bigtable o  on o.id = b.id
where o.id <= 10;
--谓词下推优化
select b.id from bigtable b
join (select id from bigtable where id <= 10 ) o on b.id = o.id;

5、合理设置Map和Reduce数

1.通常情况下，作业会通过input的目录产生一个或者多个map任务。

主要的决定因素有：input的文件总个数，input的文件大小，集群设置的文件块大小。

2.map是不是越多越好？

如果一个任务有很多小文件（远远小于块大小128m），则每个小文件也会被当做一个块，用一个map任务来完成，而一个map任务启动和初始化的时间远远大于逻辑处理的时间，就会造成很大的资源浪费。而且，同时可执行的map数是受限的。

3.是不是保证每个map处理接近128m的文件块，就高枕无忧了？

比如有一个127m的文件，正常会用一个map去完成，但这个文件只有一个或者两个小字段，却有几千万的记录，如果map处理的逻辑比较复杂，用一个map任务去做，肯定也比较耗时（NlineInputFormat）。

5.1 复杂文件增加Map数

当input的文件都很大，任务逻辑复杂，map执行非常慢的时候，可以考虑增加Map数，来使得每个map处理的数据量减少，从而提高任务的执行效率。

computeSpliteSize(Math.max(minSize,Math.min(maxSize,blocksize)))=blocksize=128M

--hive
set mapreduce.input.fileinputformat.split.maxsize=100;

根据以上参数调整切片大小，切片个数等于mapTask个数。

5.2 小文件合并

在map执行前合并小文件，减少map数：CombineHiveInputFormat具有对小文件进行合并的功能（系统默认的格式）

set hive.input.format= org.apache.hadoop.hive.ql.io.CombineHiveInputFormat;

在Map-Reduce的任务结束时合并小文件的设置：

--在map-only任务结束时合并小文件，默认true
SET hive.merge.mapfiles = true;
--在map-reduce任务结束时合并小文件，默认false
SET hive.merge.mapredfiles = true;

合并文件的大小，默认256M

SET hive.merge.size.per.task = 268435456;

当输出文件的平均大小小于该值时，启动一个独立的map-reduce任务进行文件merge

SET hive.merge.smallfiles.avgsize = 16777216;

5.3 合理设置Reduce数

• 方法一

1.每个Reduce处理的数据量默认是256MB

hive.exec.reducers.bytes.per.reducer=256000000

2.每个任务最大的reduce数，默认为1009

hive.exec.reducers.max=1009

3.计算reducer数的公式

N=min(参数2，总输入数据量/参数1)(参数2 指的是上面的1009，参数1值得是256M)

• 方法二

在hadoop的mapred-default.xml文件中修改，设置每个job的Reduce个数

set mapreduce.job.reduces = 15;

• reduce个数并不是越多越好

过多的启动和初始化reduce也会消耗时间和资源；

有多少个reduce，就会有多少个输出文件，如果生成了很多个小文件，那么如果这些小文件作为下一个任务的输入，则也会出现小文件过多的问题。

6、并行执行

Hive会将一个查询转化成一个或者多个阶段。这样的阶段可以是MapReduce阶段、抽样阶段、合并阶段、limit阶段。或者Hive执行过程中可能需要的其他阶段。默认情况下，Hive一次只会执行一个阶段。

这些阶段可能并非完全互相依赖的，也就是说有些阶段是可以并行执行的，这样可能使得整个job的执行时间缩短。

set hive.exec.parallel=true;              //打开任务并行执行，默认为false
set hive.exec.parallel.thread.number=16;  //同一个sql允许最大并行度，默认为8。

7、严格模式

放置一些危险操作

7.1 分区表不适用分区过滤

hive.strict.checks.no.partition.filter设置为true时，对于分区表，除非where语句中含有分区字段过滤条件来限制范围，否则不允许执行。

进行这个限制的原因是，通常分区表都拥有非常大的数据集，而且数据增加迅速。没有进行分区限制的查询可能会消耗令人不可接受的巨大资源来处理这个表。

7.2 使用order by没有limit

将hive.strict.checks.orderby.no.limit设置为true时，对于使用了order by语句的查询，要求必须使用limit语句。

因为order by为了执行排序过程会将所有的结果数据分发到同一个Reducer中进行处理，强制要求用户增加这个LIMIT语句可以防止Reducer额外执行很长一段时间(开启了limit可以在数据进入到reduce之前就减少一部分数据)。

7.3 笛卡尔积

将hive.strict.checks.cartesian.product设置为true时，会限制笛卡尔积的查询。对关系型数据库非常了解的用户可能期望在执行JOIN查询的时候不使用ON语句而是使用where语句，这样关系数据库的执行优化器就可以高效地将WHERE语句转化成那个ON语句。不幸的是，Hive并不会执行这种优化，因此，如果表足够大，那么这个查询就会出现不可控的情况。

8、JVM重用

和MapReduce中一样，开启一个container，多次重复使用。