第六章 包含多个段的程序

监测点6.1

（1）下面的程序实现依次用内存0:0～0:15单元中的内容改写程序中的数据，完成程序：

assume cs:codesg
codesg segment
  dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
 
start:  
  mov ax,0
  mov ds,ax
  mov bx,0
  mov cx,8
s0:     
  mov ax,[bx]
  （）
  add bx,2
  loop s0
 
  mov ax,4c00h
  int 21h
codesg ends
end start

解：mov cs:[bx],ax

（2）下面的程序实现依次用内存0:0～0:15单元中的内容改写程序中的数据，数据的传送用栈来进行。栈空间设置在程序内。完成程序：

assume cs:codesg
codesg segment
  dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
  dw 0,0,0,0,0,0,0,0,0,0

start:
  mov ax,（）
  mov ss,ax
  mov sp,（）
	  
  mov ax,0
  mov ds,ax
  mov bx,0
  mov cx,8
 s0:  
  push [bx]
  （）
  add bx,2
  loop s0
	
  mov ax,4c00h
  int 21h
codesg ends
end start

解：
mov ax, cs
mov sp, 30H
pop ss[bx]

实验5：编写、调试具体多个段的程序

（1）将下面的程序编译连接，用Debug加载、跟踪，然后回答问题。

assume cs:code,ds:data,ss:stack

data segment
        dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
data ends

stack segment
	dw 0,0,0,0,0,0,0,0 ; 8 word
stack ends

code segment
start:  mov ax,stack
        mov ss,ax
        mov sp,16
        mov ax,data
        mov ds,ax
        push ds:[0]
        push ds:[2]
        pop ds:[2]
        pop ds:[0]
        mov ax,4c00h
        int 21h
code ends

end start

① CPU执行程序，程序返回前，data段中的数据为多少？ 答：data段中的数据没有发生变化。
② CPU执行程序，程序返回前，cs = 076C、ss = 076B、ds = 075A
③ 设程序加载后，CODE段的段地址为X，则data段的段地址为X-2，stack段的段地址X-1

（2）将下面的程序编译连接，用Debug加载、跟踪，然后回答问题。

assume cs:code,ds:data,ss:stack

data segment
    dw 0123h,0456h
data ends

stack segment
    dw 0,0
stack ends

code segment
start:
    mov ax,stack      
    mov ss,ax
    mov sp,16         
    mov ax,data       
    mov ds,ax
    push ds:[0]
    push ds:[2]
    pop ds:[2]
    pop ds:[0]
    mov ax,4c00h
    int 21h
code ends

end start

① CPU执行程序，程序返回前，data段中的数据为多少？ 答：data段中的数据没有发生变化，且其余的12字节都为00
② CPU执行程序，程序返回前，cs = 076C、ss = 076B、ds = 075A
③ 设程序加载后，CODE段的段地址为X，则data段的段地址为（X-2），stack段的段地址（X-1）
④ 对于如下定义的段：

name segment

     ......
     
name ends

如果段中数据位N个字节，程序加载后，该段实际占据空间为？
答：N/16 == 0 ?（N/16后取整数部分）* 16个字节 :（N/16后取整数部分+1）* 16个字节
即：如果段的大小为16的整数倍字节，那么段字节大小则为整数倍*16字节。如果不为，则进行padding，填充段字节大小为16的整数倍。

很多网上给出的公式是（N/16后取整数部分+1）* 16个字节，那么如果数据段有8个字，那么也要多分配16字节么？至少我在测试时，并没有这样多分配了16字节大小。

（3）将下面的程序编译连接，用Debug加载、跟踪，然后回答问题。

assume cs:code,ds:data,ss:stack

code segment
start:
    mov ax,stack      
    mov ss,ax
    mov sp,16         
    mov ax,data       
    mov ds,ax
    push ds:[0]
    push ds:[2]
    pop ds:[2]
    pop ds:[0]
    mov ax,4c00h
    int 21h
code ends

data segment
    dw 0123h,0456h
data ends

stack segment
    dw 0,0
stack ends

end start

① CPU执行程序，程序返回前，data段中的数据为多少？ 答：data段中的数据没有发生变化，且其余的12字节都为00
② CPU执行程序，程序返回前，cs = 076A、ss = 076E、ds = 075D
③ 设程序加载后，code段的段地址为X，则data段的段地址为（X+3），stack段的段地址（X+4）。
那么是如何计算出的？根据cx=44H，得出程序段共为68字节，减去data & stack段的大小得出cs段为36字节，padding后为48字节。
即3*16，且data & stack段都在cs段段后面，那么data段则为（X+3），stack段为（X+4）

（4）如果将(1)、(2)、(3)题中的最后一条伪指令“end start”改为“end”(也就是说不指明程序的入口)，则哪个程序仍然可以正确执行？请说明原因。
如果不指明程序的执行代码段入口，并且使用end替换end start，只有（3）题中程序可以正确的执行。
因为如果不指定执行代码段的入口，程序会从加载进内存的第一个内存单元起开始执行。前二个题中，代码段最定义的为数据 & 栈段。但CPU还是将其当做指令代码进行执行，可以执行，但正确性是错误的。

（5）编写code段中的代码，将a段和b段数据依次相加，结果存入c段

assume cs:code

a segment
    db 1,2,3,4,5,6,7,8
a ends

b segment
    db 1,2,3,4,5,6,7,8
b ends

c segment
    db 0,0,0,0,0,0,0,0
c ends

code segment
start:
	; Write here
	mov ax, a
	mov ds, ax

	mov ax, b
	mov es, ax

	mov bx, 0
	mov cx, 8
s:	
	mov al, ds:[bx]
	add al, es:[bx]
	push ds
	mov dx, c
	mov ds, dx
	mov ds:[bx], al
	pop ds

	inc bx
	loop s

	mov ax,4c00h
	int 21h
code ends

end start

利用ds & es段寄存器存储a & b段的段号。写入结果时，利用stack暂存ds段寄存器存储的a段的段号，写入结束后在对ds重新赋值。

（6）编写code段中代码，用push指令将a段中前8个字型数据逆序存储到b段中。

assume cs:code

a segment   
	dw 1,2,3,4,5,6,7,8,9,0ah,0bh,0ch,0dh,0eh,0fh,0ffh
a ends

b segment   
	dw 0,0,0,0,0,0,0,0
b ends

code segment
start:
        ; Write here
	mov bx, 0
	mov cx, 8

	mov ax, a
	mov ds, ax

	mov ax, b
	mov ss, ax
	mov sp, 10H
s:	
	push ds:[bx]
	add bx, 2
	loop s

	mov ax,4c00h
	int 21h
code ends

end start