目录
1. Drools 概述
Drools 是一个基于Java的开源规则引擎,它允许你将业务逻辑从应用程序代码中分离出来,以规则的形式进行管理和维护。这样做的目的是为了提高业务逻辑的灵活性和可维护性,使得非程序员也能通过简单的规则编辑来改变系统的行为,而无需深入修改代码。
官网链接:Drools - Drools - Business Rules Management System (Java™, Open Source)
2. 实操(快速入门)
(1)引入Drools相关依赖
<properties>
<drools.version>8.41.0.Final</drools.version>
</properties>
<dependencies>
<dependency>
<groupId>org.drools</groupId>
<artifactId>drools-core</artifactId>
<version>${drools.version}</version>
</dependency>
<dependency>
<groupId>org.drools</groupId>
<artifactId>drools-compiler</artifactId>
<version>${drools.version}</version>
</dependency>
<dependency>
<groupId>org.drools</groupId>
<artifactId>drools-decisiontables</artifactId>
<version>${drools.version}</version>
</dependency>
<dependency>
<groupId>org.drools</groupId>
<artifactId>drools-mvel</artifactId>
<version>${drools.version}</version>
</dependency>
</dependencies>
(2)创建Drools的配置类DroolsConfig
这里的RULES_CUSTOMER_RULES_DRL = "rules/order.drl"指定了以 resource/rules/order.drl为规则引擎的文件(在该文件中制定规则)
/**
* 规则引擎配置类
*/
@Configuration
public class DroolsConfig {
private static final KieServices kieServices = KieServices.Factory.get();
//制定规则文件的路径
private static final String RULES_CUSTOMER_RULES_DRL = "rules/order.drl";
@Bean
public KieContainer kieContainer() {
//获得Kie容器对象
KieFileSystem kieFileSystem = kieServices.newKieFileSystem();
kieFileSystem.write(ResourceFactory.newClassPathResource(RULES_CUSTOMER_RULES_DRL));
KieBuilder kieBuilder = kieServices.newKieBuilder(kieFileSystem);
kieBuilder.buildAll();
KieModule kieModule = kieBuilder.getKieModule();
KieContainer kieContainer = kieServices.newKieContainer(kieModule.getReleaseId());
return kieContainer;
}
}
(3)resource/rules/order.drl:
记得 import对应的实体路径,不然会报错
订单积分规则介绍:
规则编号 | 订单金额 | 奖励积分 |
1 | 100元以下 | 不加分 |
2 | 100元-500元 | 加100分 |
3 | 500元-1000元 | 加500分 |
4 | 1000元以上 | 加1000分 |
//订单积分规则
package com.order
import com.atguigu.drools.bean.Order
//规则一:100元以下 不加分
rule "order_rule_1"
when
$order:Order(amout < 100)
then
$order.setScore(0);
System.out.println("成功匹配到规则一:100元以下 不加分");
end
//规则二:100元 - 500元 加100分
rule "order_rule_2"
when
$order:Order(amout >= 100 && amout < 500)
then
$order.setScore(100);
System.out.println("成功匹配到规则二:100元 - 500元 加100分");
end
//规则三:500元 - 1000元 加500分
rule "order_rule_3"
when
$order:Order(amout >= 500 && amout < 1000)
then
$order.setScore(500);
System.out.println("成功匹配到规则三:500元 - 1000元 加500分");
end
//规则四:1000元以上 加1000分
rule "order_rule_4"
when
$order:Order(amout >= 1000)
then
$order.setScore(1000);
System.out.println("成功匹配到规则四:1000元以上 加1000分");
end
(4)快速入门 测试示例
@Autowired
private KieContainer kieContainer;
@Test
public void test(){
//从Kie容器对象中获取会话对象
KieSession session = kieContainer.newKieSession();
//Fact对象,事实对象
Order order = new Order();
order.setAmout(1300);
//将Order对象插入到工作内存中
session.insert(order);
//激活规则,由Drools框架自动进行规则匹配,如果规则匹配成功,则执行当前规则
session.fireAllRules();
//关闭会话
session.dispose();
System.out.println("订单金额:" + order.getAmout() +
",添加积分:" + order.getScore());
}
3. Drools深入学习
3.1 规则文件内容构成
Drools支持的规则文件,除了drl形式,还有Excel文件类型的。
关键字 | 概述 |
package | 包名,逻辑上管理,同一个包名下的查询或者函数都可以直接调用 |
import | 用于导入类或者静态方法 |
global | 全局变量 |
function | 自定义函数 |
query | 查询 |
rule end | 规则体 |
3.2 规则体语法结构
rule "ruleName"
attributes
when
LHS
then
RHS
end
rule:关键字,表示规则开始,参数为规则的唯一名称。
attributes:规则属性,是rule与when之间的参数,为可选项。
when:关键字,后面跟规则的条件部分。
LHS(Left Hand Side):是规则的条件部分的通用名称。它由零个或多个条件元素组成。如果LHS为空,则它将被视为始终为true的条件元素。
then:关键字,后面跟规则的结果部分。
RHS(Right Hand Side):是规则的后果或行动部分的通用名称。
end:关键字,表示一个规则结束。
3.3 Pattern模式匹配
pattern的语法结构为:绑定变量名:Object(Field约束)
示例代码:
//规则二:100元 - 500元 加100分
rule "order_rule_2"
when
$order:Order(amout >= 100 && amout < 500)
then
$order.setScore(100);
System.out.println("成功匹配到规则二:100元 - 500元 加100分");
end
3.4 比较操作符
符号 | 说明 |
< | 小于 |
> | 大于 |
>= | 大于等于 |
<= | 小于等于 |
== | 等于 |
!= | 不等于 |
contains | 检查一个Fact对象的某个属性值是否包含一个指定对象的值 |
not contains | 检查一个Fact对象的某个属性值是否不包含一个指定的对象的值 |
memberOf | 判断一个Fact对象的某个属性是否在一个或多个集合中 |
matches | 判断一个Fact对象的属性是否与提供的标准的java正则表达式进行匹配 |
not matches | 判断一个Fact对象的属性是否不与提供的标准java正则表达式进行匹配 |
3.5 update、insert、retract 方法
update方法的作用是更新工作内存中的数据,并让相关的规则重新匹配。(要使用no-loop规则属性,避免死循环)
//规则一:100元以下 不加分
rule "order_rule_1"
when
$order:Order(amout < 100)
then
$order.setAmout(150);
update($order) //update方法用于更新Fact对象,会导致相关规则重新匹配
System.out.println("成功匹配到规则一:100元以下 不加分");
end
//规则二:100元 - 500元 加100分
rule "order_rule_2"
when
$order:Order(amout >= 100 && amout < 500)
then
$order.setScore(100);
System.out.println("成功匹配到规则二:100元 - 500元 加100分");
end
insert方法的作用是向工作内存中插入数据,并让相关的规则重新匹配。
//规则一:100元以下 不加分
rule "order_rule_1"
when
$order:Order(amout < 100)
then
Order order = new Order();
order.setAmout(130);
insert(order); //insert方法的作用是向工作内存中插入Fact对象,会导致相关规则重新匹配
System.out.println("成功匹配到规则一:100元以下 不加分");
end
//规则二:100元 - 500元 加100分
rule "order_rule_2"
when
$order:Order(amout >= 100 && amout < 500)
then
$order.setScore(100);
System.out.println("成功匹配到规则二:100元 - 500元 加100分");
end
retract方法的作用是删除工作内存中的数据,并让相关的规则重新匹配。
//规则一:100元以下 不加分
rule "order_rule_1"
when
$order:Order(amout < 100)
then
retract($order) //retract方法的作用是删除工作内存中的Fact对象,会导致相关规则重新匹配
System.out.println("成功匹配到规则一:100元以下 不加分");
end
3.6 规则属性 attributes
规则体语法结构:
rule "ruleName"
attributes
when
LHS
then
RHS
end
Drools中提供的属性如下表(部分属性):
属性名 | 说明 |
salience | 指定规则执行优先级 |
dialect | 指定规则使用的语言类型,取值java和mvel |
enabled | 指定规则是否启动 |
data-effective | 指定规则生效时间 |
data-expires | 指定规则失效时间 |
activation-group | 激活分组,具有相同分组名称的规则只能有一个规则触发 |
agenda-group | 议程分组,只有获取焦点的组中的规则才有可能触发 |
timer | 定时器,指定规则触发的时间 |
auto-focus | 自动获取焦点,一遍结合agenda-group一起使用 |
no-loop | 防止死循环 |
(1)salience属性
salience属性用于指定规则的执行优先级,取值类型为Integer。数值越大越优先执行。每个规则都有一个默认的执行顺序,如果不设置salience属性,规则体的执行顺序为由上到下。
salience示例:
package com.order
rule "rule_1"
salience 9
when
eval(true)
then
System.out.println("规则rule_1触发");
end
rule "rule_2"
salience 10
when
eval(true)
then
System.out.println("规则rule_2触发");
end
rule "rule_3"
salience 8
when
eval(true)
then
System.out.println("规则rule_3触发");
end
(2)no-loop属性
no-loop属性用于防止死循环,当规则通过update之类的函数修改了Fact对象时,可能使当前规则再次被激活从而导致死循环。取值类型为Boolean,默认值为false。
no-loop示例:
//订单积分规则
package com.order
import com.atguigu.drools.model.Order
//规则一:100元以下 不加分
rule "order_rule_1"
no-loop true //防止陷入死循环
when
$order:Order(amout < 100)
then
$order.setScore(0);
update($order)
System.out.println("成功匹配到规则一:100元以下 不加分");
end
4. 实操(global全局变量)
global关键字用于在规则文件中定义全局变量,它可以让应用程序的对象在规则文件中能够被访问。可以用来为规则文件提供数据或服务。
语法结构为:global 对象类型 对象名称
在使用global定义的全局变量时有两点需要注意:
1、如果对象类型为**包装类型**时,在一个规则中改变了global的值,那么只针对当前规则有效,对其他规则中的global不会有影响。可以理解为它是当前规则代码中的global副本,规则内部修改不会影响全局的使用。
2、如果对象类型为集合类型或JavaBean时,在一个规则中改变了global的值,对java代码和所有规则都有效。
(1)Order 订单类:
package com.atguigu.drools.model;
public class Order {
private double amout;
public double getAmout() {
return amout;
}
public void setAmout(double amout) {
this.amout = amout;
}
}
(2)Integral 积分类:
package com.atguigu.drools.model;
public class Integral {
private double score;
public double getScore() {
return score;
}
public void setScore(double score) {
this.score = score;
}
}
(3)resource/rules/order.drl:
//订单积分规则
package com.order
import com.atguigu.drools.model.Order
global com.atguigu.drools.model.Integral integral;
//规则一:100元以下 不加分
rule "order_rule_1"
no-loop true //防止陷入死循环
when
$order:Order(amout < 100)
then
integral.setScore(10);
update($order)
System.out.println("成功匹配到规则一:100元以下 不加分");
end
(4)测试示例:
@Test
public void test1(){
//从Kie容器对象中获取会话对象
KieSession session = kieContainer.newKieSession();
//Fact对象,事实对象
Order order = new Order();
order.setAmout(30);
//全局变量
Integral integral = new Integral();
session.setGlobal("integral", integral);
//将Order对象插入到工作内存中
session.insert(order);
//激活规则,由Drools框架自动进行规则匹配,如果规则匹配成功,则执行当前规则
session.fireAllRules();
//关闭会话
session.dispose();
System.out.println("订单金额:" + order.getAmout());
System.out.println("添加积分:" + integral.getScore());
}