目录
一、集合数据类型应用
Hive 有三种复杂数据类型 ARRAY、MAP 和 STRUCT
案例：1） 假设某表有如下一行，我们用 JSON 格式来表示其数据结构。在 Hive 下访问的格式为：
{
"name": "songsong",
"friends": ["bingbing" , "lili"] , //列表 Array,
"children": { //键值 Map,
"xiao song": 18 ,
"xiaoxiao song": 19
}
"address": { //结构 Struct,
"street": "hui long guan" ,
"city": "beijing"
}
}创建本地测试文件test.txt
//注意：MAP，STRUCT 和 ARRAY 里的元素间关系都可以用同一个字符表示，这里用“_”。
songsong,bingbing_lili,xiao song:18_xiaoxiao song:19,hui long guan_beijing
yangyang,caicai_susu,xiao yang:18_xiaoxiao yang:19,chao yang_beijinghive创建表
create table test(
name string,
friends array<string>,
children map<string, int>,
address struct<street:string, city:string>
)
row format delimited
fields terminated by ',' // 列分隔符
collection items terminated by '_' // MAP STRUCT和ARRAY 的分隔符(数据分割符)
map keys terminated by ':' // MAP 中的 key 与 value 的分隔符
lines terminated by '\n'; // 行分隔符导入文本数据测试
load data local inpath "/root/data/hive/test.txt" into table test;
##查询
select friends[0],children["xiao song"],address.street from test where name="songsong";二、分区表基本操作
1、引入分区表（需要根据日期对日志进行管理）
/root/data/hive/partitioned/20200405.log
/root/data/hive/partitioned/20200406.log
2、创建表
create table ip_count(ip string,username string,count int)
partitioned by (producedate string) #不可以设置关键词的属性 例如 date
row format delimited
fields terminated by '\t';加载数据
load data local inpath '/root/data/hive/partitioned/20200405.log' into table ip_count partition (producedate='20200405');
load data local inpath '/root/data/hive/partitioned/20200406.log' into table ip_count partition (producedate='20200406');存储在HDFS中是分文件夹存放的
查询分区表
#单分区
select * from ip_count where producedate='20200406';
#多分区 会进行MR
select * from ip_count where producedate='20200406'
union
select * from ip_count where producedate='20200405';
#添加单个分区
alter table ip_count add partition(producedate='20200408') ;
#添加多个分区
alter table ip_count
add partition(producedate='20200408') partition(producedate='20200407');
#删除分区 注意：添加多个分区中间空格，删除多个分区中间逗号
alter table ip_count drop partition(producedate='20200408'),partition(producedate='20200407');
#显示所有分区
show partitions ip_count;
#查看分区结构
desc formatted dept_partition;
3、二级分区表
#建表
create table ipc2(ip string,name string,count int)
partitioned by (month string,day string)
row format delimited fields terminated by '\t';
#加载数据（正常方法）
load data local inpath '/root/data/hive/partitioned/20200405.log' into table ipc2 partition(month='202004',day='05');
#查询
select * from ipc2 where month='202004' and day='05';
#方法二，上传数据后修复
#hive内创建文件夹并上传数据
hive (school)> dfs -mkdir -p /user/hive/warehouse/school.db/ipc2/month=202004/day=06;
#路径不加'' or ""
dfs -put /root/data/hive/partitioned/20200406.log /user/hive/warehouse/school.db/ipc2/month=202004/day=06;
#修复表 不然查询不到（分区表hive内dfs -put数据需要修复，hadoop fs -put不用。普通表都不用）
#如果不修复，添加分区也是可以查询到数据的
msck repair table ipc2;
#方法三：创建文件夹后 load 数据到分区，也是不用修复就查询到数据三、行转列、列转行
1、行转列
（1）用到的函数
CONCAT(string A/col, string B/col…)：返回输入字符串连接后的结果，支持任意个输入字符串;
CONCAT_WS(separator, str1, str2,...)：在上个基础上每个字符串中间加个separator分隔符
COLLECT_SET(col)：函数只接受基本数据类型，它的主要作用是将某字段的值进行去重汇总，产生 array 类型字段。
（2）数据准备
| name | xingzuo | xuexing |
| 孙悟空 | 白羊座 | A |
| 猪八戒 | 射手座 | A |
| 沙僧 | 白羊座 | B |
| 白龙马 | 白羊座 | B |
| 唐僧 | 射手座 | A |
（3）需求
把星座和血型一样的人归类到一起。结果如下：
data.hang name
射手座,A 猪八戒|唐僧
白羊座,A 孙悟空
白羊座,B 沙僧|白龙马（4）创建 hive 表并导入数据
create table hang_lie(name string,xingzuo string,xuexing string) row format delimited fields terminated by '\t';
load data local inpath '/root/data/hive/hangzhuanlie.log' into table hang_lie;（5）按需求查询数据
思路：子查询先按 name,（星座+血型）两个字段为一张表，在从中按星座血型为组统计所有name的集合
select data.hang,concat_ws('|',collect_set(data.name)) name
from
(select name,concat(xingzuo,',',xuexing) hang from hang_lie) data
group by data.hang;2、行转列
（1）用到的函数
炸裂函数（将数组炸成每一行）explode(col)：将 hive 一列中复杂的 array 或者 map 结构拆分成多行。
表生成函数，将炸裂后内容进行聚合 lateral view 用法：LATERAL VIEW udtf(expression) tableAlias AS columnAlias，用于和 split, explode 等 UDTF 一起使用，它能够将一列数据拆成多行数据，在此基础上可以对拆分后的数据进行聚合。
（2）数据准备
《疑犯追踪》 悬疑,动作,科幻,剧情
《Lie to me》 悬疑,警匪,动作,心理,剧情
《战狼 2》 战争,动作,灾难（3）需求
将电影分类中的数组数据展开。结果如下：
《疑犯追踪》 悬疑
《疑犯追踪》 动作
《疑犯追踪》 科幻
《疑犯追踪》 剧情
《Lie to me》 悬疑
《Lie to me》 警匪
《Lie to me》 动作
《Lie to me》 心理
《Lie to me》 剧情
《战狼 2》 战争
《战狼 2》 动作
《战狼 2》 灾难（4）创建 hive 表并导入数据
create table movie(name string,category array<string>)
row format delimited
fields terminated by '\t'
collection items terminated by ',';
load data local inpath '/root/data/hive/movie.txt' into table movie;（5）按需求查询数据
lateral view explode(category) A as B; 其中A是生成表的别名，B是列的别名
select name,mv from movie lateral view explode(category) movietmp as mv;
hive (school)> select * from movie lateral view explode(category) movietmp as mv;
OK
movie.name movie.category movietmp.mv
《疑犯追踪》 ["悬疑","动作","科幻","剧情"] 悬疑
《疑犯追踪》 ["悬疑","动作","科幻","剧情"] 动作四、窗口函数
窗口函数是SQL语句最后执行的函数，因此可以把SQL结果集想象成输入数据
（1）相关函数
OVER()：分析函数工作的数据窗口大小，这个数据窗口大小可能会随着行的变化而变化；对前面字段提供的一个独立窗口
CURRENT ROW：当前行；
n PRECEDING：往前 n 行数据；
n FOLLOWING：往后 n 行数据；
UNBOUNDED：起点，UNBOUNDED PRECEDING 表示从前面的起点， UNBOUNDED
FOLLOWING 表示到后面的终点；
LAG(col,n)：往前第 n 行数据；
LEAD(col,n)：往后第 n 行数据；
NTILE(n)：把有序分区中的行分发到指定数据的组中，各个组有编号，编号从 1 开始，对于每一行，NTILE 返回此行所属的组的编号。注意：n 必须为 int 类型。 （用于将分组数据按照顺序切分成n片，返回当前切片值）
（2）数据准备：name，orderdate，cost
jack,2017-01-01,10
tony,2017-01-02,15
jack,2017-02-03,23
tony,2017-01-04,29
jack,2017-01-05,46
jack,2017-04-06,42
tony,2017-01-07,50
jack,2017-01-08,55
mart,2017-04-08,62
mart,2017-04-09,68
neil,2017-05-10,12
mart,2017-04-11,75
neil,2017-06-12,80
mart,2017-04-13,94（3）需求
- a 查询在 2017 年 4 月份购买过的顾客及总人数
- b 查询顾客的购买明细及月购买总额
- c 上述的场景,要将 cost 按照日期进行累加
- d 查询顾客上次的购买时间
- e 查询前 20%时间的订单信息
（4）建表导入数据
create table business(name string,orderdate string,cost int)
row format delimited fields terminated by ',';
load data local inpath '/root/data/hive/chuangkou.txt' into table business;（5）按需求查询数据
查询在 2017 年 4 月份购买过的顾客及总人数
#方法一 over ()表示窗口时所有行
select name,count(*) over ()
from business
where substring(orderdate,1,7) = '2017-04'
group by name;
#方法二
select distinct name,count(*) over()
from business
where orderdate like '2017-04-%';查询顾客的购买明细及月购买总额(月购买总额指的是每个月所有人总消费)
#以月份进行分区，sum求月消费 over (*)表示窗口的条件是*
select name,orderdate,cost,sum(cost)
over(partition by month(orderdate))
from business;上述的场景,要将 cost 按照日期进行累加
select *,sum(cost) over(partition by month(orderdate) order by orderdate) from business;
business.name business.orderdate business.cost sum_window_0
jack 2017-01-01 10 10
tony 2017-01-02 15 25
tony 2017-01-04 29 54
jack 2017-01-05 46 100
tony 2017-01-07 50 150
jack 2017-01-08 55 205
jack 2017-02-03 23 23
jack 2017-04-06 42 42
mart 2017-04-08 62 104
mart 2017-04-09 68 172
mart 2017-04-11 75 247
mart 2017-04-13 94 341
neil 2017-05-10 12 12
neil 2017-06-12 80 80分析：order by子句会让输入的数据强制排序。Order By子句对于诸如Row_Number()，Lead()，LAG()等函数是必须的，因为如果数据无序，这些函数的结果就没有任何意义。因此如果有了Order By子句，则Count()，Min()等计算出来的结果就没有任何意义。
以下是各种场景窗口累加清空
select name,orderdate,cost,
sum(cost) over() as sample1, --所有行相加
sum(cost) over(partition by name) as sample2, --按 name 分组，组内数据相加
sum(cost) over(partition by name order by orderdate) as sample3, --按 name 分组，组内数据累加
sum(cost) over(partition by name order by orderdate rows between
UNBOUNDED PRECEDING and current row ) as sample4 ,--和 sample3 一样,由起点到当前行的聚合
sum(cost) over(partition by name order by orderdate rows between
1 PRECEDING and current row) as sample5, --当前行和前面一行做聚合
sum(cost) over(partition by name order by orderdate rows between
1 PRECEDING AND 1 FOLLOWING ) as sample6,--当前行和前边一行及后面一行
sum(cost) over(partition by name order by orderdate rows between
current row and UNBOUNDED FOLLOWING ) as sample7 --当前行及后面所有行
from business;
name orderdate cost sample1 sample2 sample3 sample4 sample5 sample6 sample7
jack 2017-01-01 10 661 176 10 10 10 56 176
jack 2017-01-05 46 661 176 56 56 56 111 166
jack 2017-01-08 55 661 176 111 111 101 124 120
jack 2017-02-03 23 661 176 134 134 78 120 65
jack 2017-04-06 42 661 176 176 176 65 65 42
mart 2017-04-08 62 661 299 62 62 62 130 299
mart 2017-04-09 68 661 299 130 130 130 205 237
mart 2017-04-11 75 661 299 205 205 143 237 169
mart 2017-04-13 94 661 299 299 299 169 169 94
neil 2017-05-10 12 661 92 12 12 12 92 92
neil 2017-06-12 80 661 92 92 92 92 92 80
tony 2017-01-02 15 661 94 15 15 15 44 94
tony 2017-01-04 29 661 94 44 44 44 94 79
tony 2017-01-07 50 661 94 94 94 79 79 50查询顾客上次的购买时间
LAG和LEAD函数：这两个函数为常用的窗口函数,可以返回上下数据行的数据.以我们的订单表为例,假如我们想要查看顾客上次的购买时间可以这样去查询
select name,orderdate,cost,
lag(orderdate,1,'1900-01-01') over(partition by name order by
orderdate ) as time1, lag(orderdate,2) over (partition by name
order by orderdate) as time2
from business;
name orderdate cost time1 time2
jack 2017-01-01 10 1900-01-01 NULL
jack 2017-01-05 46 2017-01-01 NULL
jack 2017-01-08 55 2017-01-05 2017-01-01
jack 2017-02-03 23 2017-01-08 2017-01-05
jack 2017-04-06 42 2017-02-03 2017-01-08
mart 2017-04-08 62 1900-01-01 NULL
mart 2017-04-09 68 2017-04-08 NULL
mart 2017-04-11 75 2017-04-09 2017-04-08
mart 2017-04-13 94 2017-04-11 2017-04-09
neil 2017-05-10 12 1900-01-01 NULL
neil 2017-06-12 80 2017-05-10 NULL
tony 2017-01-02 15 1900-01-01 NULL
tony 2017-01-04 29 2017-01-02 NULL
tony 2017-01-07 50 2017-01-04 2017-01-02查询前 20%时间的订单信息
# nitile函数
select name,orderdate,cost, ntile(5) over(order by orderdate) sorted from business;
name orderdate cost sorted
jack 2017-01-01 10 1
tony 2017-01-02 15 1
tony 2017-01-04 29 1
jack 2017-01-05 46 2
tony 2017-01-07 50 2
jack 2017-01-08 55 2
jack 2017-02-03 23 3
jack 2017-04-06 42 3
mart 2017-04-08 62 3
mart 2017-04-09 68 4
mart 2017-04-11 75 4
mart 2017-04-13 94 4
neil 2017-05-10 12 5
neil 2017-06-12 80 5
# 查询20%，即1/5
select * from (
select name,orderdate,cost, ntile(5) over(order by orderdate)
sorted
from business
) t
where sorted = 1;五、Rank函数
1、函数说明
RANK() ： 生成数据项在分组中的排名，排名相等会在名次中留下空位，总数不会变 1 1 1 4 5
DENSE_RANK() ： 排序相同时会重复，总数会减少 1 1 1 2 3
ROW_NUMBER() 从1开始，按照顺序，生成分组内记录的序列,row_number()的值不会存在重复 12345
2、数据准备
悟空 语文 87
孙悟空 数学 95
孙悟空 英语 68
大海 语文 94
大海 数学 56
大海 英语 84
宋宋 语文 64
宋宋 数学 86
宋宋 英语 84
婷婷 语文 65
婷婷 数学 85
婷婷 英语 783、需求：计算每门学科成绩排名。
4、建表导入数据
create table score(
name string,
subject string,
score int)
row format delimited fields terminated by "\t";
load data local inpath '/root/data/hive/rank.txt' into table score;5、查询语句
select name,subject,score,
rank() over(partition by subject order by score desc) rp,
dense_rank() over(partition by subject order by score desc) drp,
row_number() over(partition by subject order by score desc) rmp
from score;
name subject score rp drp rmp
孙悟空 数学 95 1 1 1
宋宋 数学 86 2 2 2
婷婷 数学 85 3 3 3
大海 数学 56 4 4 4
宋宋 英语 84 1 1 1
大海 英语 84 1 1 2
婷婷 英语 78 3 2 3
孙悟空 英语 68 4 3 4六、系统内置函数、自定义函数
1、内置函数
#查看系统自带的函数
hive> show functions;
#自带的函数的用法
hive> desc function upper;
#详细显示自带的函数的用法
hive> desc function extended upper;2、自定义函数
当 Hive 提供的内置函数无法满足你的业务处理需要时，可以使用用户自定义函数（UDF：user-defined function）。
根据用户自定义函数类别分为以下三种：
（1）UDF（User-Defined-Function） 一进一出
（2）UDAF（User-Defined Aggregation Function） 聚集函数，多进一出，类似于：count/max/min
（3）UDTF（User-Defined Table-Generating Functions） 一进多出，如 lateral view explore()
3、官方文档
https://cwiki.apache.org/confluence/display/Hive/HivePlugins
4、编程步骤
（1）继承 org.apache.hadoop.hive.ql.UDF
（2）需要实现 evaluate 函数；evaluate 函数支持重载；
（3）在 hive 的命令行窗口创建函数
# a）添加 jar linux_jar_path是jar包在linux的路径
add jar linux_jar_path
# b）创建 function class_name是运行主类
create [temporary] function [dbname.]function_name AS class_name;（4）在 hive 的命令行窗口删除函数
Drop [temporary] function [if exists] [dbname.]function_name;注意：UDF 必须要有返回类型，可以返回 null，但是返回类型不能为 void；
5、自定义 UDF 函数
<dependency>
<groupId>org.apache.hive</groupId>
<artifactId>hive-exec</artifactId>
<version>1.2.1</version>
</dependency>package com.xin;
import org.apache.hadoop.hive.ql.exec.UDF;
/**
* Created by xinBa.
* User: 辛聪明
* Date: 2020/4/13
*/
public class Lower extends UDF {
public String evaluate(String s){
if(s == null) return null;
return s.toLowerCase();
}
}
打成 jar 包上传到服务器
## 将 jar 包添加到 hive 的 classpath
hive (default)> add jar /opt/module/datas/udf.jar;
## 创建临时函数与开发好的 java class 关联
hive (default)> create temporary function mylower as "com.xin.Lower";
## 即可在 hql 中使用自定义的函数
hive (default)> select ename, mylower(ename) lowername from emp;
hive (school)> select mylower('UDF')6、自定义 UDTF 函数
需求分析：自定义一个 UDTF 实现将一个任意分割符的字符串切割成独立的单词，例如：
Line:"hello,world,hadoop,hive"
Myudtf(line, ",")
hello
world
hadoop
hivepackage com.xin;
import org.apache.hadoop.hive.ql.exec.UDFArgumentException;
import org.apache.hadoop.hive.ql.metadata.HiveException;
import org.apache.hadoop.hive.ql.udf.generic.GenericUDTF;
import org.apache.hadoop.hive.serde2.objectinspector.ObjectInspector;
import org.apache.hadoop.hive.serde2.objectinspector.ObjectInspectorFactory;
import org.apache.hadoop.hive.serde2.objectinspector.StructObjectInspector;
import org.apache.hadoop.hive.serde2.objectinspector.primitive.PrimitiveObjectInspectorFactory;
import java.util.ArrayList;
import java.util.List;
/**
* Created by xinBa.
* User: 辛聪明
* Date: 2020/4/14
*/
public class MyUDTF extends GenericUDTF {
private ArrayList<String> array = new ArrayList<String>();
@Override
public StructObjectInspector initialize(StructObjectInspector argOIs) throws UDFArgumentException {
//1.定义添加输出数据的列名和类型
List<String> fieldNames = new ArrayList<String>();
List<ObjectInspector> fieldOIs = new ArrayList<ObjectInspector>();
fieldNames.add("lineToWord"); //hive字段名称，可用别名覆盖
fieldOIs.add(PrimitiveObjectInspectorFactory.javaStringObjectInspector); //字段数据类型
return ObjectInspectorFactory.getStandardStructObjectInspector(fieldNames, fieldOIs);
}
public void process(Object[] args) throws HiveException {
// 获取原始数据
String line = args[0].toString();
// 获取分隔符
String splitWord = args[1].toString();
String[] words = line.split(splitWord);
for(String str : words){
//集合为复用的，首先清空集合
array.clear();
//将每一个单词添加至集合
array.add(str);
//将集合内容写出 GenericUDTF提供的方法
forward(array);
}
}
public void close() throws HiveException {
}
}
select myudtf(line, ",") word from words;七、压缩和储存
1、Hadoop 源码持 编译支持 Snappy 压缩
（1）环境准备安装以下程序：
hadoop-2.7.2-src.tar.gz //将此编译好的文件中/hadoop/lib/native中所有jar包覆盖掉原本的hadoop相对应下文件夹内
jdk-8u144-linux-x64.tar.gz
snappy-1.1.3.tar.gz
apache-maven-3.0.5-bin.tar.gz
protobuf-2.5.0.tar.gz
使用命令 hadoop checknative查看HDFS压缩格式
（2）Hadoop中压缩参数配置
要在 Hadoop 中启用压缩，可以配置如下参数（mapred-site.xml 文件中）：
2、在Hive中启用压缩（不需要hadoop中开启压缩，需要支持压缩。以下语句退出hive后下次打开就失效了）
（2）开启 Map 输出阶段压缩
开启 map 输出阶段压缩可以减少 job 中 map 和 Reduce task 间数据传输量。具体配置如下：
#开启 hive 中间传输数据压缩功能
hive (default)>set hive.exec.compress.intermediate=true;
#开启 mapreduce 中 map 输出压缩功能
hive (default)>set mapreduce.map.output.compress=true;
#设置 mapreduce 中 map 输出数据的压缩方式
hive (default)>set mapreduce.map.output.compress.codec=org.apache.hadoop.io.compress.SnappyCodec;
#执行查询语句
hive (default)> select count(ename) name from emp;（3）开启 Reduce 输出 阶段压缩
当 Hive 将 输 出 写 入 到 表 中 时 ， 输 出 内 容 同 样 可 以 进 行 压 缩 。 属 性hive.exec.compress.output 控制着这个功能。用户可能需要保持默认设置文件中的默认值false，这样默认的输出就是非压缩的纯文本文件了。用户可以通过在查询语句或执行脚本中设置这个值为 true，来开启输出结果压缩功能。
#1．开启 hive 最终输出数据压缩功能
hive (default)>set hive.exec.compress.output=true;
#2．开启 mapreduce 最终输出数据压缩
hive (default)>set
mapreduce.output.fileoutputformat.compress=true;
#3．设置 mapreduce 最终数据输出压缩方式
hive (default)> set mapreduce.output.fileoutputformat.compress.codec =org.apache.hadoop.io.compress.SnappyCodec;
#4．设置 mapreduce 最终数据输出压缩为块压缩
hive (default)> set
mapreduce.output.fileoutputformat.compress.type=BLOCK;
#5．测试一下输出结果是否是压缩文件
hive (default)> insert overwrite local directory
'/opt/module/datas/distribute-result' select * from emp
distribute by deptno sort by empno desc;3、文件存储格式
Hive 支持的存储数的格式主要有：TEXTFILE 、SEQUENCEFILE、ORC、PARQUET。
（1）TEXTFILE
默认格式，建表时不指定默认为这个格式，导入数据时会直接把数据文件拷贝到hdfs上不进行处理。源文件可以直接通过hadoop fs -cat 查看。行存储
（2）SEQUENCEFILE
一种Hadoop API提供的二进制文件，使用方便、可分割、可压缩等特点。SEQUENCEFILE将数据以<key,value>的形式序列化到文件中。序列化和反序列化使用Hadoop 的标准的Writable 接口实现。key为空，用value 存放实际的值， 这样可以避免map 阶段的排序过程。三种压缩选择：NONE, RECORD, BLOCK。 Record压缩率低，一般建议使用BLOCK压缩。
create table if not exists user_info_seq(id bigint,username string,password string,sex string) row format delimited fields terminated by '\t' stored as sequencefile;（3）ORCFile
hive/spark都支持这种存储格式，它存储的方式是采用数据按照行分块，每个块按照列存储，其中每个块都存储有一个索引。特点是数据压缩率非常高，是hive 0.11版里引入的新的存储格式，是对之前的RCFile存储格式的优化.
可以看到每个Orc文件由1个或多个stripe组成，每个stripe250MB大小，这个Stripe实际相当于之前的rcfile里的RowGroup概念，不过大小由4MB->250MB，这样应该能提升顺序读的吞吐率。每个Stripe里有三部分组成，分别是Index Data,Row Data,Stripe Footer
1，Index Data：一个轻量级的index，默认是每隔1W行做一个索引。这里做的索引应该只是记录某行的各字段在Row Data中的offset，据说还包括每个Column的max和min值，具体没细看代码。
2，Row Data：存的是具体的数据，和RCfile一样，先取部分行，然后对这些行按列进行存储。与RCfile不同的地方在于每个列进行了编码，分成多个Stream来存储，具体如何编码在下一篇解析里会讲。
3，Stripe Footer：存的是各个Stream的类型，长度等信息。
create table if not exists user_info_orc(id bigint,username string,password string,sex string) row format delimited fields terminated by '\t' stored as orc;（4）parquet
sparksql默认的输出格式，parquet具有要较快的处理效率显然牺牲点存储(相对于orc格式)但是计算速度可以很大提升，加快响应速度，提供交互式查询 。
Parquet 文件是以二进制方式存储的，所以是不可以直接读取的，文件中包括该文件的数据和元数据，因此 Parquet 格式文件是自解析的。通常情况下，在存储 Parquet 数据的时候会按照 Block 大小设置行组的大小，由于一般情况下每一个 Mapper 任务处理数据的最小单位是一个 Block，这样可以把每一个行组由一个 Mapper 任务处理，增大任务执行并行度。
textfile 存储空间消耗比较大，并且压缩的text 无法分割和合并 查询的效率最低,可以直接存储，加载数据的速度最高
sequencefile 存储空间消耗最大,压缩的文件可以分割和合并 查询效率高
orc 存储空间最小，查询的最高 ，需要通过text文件转化来加载，加载的速度最低（个人建议使用orc）
在实际操作过程中另外2种都需要通过textfile临时存储导入数据
（5）列式存储和行式存储
行存储特点：查询满足条件的一整行数据的时候，列存储则需要去每个聚集的字段找到对应的每个列的值，行存储只需要找到其中一个值，其余的值都在相邻地方，所以此时行存储查询的速度更快。
列存储特点：因为每个字段的数据聚集存储，在查询只需要少数几个字段的时候，能大大减少读取的数据量；每个字段的数据类型一定是相同的，列式存储可以针对性的设计更好的设计压缩算法。
TEXTFILE 和 SEQUENCEFILE 的存储格式都是基于行存储的；
ORC 和 PARQUET 是基于列式存储的。
（6）创建一个非压缩的的 ORC 存储方式
#建表语句
create table log_orc_none(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc tblproperties ("orc.compress"="NONE");
#插入数据
hive (default)> insert into table log_orc_none select * from log_text ;
#查看插入后数据
hive (default)> dfs -du -h /user/hive/warehouse/log_orc_none/;
7.7 M /user/hive/warehouse/log_orc_none/000000_0八、企业级调优
1、Fetch 抓取
Fetch 抓取是指：Hive 中对某些情况的查询可以不必使用 MapReduce 计算。例如：SELECT * FROM employees;在这种情况下，Hive 可以简单地读取 employee 对应的存储目录下的文件，然后输出查询结果到控制台。
在 hive-default.xml.template 文件中 hive.fetch.task.conversion 默认是 more，老版本 hive默认是 minimal，该属性修改为 more 以后，在全局查找、字段查找、limit 查找等都不走mapreduce。
<property>
<name>hive.fetch.task.conversion</name>
<value>more</value>
<description>
Expects one of [none, minimal, more].
Some select queries can be converted to single FETCH task minimizing latency.
Currently the query should be single sourced not having any subquery and should not have
any aggregations or distincts (which incurs RS), lateral views and joins.
0. none : disable hive.fetch.task.conversion
1. minimal : SELECT STAR, FILTER on partition columns, LIMIT only
2. more : SELECT, FILTER, LIMIT only (support TABLESAMPLE and virtual columns)
</description>
</property>2、本地模式
大多数的 Hadoop Job 是需要 Hadoop 提供的完整的可扩展性来处理大数据集的。不过，有时 Hive 的输入数据量是非常小的。在这种情况下，为查询触发执行任务消耗的时间可能会比实际 job 的执行时间要多的多。对于大多数这种情况，Hive 可以通过本地模式在单台机器上处理所有的任务。对于小数据集，执行时间可以明显被缩短。
用户可以通过设置 hive.exec.mode.local.auto 的值为 true，来让 Hive 在适当的时候自动启动这个优化。
#开启本地 mr
set hive.exec.mode.local.auto=true;
#设置 local mr 的最大输入数据量，当输入数据量小于这个值时采用 local mr 的方式，默认为 134217728，即 128M
set hive.exec.mode.local.auto.inputbytes.max=50000000;
#设置 local mr 的最大输入文件个数，当输入文件个数小于这个值时采用 local mr的方式，默认为 4
set hive.exec.mode.local.auto.input.files.max=10;3、表的优化
（1）小表、大表 Join
将 key 相对分散，并且数据量小的表放在 join 的左边，这样可以有效减少内存溢出错误发生的几率；再进一步，可以使用 map join 让小的维度表（1000 条以下的记录条数）先进内存。在 map 端完成 reduce。
实际测试发现：新版的 hive 已经对小表 JOIN 大表和大表 JOIN 小表进行了优化。小表放在左边和右边已经没有明显区别。
（2）大表 Join 大表
有时 join 超时是因为某些 key 对应的数据太多，而相同 key 对应的数据都会发送到相同的 reducer 上，从而导致内存不够。此时我们应该仔细分析这些异常的 key，很多情况下，这些 key 对应的数据是异常数据，我们需要在 SQL 语句中进行过滤。例如 key 对应的字段为空，操作如下：
案例实操：
1）配置历史服务器，配置 mapred-site.xml
<property>
<name>mapreduce.jobhistory.address</name>
<value>hdp-1:10020</value>
</property>
<property>
<name>mapreduce.jobhistory.webapp.address</name>
<value>hdp-1:19888</value>
</property>2）启动历史服务器
sbin/mr-jobhistory-daemon.sh start historyserver查看 jobhistory
http://hdp-1:19888/jobhistory
3）join的时候过滤空id
insert overwrite table jointable
select n.* from (select * from nullidtable where id is not null )
n left join ori o on n.id = o.id;4）join的时候转换空id
有时虽然某个 key 为空对应的数据很多，但是相应的数据不是异常数据，必须要包含在join 的结果中，此时我们可以表 a 中 key 为空的字段赋一个随机的值，使得数据随机均匀地分不到不同的 reducer 上。
insert overwrite table jointable
select n.* from nullidtable n full join ori o on
case when n.id is null then concat('hive', rand()) else n.id end
= o.id;（3）MapJoin
如果不指定 MapJoin 或者不符合 MapJoin 的条件，那么 Hive 解析器会将 Join 操作转换成 Common Join，即：在 Reduce 阶段完成 join。容易发生数据倾斜。可以用 MapJoin 把小表全部加载到内存在 map 端进行 join，避免 reducer 处理。
1）开启 MapJoin 参数设置
#设置自动选择 MapJoin
set hive.auto.convert.join = true; 默认为 true
#大表小表的阈值设置（默认 25M 一下认为是小表）：
set hive.mapjoin.smalltable.filesize=25000000;（4）Group By
默认情况下，Map 阶段同一 Key 数据分发给一个 reduce，当一个 key 数据过大时就倾斜了。
并不是所有的聚合操作都需要在 Reduce 端完成，很多聚合操作都可以先在 Map 端进行部分聚合，最后在 Reduce 端得出最终结果。
1）开启 Map 端聚合参数设置
#是否在 Map 端进行聚合，默认为 True
hive.map.aggr = true
#在 Map 端进行聚合操作的条目数目
hive.groupby.mapaggr.checkinterval = 100000
#有数据倾斜的时候进行负载均衡（默认是 false）
hive.groupby.skewindata = true当选项设定为 true，生成的查询计划会有两个 MR Job。第一个 MR Job 中，Map 的输出结果会随机分布到 Reduce 中，每个 Reduce 做部分聚合操作，并输出结果，这样处理的结果是相同的 Group By Key 有可能被分发到不同的 Reduce 中，从而达到负载均衡的目的；第二个 MR Job 再根据预处理的数据结果按照 Group By Key 分布到 Reduce 中（这个过程可以保证相同的 Group By Key 被分布到同一个 Reduce 中），最后完成最终的聚合操作。
（5）Count(Distinct) 去重统计
数据量小的时候无所谓，数据量大的情况下，由于 COUNT DISTINCT 操作需要用一个Reduce Task 来完成，这一个 Reduce 需要处理的数据量太大，就会导致整个 Job 很难完成，一般 COUNT DISTINCT 使用先 GROUP BY 再 COUNT 的方式替换：采用 GROUP by 去重 id
hive (default)> select count(id) from (select id from bigtable group by id) a;总结：count和distinc操作只有一个reducer，子查询用到group by则是多个reducer。虽然会多用一个 Job 来完成，但在数据量大的情况下，这个绝对是值得的。
（6）笛卡尔积
尽量避免笛卡尔积，join 的时候不加 on 条件，或者无效的 on 条件，Hive 只能使用 1个 reducer 来完成笛卡尔积。
（7）行列过滤
列处理：在 SELECT 中，只拿需要的列，如果有，尽量使用分区过滤，少用 SELECT *。
行处理：在分区剪裁中，当使用外关联时，如果将副表的过滤条件写在 Where 后面，那么就会先全表关联，之后再过滤
（8）动态分区调整
关系型数据库中，对分区表 Insert 数据时候，数据库自动会根据分区字段的值，将数据插入到相应的分区中，Hive 中也提供了类似的机制，即动态分区(Dynamic Partition)，只不过，使用 Hive 的动态分区，需要进行相应的配置。
#开启动态分区功能（默认 true，开启）
set hive.exec.dynamic.partition=true
#设置为非严格模式（动态分区的模式，默认 strict，表示必须指定至少一个分区为静态分区，nonstrict 模式表示允许所有的分区字段都可以使用动态分区。）
set hive.exec.dynamic.partition.mode=nonstrict
#在所有执行 MR 的节点上，最大一共可以创建多少个动态分区。
set hive.exec.max.dynamic.partitions=1000
#在每个执行 MR 的节点上，最大可以创建多少个动态分区。该参数需要根据实际的数据来设定。比如：源数据中包含了一年的数据，即 day 字段有 365 个值，那么该参数就需要设置成大于 365，如果使用默认值 100，则会报错。
set hive.exec.max.dynamic.partitions.pernode=100
#整个 MR Job 中，最大可以创建多少个 HDFS 文件。
set hive.exec.max.created.files=100000
#当有空分区生成时，是否抛出异常。一般不需要设置。
set hive.error.on.empty.partition=false九、MR 优化
1、合理的设置map数量
1 ）通常情况下，作业会通过 input 的目录个 产生一个或者多个 map 任务。
主要的决定因素有：input 的文件总个数，input 的文件大小，集群设置的文件块大小。
2 ）是不是 map 数越多越好？
答案是否定的。如果一个任务有很多小文件（远远小于块大小 128m），则每个小文件也会被当做一个块，用一个 map 任务来完成，而一个 map 任务启动和初始化的时间远远大于逻辑处理的时间，就会造成很大的资源浪费。而且，同时可执行的 map 数是受限的。
3 ）是不是保证每个 map 处理接近 近 128m 的文件块，就高枕无忧了？
答案也是不一定。比如有一个 127m 的文件，正常会用一个 map 去完成，但这个文件只有一个或者两个小字段，却有几千万的记录，如果 map 处理的逻辑比较复杂，用一个 map任务去做，肯定也比较耗时。针对上面的问题 2 和 3，我们需要采取两种方式来解决：即减少 map 数和增加 map 数；
2、小文件进 行合并
在 map 执行前合并小文件，减少 map 数：CombineHiveInputFormat 具有对小文件进行合并的功能（系统默认的格式）。HiveInputFormat 没有对小文件合并功能。
set hive.input.format=org.apache.hadoop.hive.ql.io.CombineHiveInputFormat;3、复杂文件增加 Map 数
当 input 的文件都很大，任务逻辑复杂，map 执行非常慢的时候，可以考虑增加 Map数，来使得每个 map 处理的数据量减少，从而提高任务的执行效率。增加 map 的方法为：根据
computeSliteSize(Math.max(minSize,Math.min(maxSize,blocksize)))=blocksize=128M 公式，调整 maxSize 最大值。让maxSize 最大值低于 blocksize 就可以增加 map 的个数。
#设置切片最大值为100个字节
set mapreduce.input.fileinputformat.split.maxsize=100;4、合理设置 Reduce 数
（1）调整 reduce 个数方法一
#每个 Reduce 处理的数据量默认是 256MB
hive.exec.reducers.bytes.per.reducer=256000000
#每个任务最大的 reduce 数，默认为 1009
hive.exec.reducers.max=1009
#计算 reducer 数的公式
N=min(参数 2，总输入数据量/参数 1)（2）调整 reduce 个数方法二
在 hadoop 的 mapred-default.xml 文件中修改
#设置每个 job 的 Reduce 个数
set mapreduce.job.reduces = 15;（3）reduce 个数并不是越多越好
1）过多的启动和初始化 reduce 也会消耗时间和资源；
2）另外，有多少个 reduce，就会有多少个输出文件，如果生成了很多个小文件，那么如果这些小文件作为下一个任务的输入，则也会出现小文件过多的问题；在设置 reduce 个数的时候也需要考虑这两个原则：处理大数据量利用合适的 reduce 数；使单个 reduce 任务处理数据量大小要合适；
5、并行执行
Hive 会将一个查询转化成一个或者多个阶段。这样的阶段可以是 MapReduce 阶段、抽样阶段、合并阶段、limit 阶段。或者 Hive 执行过程中可能需要的其他阶段。默认情况下，Hive 一次只会执行一个阶段。不过，某个特定的 job 可能包含众多的阶段，而这些阶段可能并非完全互相依赖的，也就是说有些阶段是可以并行执行的，这样可能使得整个 job 的执行时间缩短。不过，如果有更多的阶段可以并行执行，那么 job 可能就越快完成。通过设置参数 hive.exec.parallel 值为 true，就可以开启并发执行。不过，在共享集群中，需要注意下，如果 job 中并行阶段增多，那么集群利用率就会增加。
#打开任务并行执行
set hive.exec.parallel=true;
#同一个 sql 允许最大并行度，默认为 8。
set hive.exec.parallel.thread.number=16; 当然，得是在系统资源比较空闲的时候才有优势，否则，没资源，并行也起不来。
6、严格模式
Hive 提供了严格模式，可以防止用户执行那些可能意想不到的不好的影响的查询。通过设置属性 hive.mapred.mode 值为默认是非严格模式 nonstrict 。开启严格模式需要修改 hive.mapred.mode 值为 strict，开启严格模式可以禁止 3 种类型的查询。
<property>
<name>hive.mapred.mode</name>
<value>strict</value>
<description>
The mode in which the Hive operations are being performed.
In strict mode, some risky queries are not allowed to run. They
include:
Cartesian Product.
No partition being picked up for a query.
Comparing bigints and strings.
Comparing bigints and doubles.
Orderby without limit.
</description>
</property>（1）对于分区表，除非 where 语句中含有分区字段过滤条件来限制范围，否则不允许执行。换句话说，就是用户不允许扫描所有分区。进行这个限制的原因是，通常分区表都拥有非常大的数据集，而且数据增加迅速。没有进行分区限制的查询可能会消耗令人不可接受的巨大资源来处理这个表。
（2) 对于使用了 order by 语句的查询，要求必须使用 limit 语句。因为 order by 为了执行排序过程会将所有的结果数据分发到同一个 Reducer 中进行处理，强制要求用户增加这个LIMIT 语句可以防止 Reducer 额外执行很长一段时间。
（3) 限制笛卡尔积的查询。对关系型数据库非常了解的用户可能期望在执行 JOIN 查询的时候不使用 ON 语句而是使用 where 语句，这样关系数据库的执行优化器就可以高效地将WHERE 语句转化成那个 ON 语句。不幸的是，Hive 并不会执行这种优化，因此，如果表足够大，那么这个查询就会出现不可控的情况。
十、JVM 重用
JVM 重用是 Hadoop 调优参数的内容，其对 Hive 的性能具有非常大的影响，特别是对于很难避免小文件的场景或 task 特别多的场景，这类场景大多数执行时间都很短。Hadoop 的默认配置通常是使用派生 JVM 来执行 map 和 Reduce 任务的。这时 JVM 的启动过程可能会造成相当大的开销，尤其是执行的job包含有成百上千task任务的情况。JVM重用可以使得 JVM 实例在同一个 job 中重新使用 N 次。N 的值可以在 Hadoop 的mapred-site.xml 文件中进行配置。通常在 10-20 之间，具体多少需要根据具体业务场景测试得出。
<property>
<name>mapreduce.job.jvm.numtasks</name>
<value>10</value>
<description>
How many tasks to run per jvm. If set to -1, there is no limit.
</description>
</property>这个功能的缺点是，开启 JVM 重用将一直占用使用到的 task 插槽，以便进行重用，直到任务完成后才能释放。如果某个“不平衡的”job 中有某几个 reduce task 执行的时间要比其他 Reduce task 消耗的时间多的多的话，那么保留的插槽就会一直空闲着却无法被其他的 job使用，直到所有的 task 都结束了才会释放。
十一、推测执行
在分布式集群环境下，因为程序 Bug（包括 Hadoop 本身的 bug），负载不均衡或者资源分布不均等原因，会造成同一个作业的多个任务之间运行速度不一致，有些任务的运行速度可能明显慢于其他任务（比如一个作业的某个任务进度只有 50%，而其他所有任务已经运行完毕），则这些任务会拖慢作业的整体执行进度。为了避免这种情况发生，Hadoop 采用了推测执行（Speculative Execution）机制，它根据一定的法则推测出“拖后腿”的任务，并为这样的任务启动一个备份任务，让该任务与原始任务同时处理同一份数据，并最终选用最先成功运行完成任务的计算结果作为最终结果。
设置开启推测执行参数：Hadoop 的 mapred-site.xml 文件中进行配置
<property>
<name>mapreduce.map.speculative</name>
<value>true</value>
<description>
If true, then multiple instances of some map tasks may be executed in parallel.
</description>
</property>
<property>
<name>mapreduce.reduce.speculative</name>
<value>true</value>
<description>
If true, then multiple instances of some reduce tasks may be executed in parallel.</description>
</property>不过 hive 本身也提供了配置项来控制 reduce-side 的推测执行：
<property>
<name>hive.mapred.reduce.tasks.speculative.execution</name>
<value>true</value>
<description>
Whether speculative execution for reducers should be turned on.
</description>
</property>关于调优这些推测执行变量，还很难给一个具体的建议。如果用户对于运行时的偏差非常敏感的话，那么可以将这些功能关闭掉。如果用户因为输入数据量很大而需要执行长时间的 map 或者 Reduce task 的话，那么启动推测执行造成的浪费是非常巨大大。
十二、 执行计划（Explain ）
1．基本语法
EXPLAIN [EXTENDED | DEPENDENCY | AUTHORIZATION] query
2．案例实操
#查看下面这条语句的执行计划
hive (default)> explain select * from emp;
hive (default)> explain select deptno, avg(sal) avg_sal from emp group by deptno;
#查看详细执行计划
hive (default)> explain extended select * from emp;
hive (default)> explain extended select deptno, avg(sal) avg_sal from emp group by deptno;
3920
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
