字符串拼接问题

字符串拼接问题

---

通常我们在使用String的“+”进行字符串连接时会，知道它其实会产生多个String对象，从而使性能变差，所以我们通常比较推荐StringBuffer或StringBuilder的append方法进行字符串连接，但大家知道字符串连接符“+”的底层吗？

---

首先我们编写如下代码，然后在 JDK 1.8 下编译运行和 javap 查看字节码。

public class Test {
    public static void main(String[] args) {
        String result = "";
        result += "other info";
        System.out.println(result);
    }
}

通过 javap 查看编译后情况如下：

$ javap -v Test.class 
......
{
  ......
  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=2, args_size=1
         0: ldc           #2                  // String
         2: astore_1
         3: new           #3                  // class java/lang/StringBuilder
         6: dup
         7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
        10: aload_1
        11: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
        14: ldc           #6                  // String other info
        16: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
        19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
        22: astore_1
        23: getstatic     #8                  // Field java/lang/System.out:Ljava/io/PrintStream;
        26: aload_1
        27: invokevirtual #9                  // Method java/io/PrintStream.println:(Ljava/lang/String;)V
        30: return
      ......
}
......

通过上面字节码可以看到，Java 编译器优化了生成的字节码，自动创建了一个 StringBuilder 并进行了 append 操作。由于构建最终字符串的子字符串在编译时已经可以确定，所以在这种情况下 Java 编译器会进行优化（这种优化称为 a static string concatenation optimization，JDK5 use）。

---

接着我们继续尝试动态拼接字符串（动态拼接字符串指的是仅在运行时才知道最终字符串的子字符串）。如下测试代码：

public class Test {
    public static void main(String[] args) {
        String result = "";
        for (int i = 0; i < 10; i++) {
            result += "other data";
        }
        System.out.println(result);
    }
}

通过 javap 查看编译后情况如下：

......
{
  ......
  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=3, args_size=1
         0: ldc           #2                  // String
         2: astore_1
         3: iconst_0
         4: istore_2
         5: iload_2
         6: bipush        10
         8: if_icmpge     37
        11: new           #3                  // class java/lang/StringBuilder
        14: dup
        15: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
        18: aload_1
        19: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
        22: ldc           #6                  // String other data
        24: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
        27: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
        30: astore_1
        31: iinc          2, 1
        34: goto          5 //重点，又跳回 5 去重新创建新的 StringBuilder
        37: getstatic     #8                  // Field java/lang/System.out:Ljava/io/PrintStream;
        40: aload_1
        41: invokevirtual #9                  // Method java/io/PrintStream.println:(Ljava/lang/String;)V
        44: return
      ......
}
SourceFile: "Test.java"

通过字节码可以看到，在循环过程中并没有达到最优化，反而在不断生成新的 StringBuilder 实例，所以上面的代码在编译后其实类似如下写法：

......
public class Test {
    public static void main(String[] args) {
        /**
        String result = "";
        for (int i = 0; i < 10; i++) {
            result += "other data";
        }
        System.out.println(result);
        */
        //编译后等价如下
        String result = "";
        for (int i = 0; i < 10; i++) {
            StringBuilder tmp = new StringBuilder();
            tmp.append(result);
            tmp.append("other data");
            result = tmp.toString();
        }
        System.out.println(result);
    }
}

可以看到，上面的代码在不断生成新的 StringBuilder 实例，并且通过 toString 方法操作，原来的 StringBuilder 实例将不再引用，作为垃圾回收增加了 GC 成本。

所以，在实际的使用中，当我们无法区分字符串是静态拼接还是动态拼接时建议使用 StringBuilder，如果能区分是静态拼接则用 + 号，反之用 StringBuilder。

---