原文链接:https://blog.csdn.net/qq_31799157/article/details/112463392
在sap中遇到loop中嵌套loop必不可少,多层loop必定会影响效率问题。
下面是多层loop优化demo。
REPORT gg.
DATA: lv_time_s TYPE timestampl, "loop前的时间点
lv_time_e TYPE timestampl, "loop后的时间点
lv_text TYPE timestampl.
DATA: lv_tabix TYPE i.
SELECT * FROM mara INTO TABLE @DATA(it_mara) UP TO 10000 ROWS.
CHECK it_mara IS NOT INITIAL.
SELECT * FROM marc INTO TABLE @DATA(it_marc) FOR ALL ENTRIES IN @it_mara WHERE matnr = @it_mara-matnr.
GET TIME STAMP FIELD lv_time_s. "获得loop前的时间点
DATA ls_data LIKE marc.
DATA lt_data LIKE TABLE OF marc.
LOOP AT it_mara INTO DATA(is_mara).
LOOP AT it_marc INTO DATA(is_marc) WHERE matnr = is_mara-matnr.
MOVE-CORRESPONDING is_marc TO ls_data.
APPEND ls_data TO lt_data.
CLEAR ls_data.
ENDLOOP.
ENDLOOP.
GET TIME STAMP FIELD lv_time_e.
lv_text = lv_time_e - lv_time_s.
DESCRIBE TABLE lt_data LINES DATA(lv_num_1).
WRITE: /(14) '普通循环时间:', lv_text, '条目数量:' ,lv_num_1.
CLEAR: lv_text, lv_time_e,lv_time_s,lt_data.
GET TIME STAMP FIELD lv_time_s.
**排序
SORT: it_mara BY matnr,
it_marc BY matnr.
LOOP AT it_mara INTO is_mara.
**取TABIX
READ TABLE it_marc TRANSPORTING NO FIELDS WITH KEY matnr = is_mara-matnr BINARY SEARCH.
IF sy-subrc = 0.
lv_tabix = sy-tabix.
LOOP AT it_marc FROM lv_tabix INTO is_marc.
IF is_mara-matnr <> is_marc-matnr.
EXIT.
ENDIF.
MOVE-CORRESPONDING is_marc TO ls_data.
APPEND ls_data TO lt_data.
CLEAR ls_data.
ENDLOOP.
ENDIF.
ENDLOOP.
GET TIME STAMP FIELD lv_time_e.
DESCRIBE TABLE lt_data LINES DATA(lv_num_2).
lv_text = lv_time_e - lv_time_s.
WRITE: /(14)'优化循环时间:', lv_text,'条目数量:' ,lv_num_2.