IDEA自动生成实体类

IDEA根据数据表自动生成实体类

第一次根据需求建了库，写实体类的时候一条条写太过麻烦，于是上网查找了一些资料一劳永逸一下。之前看到过别人使用自动生成的工具，不知道是Navicat自带的还是其他的工具，这次我使用的是idea的工具进行操作，记录一下操作步骤以便后续使用也分享一下。

简单的流程介绍

1. 首先使用IDEA的Database链接数据库
2. 修改Generate POJOs.groovy文件
3. 选择指定的包下生成实体类

具体操作

IDEA顶部菜单栏选择View—Tool Windows—Database

点击Test Connection可以测试链接，进行相关的配置后点击Apply/OK

这时候右侧就可以找到Database的菜单栏了

右键点击一张表，选择Scripted Extensions — Generate POJOs.groovy，在弹出的对话框中选择想要创建实体类的包，点击ok就可以自动生成了

但是！自带的生成格式可能无法满足需求，比方说类名未必符合需求，没有使用Lombok自动生成get/set等方法，也没有生成注解等问题，所以需要修改Generate POJOs.groovy文件，用来自定义生成实体类的样式

同样的右键点击一张表，选择Scripted Extensions — Go To Scripts Directory可以找到生成实体类的相关配置文件，在此包下新建一个配置文件，这里我取名为Generate MyPOJOs.groovy，附上代码

• 此处参考了https://blog.csdn.net/qq_34371461/article/details/80571281/，并在此基础上进行了些许修改，主要修改为：

1. 使用了Lombok的@Data注解来处理get/set等方法，简化了原代码
2. 修改使用@TableName注解来设置对应表名
3. 去除了@Column注解

可以根据个人不同的需求再进行其他的修改

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
typeMapping = [
        (~/(?i)bigint/)      : "Long",
        (~/(?i)tinyint|smallint|mediumint|int/)      : "Integer",
        (~/(?i)bool|bit/)      : "Boolean",
        (~/(?i)float|double|real/)      : "Double",
        (~/(?i)decimal/)      : "BigDecimal",
        (~/(?i)datetime|timestamp|date|time/)      : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/)      : "InputStream",
        (~/(?i)/)      : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaClassName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println "import com.baomidou.mybatisplus.annotation.TableName;"
    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    
	if (types.contains("BigDecimal")) {
        out.println "import java.math.BigDecimal;"
    }
    out.println ""
    out.println "@Data"
    out.println "@TableName(\""+table.getName() +"\")"
    out.println "public class $className implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""
        // 输出注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

//        if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"

        // 输出成员变量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    // 输出get/set方法
//    fields.each() {
//        out.println ""
//        out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
//        out.println "\t\treturn this.${it.name};"
//        out.println "\t}"
//        out.println ""
//
//        out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
//        out.println "\t\tthis.${it.name} = ${it.name};"
//        out.println "\t}"
//    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment()]
//                annos: "\t@Column(name = \""+col.getName()+"\" )"]
//        if("id".equals(Case.LOWER.apply(col.getName())))
//            comm.annos +=["@Id"]
        fields += [comm]
    }
}

// 处理类名（这里是因为我的表都是以t_命名的，所以需要处理去掉生成类名时的开头的T，
// 如果你不需要那么请查找用到了 javaClassName这个方法的地方修改为 javaName 即可）
def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    // 去除开头的T  http://developer.51cto.com/art/200906/129168.htm
    s = s[1..s.size() - 1]
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str

    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

修改后再次右键点击表名，选我们刚刚新建的文件，再选择包进行创建实体类

这次创建的实体类中可以看到使用了Lombok并且表中对应的注解也写了进来，也进行了驼峰命名转换，完美符合了我的需求

至此，问题解决，可以不再为建实体类而发愁了。

PS. 如果有帮助欢迎采用转载