冬天OS（二）：go to protected mod

最新推荐文章于 2021-03-13 13:47:23 发布

sssnial-jz

最新推荐文章于 2021-03-13 13:47:23 发布

阅读量154

点赞数

分类专栏： WinterOS（写个操作系统）文章标签：记事本写程序

本文链接：https://blog.csdn.net/qq_42306471/article/details/103303280

版权

WinterOS（写个操作系统）专栏收录该内容

40 篇文章 2 订阅

订阅专栏

--------------------------------------------------------

加载 kennel

进入保护模式

--------------------------------------------------------

上一节我们已经进入 loader 里执行了，但那时的 loader 不具备什么功能，现在我们需要通过 loader 将 kernel 加载到内存，然后进入保护模式！

一，让 loader 加载 kernel
boot 加载 loader 和 loader 加载kernel 基本相同！

; ----------------------------
; <loader.asm>
; Jack Zheng 11.26
; ----------------------------

...

; ----------------------------
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
    cmp word [wRootDirSizeForLoop], 0       ; ┓
    jz  LABEL_NO_KERNELBIN                  ; ┣ 判断根目录区是不是已经读完, 如果读完表示没有找到 KERNEL.BIN
    dec word [wRootDirSizeForLoop]          ; ┛
    mov ax, BaseOfKernelFile
    mov es, ax                              ; es <- BaseOfKernelFile
    mov bx, OffsetOfKernelFile              ; bx <- OffsetOfKernelFile  于是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
    mov ax, [wSectorNo]                     ; ax <- Root Directory 中的某 Sector 号
    mov cl, 1
    call    ReadSector

    mov si, KernelFileName                  ; ds:si -> "KERNEL  BIN"
    mov di, OffsetOfKernelFile              ; es:di -> BaseOfKernelFile:???? = BaseOfKernelFile*10h+????
    cld
    mov dx, 10h
LABEL_SEARCH_FOR_KERNELBIN:
    cmp dx, 0                               ; ┓
    jz  LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR  ; ┣ 循环次数控制, 如果已经读完了一个 Sector, 就跳到下一个 Sector
    dec dx                                  ; ┛
    mov cx, 11
LABEL_CMP_FILENAME:
    cmp cx, 0                               ; ┓
    jz  LABEL_FILENAME_FOUND                ; ┣ 循环次数控制, 如果比较了 11 个字符都相等, 表示找到
    dec cx                                  ; ┛
    lodsb                                   ; ds:si -> al
    cmp al, byte [es:di]                    ; if al == es:di
    jz  LABEL_GO_ON
    jmp LABEL_DIFFERENT
LABEL_GO_ON:
    inc di
    jmp LABEL_CMP_FILENAME                  ;   继续循环

LABEL_DIFFERENT:
    and di, 0FFE0h                          ; else┓ 这时di的值不知道是什么, di &= e0 为了让它是 20h 的倍数
    add di, 20h                             ;     ┃
    mov si, KernelFileName                  ;     ┣ di += 20h  下一个目录条目
    jmp LABEL_SEARCH_FOR_KERNELBIN          ;   ┛

LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
    add word [wSectorNo], 1
    jmp LABEL_SEARCH_IN_ROOT_DIR_BEGIN

LABEL_NO_KERNELBIN:
    mov dh, 2                               ; "No KERNEL."
    call    DispStr                         ; 显示字符串
    jmp $                                   ; 没有找到 KERNEL.BIN, 死循环在这里

LABEL_FILENAME_FOUND:                       ; 找到 KERNEL.BIN 后便来到这里继续
    mov ax, RootDirSectors
    and di, 0FFF0h                          ; di -> 当前条目的开始

    push    eax
    mov eax, [es : di + 01Ch]               ; ┓
    mov dword [dwKernelSize], eax           ; ┛保存 KERNEL.BIN 文件大小
    pop eax

    add di, 01Ah                            ; di -> 首 Sector
    mov cx, word [es:di]
    push    cx                              ; 保存此 Sector 在 FAT 中的序号
    add cx, ax
    add cx, DeltaSectorNo                   ; 这时 cl 里面是 LOADER.BIN 的起始扇区号 (从 0 开始数的序号)
    mov ax, BaseOfKernelFile
    mov es, ax                              ; es <- BaseOfKernelFile
    mov bx, OffsetOfKernelFile              ; bx <- OffsetOfKernelFile  于是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
    mov ax, cx                              ; ax <- Sector 号

LABEL_GOON_LOADING_FILE:
    push    ax                              ; ┓
    push    bx                              ; ┃
    mov ah, 0Eh                             ; ┃ 每读一个扇区就在 "Loading  " 后面打一个点, 形成这样的效果:
    mov al, '.'                             ; ┃
    mov bl, 0Fh                             ; ┃ Loading ......
    int 10h                                 ; ┃
    pop bx                                  ; ┃
    pop ax                                  ; ┛

    mov cl, 1
    call    ReadSector
    pop ax                                  ; 取出此 Sector 在 FAT 中的序号
    call    GetFATEntry
    cmp ax, 0FFFh
    jz  LABEL_FILE_LOADED
    push    ax                              ; 保存 Sector 在 FAT 中的序号
    mov dx, RootDirSectors
    add ax, dx
    add ax, DeltaSectorNo
    add bx, [BPB_BytsPerSec]
    jmp LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:
; ----------------------------

...

; ----------------------------
; <kernel>
; Jack Zheng 11.26
; ----------------------------
[section .text]

global  _start
_start:

    mov ax, 0fh
    mov al, 'K'
    mov [gs:(80 * 6)], ax
    jmp $

刚开始没有 kernel 文件：

我们往软盘写入 kernel文件：

可以看到已经加载内核文件到内存了！

二，进入保护模式
我们不可能让我们的 OS 全程运行在 real mod 下，而要让它进入 protect mod ，protect mod 不只提供了大的地址空间，而且提供了严格的特权级保护和强大的虚拟内存机制，因此，接下来就让我们进入保护机制...
·需要注意的是下面 GDT 表中 flatc 和 flatrw 描述符的段基址都是 0 ，因为我们知道程序中每一个标号在 4G 内存的具体位置，所以：【0 + 标号线性地址】就可以了！只有在不知道程序具体位置时，才会【段基址 = 程序内标号的线性地址】，然后使用【段基址 + 0 】来访问程序内的标号！

; ----------------------------
; <pm.inc>
; Jack Zheng 11.26
; ----------------------------

; usage: Descriptor Base, Limit, Attr
;        Base:  dd
;        Limit: dd (low 20 bits available)
;        Attr:  dw (lower 4 bits of higher byte are always 0)
%macro Descriptor 3
    dw  %2 & 0FFFFh             		; 段界限 1             (2 字节)
    dw  %1 & 0FFFFh             		; 段基址 1             (2 字节)
    db  (%1 >> 16) & 0FFh           		; 段基址 2             (1 字节)
    dw  ((%2 >> 8) & 0F00h) | (%3 & 0F0FFh) 	; 属性 1 + 段界限 2 + 属性 2       (2 字节)
    db  (%1 >> 24) & 0FFh           		; 段基址 3             (1 字节)
%endmacro ; 共 8 字节

; usage: Gate Selector, Offset, DCount, Attr
;        Selector:  dw
;        Offset:    dd
;        DCount:    db
;        Attr:      db
%macro Gate 4
    dw  (%2 & 0FFFFh)               		; 偏移 1              (2 字节)
    dw  %1                  			; 选择子               (2 字节)
    dw  (%3 & 1Fh) | ((%4 << 8) & 0FF00h)   	; 属性                    (2 字节)
    dw  ((%2 >> 16) & 0FFFFh)           	; 偏移 2              (2 字节)
%endmacro ; 共 8 字节

; ----------------------------
; <loader.asm>
; Jack Zheng 11.26
; ----------------------------

...

; ---------------------------
    lgdt    [GdtPtr]
    
    cli                                     ; 关中断

    in  al, 92h                             ; 打开地址线A20
    or  al, 00000010b
    out 92h, al

    mov eax, cr0                            ; 准备切换到保护模式
    or  eax, 1
    mov cr0, eax

    ; ----
    ; 真正进入保护模式
    ; ----
    jmp dword SelectorFlatC:(BaseOfLoaderPhyAddr+LABEL_PM_START)

    jmp $
; ---------------------------

...

; ---------------------------
; 保护模式入口
; ---------------------------
[SECTION .s32]
ALIGN   32
[BITS   32]
LABEL_PM_START:
    mov ax, SelectorVideo
    mov gs, ax
    mov ax, SelectorFlatRW
    mov ds, ax
    mov es, ax
    mov fs, ax
    mov ss, ax
    mov esp, TopOfStack

    mov ah, 0Fh             ; 0000: 黑底    1111: 白字
    mov al, 'P'
    mov [gs:(80 * 10)], ax  ; 屏幕第 0 行, 第 39 列。
    jmp $
; ---------------------------

...

; GDT ----------------------------
LABEL_GDT:              Descriptor             0,                    0, 0                                   ; 空描述符
LABEL_DESC_FLAT_C:      Descriptor             0,              0fffffh, DA_CR  | DA_32 | DA_LIMIT_4K        ; 0 ~ 4G
LABEL_DESC_FLAT_RW:     Descriptor             0,              0fffffh, DA_DRW | DA_32 | DA_LIMIT_4K        ; 0 ~ 4G
LABEL_DESC_VIDEO:       Descriptor       0B8000h,               0ffffh, DA_DRW | DA_DPL3                    ; 显存首地址
; GDT ----------------------------

GdtLen  equ $ - LABEL_GDT
GdtPtr  dw  GdtLen - 1                          ; 段界限
        dd  BaseOfLoaderPhyAddr + LABEL_GDT     ; 基地址

; GDT 选择子 ----------------------------
SelectorFlatC       equ LABEL_DESC_FLAT_C   - LABEL_GDT
SelectorFlatRW      equ LABEL_DESC_FLAT_RW  - LABEL_GDT
SelectorVideo       equ LABEL_DESC_VIDEO    - LABEL_GDT + SA_RPL3
; GDT 选择子 ----------------------------

...

; ----------------------------
; <fat12hdr.inc>
; Jack Zheng 11.26
; ----------------------------
BS_OEMName      DB 'ForrestY'   ; OEM String, 必须 8 个字节

BPB_BytsPerSec  DW 512          ; 每扇区字节数
BPB_SecPerClus  DB 1            ; 每簇多少扇区
BPB_RsvdSecCnt  DW 1            ; Boot 记录占用多少扇区
BPB_NumFATs     DB 2            ; 共有多少 FAT 表
BPB_RootEntCnt  DW 224          ; 根目录文件数最大值
BPB_TotSec16    DW 2880         ; 逻辑扇区总数
BPB_Media       DB 0xF0         ; 媒体描述符
BPB_FATSz16     DW 9            ; 每FAT扇区数
BPB_SecPerTrk   DW 18           ; 每磁道扇区数
BPB_NumHeads    DW 2            ; 磁头数(面数)
BPB_HiddSec     DD 0            ; 隐藏扇区数
BPB_TotSec32    DD 0            ; 如果 wTotalSectorCount 是 0 由这个值记录扇区数

BS_DrvNum       DB 0            ; 中断 13 的驱动器号
BS_Reserved1    DB 0            ; 未使用
BS_BootSig      DB 29h          ; 扩展引导标记 (29h)
BS_VolID        DD 0            ; 卷序列号
BS_VolLab       DB 'Tinix0.01  '; 卷标, 必须 11 个字节
BS_FileSysType  DB 'FAT12   '   ; 文件系统类型, 必须 8个字节 

; ----------------------------
; 基于 FAT12 头的一些常量定义，如果头信息改变，下面的常量可能也要做相应改变
; ----------------------------
FATSz                   equ 9   ; BPB_FATSz16
RootDirSectors          equ 14  ; 根目录占用空间: RootDirSectors = ((BPB_RootEntCnt * 32) + (BPB_BytsPerSec – 1)) / BPB_BytsPerSec; 但如果按照此公式代码过长
SectorNoOfRootDirectory equ 19  ; Root Directory 的第一个扇区号    = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz)
SectorNoOfFAT1          equ 1   ; FAT1 的第一个扇区号  = BPB_RsvdSecCnt
DeltaSectorNo           equ 17

可以看到，屏幕打印出了 P ，进入了保护模式！

前面我们已经将 kernel 加载进内存了，那是因为我们打算在进入保护模式之后将 CPU 的控制权交给它，所以下一节我们就 jmp到 kernel ...

sssnial-jz

关注

0
点赞
踩
0

收藏

觉得还不错? 一键收藏
打赏
0
评论
冬天OS（二）：go to protected mod

--------------------------------------------------------加载 kennel进入保护模式--------------------------------------------------------上一节我们已经进入 loader 里执行了，但那时的 loader 不具备什么功能，现在我们需要通过 loader 将 ke...
复制链接

扫一扫