win10bat脚本配置dhcp获取IP和静态配置IP

以管理员身份运行此bat文件
1.使用文件中配置好的IP进行配置
2.将网卡设置为dhcp获取IP
3.交互式配置IP

@echo off
rem //设置变量 
set NAME="以太网"
rem //以下属性值可以根据需要更改
set ADDR=192.168.8.184
set MASK=255.255.255.0
set GATEWAY=192.168.8.108
set DNS1=114.114.114.114
set DNS2=
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS


echo 当前可用操作有：
echo 1 设置为静态IP
echo 2 设置为动态IP
echo 3 交互式配置IP
echo 4 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3
if %operate%==4 goto 4


:1
echo 正在设置静态IP，请稍等...
rem //可以根据你的需要更改 
echo IP地址 = %ADDR%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY%
netsh interface ipv4 set address %NAME% static %ADDR% %MASK% %GATEWAY% 
echo 首选DNS = %DNS1% 
netsh interface ipv4 set dns %NAME% static %DNS1%
echo 备用DNS = %DNS2% 
if "%DNS2%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %DNS2%) 
echo 静态IP已设置！
pause
goto 4


:2
echo 正在设置动态IP，请稍等...
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address %NAME% dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns %NAME% dhcp 
echo 动态IP已设置！
pause
goto 4

:3
rem //设置IP地址
echo 输入IP地址
set /p addr=
rem //设置子网掩码
echo 输入子网掩码
set /p mask=
rem //设置网关
echo 输入网关
set /p gateway=
rem //设置dns1
echo 输入首选DNS
set /p dns1=
rem //设置dns2
echo 输入备用DNS
set /p dns2=

echo 正在设置自定义静态IP，请稍等...
rem //可以根据你的需要更改 
echo IP地址 = %addr%
echo 掩码 = %mask%
echo 网关 = %gateway%
netsh interface ipv4 set address %NAME% static %addr% %mask% %gateway% 
echo 首选DNS = %dns1% 
netsh interface ipv4 set dns %NAME% static %dns1%
echo 备用DNS = %dns2% 
if "%dns2%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %dns2%) 
echo 静态IP已设置！
pause
goto 4

:4
exit