AutoLisp从入门到放弃（六）

本章主要讲解如何通过AutoLisp代码查看、修改实体的所有属性信息，即图元信息。

一、获取图元属性信息

如果你是一个CAD二次开发的初学者，请你一定记住如下两行代码：

(entget(car(entsel)))			;; 列出所选图元的所有属性信息
(entget(car(entsel)) '("*"))	;; 列出所选图元的所有属性信息（包括扩展数据）

在如上两行代码中，我们使用到了两个新的函数：

函数名称	功能说明
(entsel)	选择一个图元后，得到这个图元的实体名和选择图元时的鼠标点击位置。
(entget)	根据实体名，得到图元的属性信息。

接下来，我们看这两个函数在实际绘图操作中如何使用。

首先，假如当前打开的图纸中有一条任意直线，我们在命令行中输入如下代码：

(entsel)

当鼠标光标变为拾取框的时候，选中图纸中的直线，你会看到如下数据：

(<图元名: 19651314580> (26.2477 5.38902 0.0))

这里的图元名就是你所选中的这条直线的实体名，后边的点坐标就是你在选择实体过程中鼠标点击的位置。根据之前的学习，我们已经知道我们这一步得到的这种数据类型是一个列表（LIST），我们要获取图元的属性信息，就必须要获取到图元的实体名。这就转换成了获取列表中第一个元素的操作，所以我们对上述的代码做如下改动：

(car(entsel))

执行上述代码，再次选择上一次选择的直线，我们会得到结果如下：

<图元名: 19651314580>

这里得到的结果就是选中直线的实体名了，我们可以通过实体名获取图元的所有属性信息了，所以，再对这行代码作进一步的改进：

(entget(car(entsel))) 

重复执行上述操作，得到结果如下：

(
	(-1 . <图元名: 19651314580>)
	(0 . "LINE") 
	(330 . <图元名: 19667dad1f0>) 
	(5 . "238") 
	(100 . "AcDbEntity") 
	(67 . 0) 
	(410 . "Model") 
	(8 . "0") 
	(100 . "AcDbLine") 
	(10 22.8099 3.96226 0.0) 
	(11 34.571 8.90368 0.0) 
	(210 0.0 0.0 1.0)
)

如上所示，这里我们可以看到这条直线的所有基本属性信息了。
观察这些属性，我们应该能看出来每一个点对所表示的属性信息，其中0是图元名称，8是图层，10和11分别是直线的起点坐标和终点坐标。

二、修改图元属性信息

在之前的操作中，我们可以看到，在AutoLisp中图元的所有属性信息都是以列表的形式进行存储的，也就是说，我们可以通过对列表的修改实现编辑图元的操作。
在这一部分，我们会用到如下函数：

函数名称	功能说明
(assoc)	从关联表中搜索一个元素，如果找到则返回该关联表条目。
(cons)	向表的头部添加一个元素，或构造一个点对 。
(list)	将任意数目的表达式组合成一个表 。
(subst)	在表中搜索某旧项，并将表中出现的每一个旧项用新项代替，然后返回修改后所得的表 。
(entmod)	修改对象（图元）的定义数据 。

接下来，我们以更新直线的起止点坐标为例，来实现修改图元属性信息的操作：

(defun C:ModifyLinePoint(/ #iCmdEcho #linedata #newlinedata #ptStaOld #ptEndOld #ptStaNew #ptEndNew)
	(setq #iCmdEcho (getvar "CMDECHO"))
	(setvar "CMDECHO" 0)
	
	(setq #linedata (entget (car (entsel))))  		;; 取得图元信息并赋值给变量#linedata
	(setq #ptStaOld (assoc 10 #linedata)) 			;; 获取直线的起点坐标
	(setq #ptEndOld (assoc 11 #linedata)) 			;; 获取直线的终点坐标
	(setq #ptStaNew (cons 10 (list 0.0 0.0 0.0)))	;; 使用列表创建一个新点坐标，并合成点对，用来替换原起点坐标
	(setq #ptEndNew (cons 11 (list 100.0 0.0 0.0)))	;; 使用列表创建一个新点坐标，并合成点对，用来替换原终点坐标

	;; 替换原来的点坐标
	(setq #newlinedata (subst #ptStaNew #ptStaOld #linedata))
	(setq #newlinedata (subst #ptEndNew #ptEndOld #newlinedata))
	
	(entmod #newlinedata)							;; 更新实体
	
	(setvar "CMDECHO" #iCmdEcho)
	(princ)
)

将上述代码加载到AutoCAD中，任意绘制一条直线，执行ModifyLinePoint命令，选中直线，就可以将选中的直线的起止点坐标分别修改为(0 0 0)和(100 0 0)了。