汇编语言第三版（王爽著）(第六章.包含多个段的程序)

前导

在操作系统的环境中，合法地通过操作系统取得的空间都是安全的，因为操作系统不会让一个程序所用的空间和其他程序以及系统自己的空间相冲突。在操作系统允许的情况下，程序可以取得任意容量的空间
程序取得所需空间的方法有两种，一是在加载程序的时候为程序分配，再就是程序在执行的过程中向系统申请。

6.1 在代码段中使用数据

为了使程序在编译、链接后可以在系统中直接运行，我们可以在源程序中指明程序的入口所在。

assume cs:code
code segment
dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
start:mov bx,0
mov ax,0
mov cx,8
s:add ax,cs:[bx]
add bx,2
loop s
mov ax,4c00h
int 21h
code ends
end start
**end的作用：**除了通知编译器程序的结束外，还可以通知编译器程序的入口在什么地方。
可执行文件由描述信息和程序组成。当程序被加载入内存之后，加载者从程序的可执行文件的描述信息中读到程序的入口地址，设置CS:IP。这样CPU就从我们希望的地址处开始执行。
当前程序框架：
assume cs:code
code segment
数据
start:
代码
code ends
end start

6.2 在代码段中使用栈

利用栈，将程序中定义的数据逆序存放
assume cs:codesg
codesg segment
dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
start:mov ax,cs
mov ss,ax
mov sp,30h
mov bx,0
mov cx,8
s:push cs:[bx]
inc bx
inc bx
loop s
mov bx,0
mov cx,8
s0:pop cs:[bx]
inc bx
inc bx
loop s0
mov ax,4c00h
int 21h
codesg ends
end start

检测点6.1
1.mov cs:[bx],ax
2.cs 24h pop cs:[bx]
assume cs:codesg
codesg segment
dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
dw 0,0,0,0,0,0,0,0,0,0
start:mov ax,cs
mov ss,ax
mov sp,24h
mov ax,0
mov ds,ax
mov bx,0
mov cx,8
s:push [bx]
pop cs:[bx]
add bx,2
loop s
mov ax,4c00h
int 21h
codesg ends
end start

6.3 将数据、代码、栈放入不同的段

在8086模式中，一个段的内容不能大于64KB，所以定义多个段
8086CPU不允许将一个数值直接送入段寄存器中。
mov ax,data
mov ds,ax
不能 mov ds,data
实现逆序存放数据
assume cs:code,ds:data,ss:stack
data segment
dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
data ends

stack segment
dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
stack ends

code segment
start:mov ax,stack
mov ss,ax
mov sp,20h
mov ax,data
mov ds,ax
mov bx,0
mov cx,8
s:push [bx]
add bx,2
loop s
mov bx,0
mov cx,8
s0:pop [bx]
add bx,2
loop s0

mov ax,4c00h
int 21h
code ends
end start