王爽汇编语言第四版实验七
本人最后的答案:
assume cs:codesg,ss:stacksg,ds:data,es:table
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
data ends
table segment
db 21 dup('year summ ne ?? ')
table ends
stacksg segment
dw 0,0,0,0,0,0,0,0
stacksg ends
codesg segment
start:mov ax,stacksg
mov ss,ax
mov sp,16
mov ax,data
mov ds,ax
mov bx,0
mov ax,table
mov es,ax
mov cx,21
mov si,0
mov di,0
s:push cx
mov cx,4
mov si,0
s0:mov al,[di]
mov es:[bx+si],al
inc di
inc si
loop s0
add bx,16
pop cx
loop s
mov cx,21
mov bx,0
s1:mov al,' '
mov es:[bx+4],al
mov ax,[di]
mov dx,[di+2]
mov es:[bx+4+1],ax
mov es:[bx+4+3],dx
add di,4
add bx,16
loop s1
mov cx,21
mov bx,0
s2:mov al,' '
mov es:[bx+9],al
mov ax,[di]
mov es:[bx+9+1],ax
add di,2
add bx,16
loop s2
mov cx,21
mov bx,0
s3:mov al,' '
mov es:[bx+12],al
mov ax,es:[bx+5]
mov dx,es:[bx+5+2]
div word ptr es:[bx+10]
mov es:[bx+13],ax
mov al,' '
mov es:[bx+15],al
add bx,16
loop s3
mov ax,4c00H
int 21H
codesg ends
end start
在做这个实验的时候,我犯了以下错误:
1.不正确的寻址格式
mov es:[bx].4[1],ax
好像是指明了段寄存器es后就不能用"."操符寻址了
error A2166: structure field expected
2.将table的段地址当做偏移地址使用导致程序陷入死循环
这个错误还是很难找的,开始我没有用es寄存器当做table的段地址临时存放点, 而是直接塞进bx存储器中参与了寻址运算:
mov bx,table
... ;此处省略很多代码
s0:mov al,[di]
mov [bx+si],al
inc di
inc si
loop s0
add bx,16
pop cx
loop s
简而言之就是把段地址当做偏移地址处理导致内存分配混乱. 当时才学到王爽老师的第八章, 还不知道es寄存器也能用来存储段地址
3.在指明寄存器的情况下还用X ptr指明内存单元长度
就是操作对象中有寄存器符号我还用word ptr或byte ptr再指明一次内存单元长度,我不知道这个算不算错的, 但是至少当时在实验的时候就是因为这种杂糅使用降低了我DosBox的速度, 但在masm for windows上运行还算正常:
s0:mov al,byte ptr [di]
...
mov ax,word ptr [di]
mov dx,word ptr [di+2]
...
4.地址取值后对另一个地址直接赋值
s0:mov es:[bx+si],[di]
error A2070: invalid instruction operands
这个错误很明显了, 做这个实验时第一次写汇编代码就想图个省事就直接传值, 然后就把这个家伙(A2070)弄出来了
赋值是不能直接用地址取值来处理的, 应用寄存器来间接传值.