用脚本文件，服务管理.bat 操作本机服务

自己编写一个常用的服务操作管理 .bat

可创建服务，开启和停止、删除服务，设置和查看服务描述。简单明了

@echo off

mode con cols=80 lines=30
title 服务管理
color 0f

:begin
@echo.
@echo 请输入[1]用来进入操作windows服务，输入[2]用来创建新的windows服务
set /p select1=请输入:
if /i "%select1%"=="1" goto 1
if /i "%select1%"=="2" goto 2
goto 3
:2
set /p sname=请输入新的windows服务名字:
set /p spath=请输入新服务.exe服务程序所在路径(绝对路径):
sc create %sname% binpath= "%spath%"
goto begin
:3
@echo 此操作无效
goto begin
:1
@echo 请输入您想操作的windwos服务的名字
set /p servicename= 服务名称:

@echo 当前操作的服务为 [%servicename%] ，请输入命令进行更多操作。
@echo 命令操作 示例如下：
@echo.
@echo start			开启正在操作的服务
@echo stop    		停止正在操作的服务
@echo delete  		删除正在操作的服务
@echo text 描述		给正在操作的服务，设置一个描述
@echo qtext			查看正在操作的服务的描述
@echo reset			修改想要操作的服务的名字
@echo cls			清空屏幕
@echo begin			退到初始界面
@echo q			退出程序
@echo.

:input
@echo.
set /p cmdname= 在此处输入您的命令：
if /i "%cmdname%"=="begin" goto begin
if /i "%cmdname%"=="reset" goto reset
if /i "%cmdname%"=="cls" goto clear
if /i "%cmdname%"=="help" goto help
if /i "%cmdname%"=="q" goto end
if /i "%cmdname%"=="start" goto start
if /i "%cmdname%"=="stop" goto stop
if /i "%cmdname%"=="delete" goto delete
if /i "%cmdname%"=="qtext" goto qtext
if /i "%cmdname%"=="text" goto text

goto tip
:reset
set /p servicename= 新的服务名称:
@echo 当前操作的服务为 [%servicename%] ，请输入命令进行更多操作。
goto input
:start
net start %servicename%
goto input
:stop
net stop %servicename%
goto input
:delete
net stop %servicename%
sc delete %servicename%
goto input
:text
set /p ds= 请输入新的描述：
sc description %servicename% %ds%
goto input
:qtext
sc qdescription %servicename%
goto input
:tip
@echo 该命令 [%cmdname%] 无效，请输入[help]查看可用命令。
goto input
:clear
cls
goto input
:end
exit
:help
@echo.
@echo start			开启正在操作的服务
@echo stop    		停止正在操作的服务
@echo delete  		删除正在操作的服务
@echo text 描述		给正在操作的服务，设置一个描述
@echo qtext			查看正在操作的服务的描述
@echo reset			修改想要操作的服务的名字
@echo cls			清空屏幕
@echo begin			退到初始界面
@echo q			退出程序
@echo.
goto input