VB自动登陆网络站点详解

   得到参数名

自动登陆站点有一个关键的地方就在于参数名的正确与否，因为各个WEB服务器接收的参数名都不可能相同，在程序中倘若参数名使用不正确，会误以为代码的错误而徒増烦恼，因此首先推荐一个很有用的工具“Visual Sniffer”：它可以拦截通过网络传输的TCP/IP/UDP/ICMP等数据包，利用这个工具可以很轻松的得到向服务器发送的相关参数。

以登陆CSDN为例，现在我们先用IE打开“http://www.csdn.net/member/login.asp”CSDN的登陆页面，输入帐号及密码，先不要登陆，将Visual Sniffer运行起来，点一下“开始拦截”这个按钮，再回到登陆页面，点击“登陆”，稍等片刻，登陆成功之后在Visual Sniffer上点一下“停止拦截”，现在就可以找一下刚才IE到底向外发送了些什么东西。（建议在做这些之前将多余的IE全都关掉，因为倘若其它IE窗口也在发送数据，你将会在Visual Sniffer受到不必要的干扰。）

注意现在在Visual Sniffer的左边有很多“+”号，这些便是被拦截到的数据，将它们一一展开，此时应注意查看右边的数据，倘若第一行没有“POST”这样的字符，那便迅速换一个“+”号，这已经是最快的找到向CSDN的服务器发送数据的方法了（我们的登陆是“POST”请求，如果看到的“GET”，那肯定不是）。请看实际的图片：

 

先对发出去的文件头稍加说明一下，有几个不是很重要，因此这里就不多说了：

“Accept：”表示能够收到的文件格式。

“Referer：”表示指向的文件地址。

“Accept_Language：”表示接受的语言。

“Host：”表示主机名。

图中的紫线部分合起来便是POST请求发往的地址，红线所示便是所有服务器需要接收的参数，四个等号表示共有四个参数用“&”连接起来。顺便提一句，你看到的那个Cookie：ASPSESSION……长长的这段就是Session，它是在IE与服务器请求连接的时候由服务器发给IE的，现在又被原样返回了。你可以在Visual Sniffer中其它地方查查，看一下它是什么时候得到的。由于在程序中，我们使用的是控件，实际上不需要考虑Cookie及Session的问题，因为VB的Inet、WebBrowser都封装的很好，关键只是如何正确的使用。

 “login_name”、“password”这两个就是CSDN在登陆时接收的最主要的参数名；此外，还有一个“cookietime”告诉本地Cookie的有效时间，这三个是登陆CSDN时所必须发送的参数。帐号及密码是一般登陆站点都需要的参数，但有些服务器会接收三个以上的参数，除了帐号及密码我们可以把其它的参数统统算作第三参数，中间使用“&”连接即可。另外比较重要的是“Content-Type: application/x-www-form-urlencoded”，这里告诉服务器解码的方式，程序中要是少了这句，什么都干不了。

登陆其它论坛、邮箱、社区的时候，都可以通过Visual Sniffer来得到POST的所有重要信息，而且这也是我推荐给大家的方法，特别是在有些参数不那么容易从HTML源文件中分析的时候。不仅如此，你还可以用这种方法来拦截自己的程序，因为同样也是HTTP协议，Visual Sniffer也是能够拦截的。这样你就可以比较程序与IE登陆时到底有何异同，以达到除错的目的。

Inet控件与WebBrowser控件配合使用

URL	帐号	密码	其它参数
SOHU邮箱	http://login.sohu.com/chkpwd.php	UserName	Password
网易通行证	http://reg4.163.com/CheckUser.jsp	username	password
CSDN通行证	http://www.csdn.net/member/logon.asp	login_name	password	cookietime=0& x=42&y=10

表格中的参数就是按照前面介绍的方法得到的，在程序中将要用到。

先说明一点， WebBrowser也是可以直接POST数据给Web服务器的，我将在第四部分给出代码。这里先看看Inet与WebBrowser相互配合的效果。

新建一个工程，部件中勾选中“Microsoft Internet Transfer Controls 6.0”、“Microsoft Internet Controls”，依次添加Inet1、WebBrowser1、Text1、Text2、Combo1在窗体上，可以把WebBrowser1适当拉大一点，将各控件位置安排好（可以参考运行后的图片），下面是代码：

    Dim URL1(2) As String: Dim URL2(2) As String

    Dim C1(2) As String: Dim C2(2) As String: Dim C3(2) As String

Private Sub Form_Load()

       Text1.Text = ""

    Text2.Text = ""

    Text2.PasswordChar = "*"

    Combo1.AddItem "SOHU邮箱", 0

    Combo1.AddItem "网易通行证", 1

    Combo1.AddItem "CSDN通行证", 2

    Combo1.AddItem "请选择一个登陆", 3

    Combo1.Text = Combo1.List(3)

    URL1(0) = "http://login.sohu.com/chkpwd.php": URL2(0) = "http://www34.mail.sohu.com/control/entry"

    URL1(1) = "http://reg4.163.com/CheckUser.jsp": URL2(1) = "http://reg4.163.com/Main.jsp?"

    URL1(2) = "http://www.csdn.net/member/logon.asp": URL2(2) = "http://www.csdn.net/Member/Passport.asp"

    C1(0) = "UserName": C2(0) = "Password": C3(0) = ""

    C1(1) = "username": C2(1) = "password": C3(1) = ""

    C1(2) = "login_name": C2(2) = "password": C3(2) = "cookietime=0&x=42&y=10"

End Sub

Private Sub Form_Resize()

If Me.WindowState <> 1 Then

    WebBrowser1.Left = 10

    WebBrowser1.Width = Me.Width - 120

    WebBrowser1.Height = Me.Height - 800

End If

End Sub

Private Sub Text2_KeyUp(KeyCode As Integer, Shift As Integer)

    If KeyCode <> 13 Then Exit Sub

    If Combo1.ListIndex = 3 Then MsgBox "请选择一个登陆": Exit Sub

    If Text1.Text = "" Then MsgBox "请输入用户名": Exit Sub

    If Text2.Text = "" Then MsgBox "请输入密码": Exit Sub

    Dim strFormData As String

    strFormData = C1(Combo1.ListIndex) + "=" + Text1.Text + "&" + C2(Combo1.ListIndex) + "=" + Text2.Text + "&" + C3(Combo1.ListIndex)

    Inet1.Execute URL1(Combo1.ListIndex), "Post", strFormData, "Content-Type: application/x-www-form-urlencoded "

    Do Until Inet1.StillExecuting = False ''''这里阻塞前面的Inet1，确保登陆成功之后再取页面，你可以将此Do取消了试一次。

        DoEvents

    Loop

    If Combo1.ListIndex = 1 Then

        WebBrowser1.Navigate URL2(Combo1.ListIndex) + C1(Combo1.ListIndex) + "=" + Text1.Text

    Else

        WebBrowser1.Navigate URL2(Combo1.ListIndex)

    End If

End Sub

 

大家可以挑选一个自己已经注册过的站点看看效果。

可以看到，登陆成功之后， Inet与WebBrowser是可以保持住同一个Session对话的！不过当我们在WebBrowser中显示出来的页面上点击了一个连接之后，请求却不能成功（请读者自己试一下，在登陆成功的站点中任意点击一个与用户相关的连接，弹出来的将是一个“你没有登陆”的页面）。为什么？

因为我们现在点击的连接还是使用IE（操作系统默认的浏览器）打开的，而IE请求页面的时候使用的是服务器新发送过来的Session，这个新的Session与你在WebBrowser中使用的Session也就是身份ID不一样，至少服务器是这么认为的，它以为是另一个没有登陆的用户。所以说Session的作用范围不是对整个客户机的，通过实际的代码可以很好的理解这一点。(可以利用这一点，使用代码在一台电脑上实现两个以上的用户同时登陆，甚至还能对同一主题进行无缝发言。)

所以接下来我们要使页面继续停在WebBrowser中显示。因为很显然，既然WebBrowser与Inet是可以保持住同一个Session对话的，那么WebBrowser与WebBrowser内部自然也是可以的！

要添加的代码很简单——

Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)

    Dim frm2 As New Form2

    frm2.WebBrowser1.RegisterAsBrowser = True

    Set ppDisp = frm2.WebBrowser1.Object

    frm2.Show

End Sub

然后在工程中添加一个Form2，上面再放一个WebBrowser1，调整好位置，Form2的代码窗口添加上以下代码：

Private Sub Form_Load()

WebBrowser1.Silent = True

End Sub

 

Private Sub Form_Resize()

If Me.WindowState <> 1 Then

    WebBrowser1.Left = 10

    WebBrowser1.Width = Me.Width - 120

    WebBrowser1.Height = Me.Height - 600

End If

End Sub

Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)’这里为了避免在Form1中同样发生的事情。

    Dim frm2 As New Form2

    frm2.WebBrowser1.RegisterAsBrowser = True

    Set ppDisp = frm2.WebBrowser1.Object

    frm2.Show

End Sub

利用Inet发送登陆请求，WebBrowser浏览实际页面，的确是个很不错的构思，在登陆站点相对教少的情况下应该是没有什么问题的。但是这也会使事情变得更加复杂。除了不能缺少的POST地址（URL1）、帐号参数（C1）、密码参数（C2）、其它参数（C3）之外，还必须要有供WebBrowser请求浏览的页面地址参数（URL2）。 虽然只是多了一个参数，但却添加了很多麻烦（比如网易邮箱的请求页面是根据用户的帐号名自动生成的，不固定）。只有利用WebBrowser直接POST数据才能避免第四个参数。但是浏览器的界面以及功能却是一个比较麻烦的问题（除非你不嫌麻烦，自己再动手写一个）。

Internet Explorer对象

使用Internet Explorer对象可以使POST请求在IE中产生，从而脱离程序，远离了美化界面的工作。程序甚至可以隐藏或退出，免去了WebBrowser带来的烦恼，当然也不需要第四个参数。

下面我们还是以登陆CSDN为例，给出实际的代码，您可以根据前面文章中提供的参数换成你注册过的站点：

建新工程，在工程中“引用”Internet Explorer对象，点“浏览”，在系统文件夹下找到Shdocvw.dll（这个文件是IE自带的）， Form1中添加Command1，以下是代码——

 

    Dim g_oIE As InternetExplorer

Private Sub Command1_Click()

    Dim vPost As Variant

    Dim vHeaders As Variant

 

    Set g_oIE = New InternetExplorer

    g_oIE.Visible = True

   

    ReDim aByte(0) As Byte

    cPostData = "login_name=帐号&password=密码&cookietime=0"

    PackBytes aByte(), cPostData

   

    vPost = aByte

    vHeaders = "Content-Type: application/x-www-form-urlencoded" + Chr(10) + Chr(13)

   

    g_oIE.Navigate "http://www.csdn.net/member/logon.asp", , , vPost, vHeaders

   

End Sub

Private Sub PackBytes(ByteArray() As Byte, ByVal PostData As String)

    iNewBytes = Len(PostData) - 1

    If iNewBytes < 0 Then Exit Sub

    ReDim ByteArray(iNewBytes)

    For i = 0 To iNewBytes

       ch = Mid(PostData, i + 1, 1)

       If ch = Space(1) Then

          ch = "+"

       End If

       ByteArray(i) = Asc(ch)

    Next

End Sub

（请输入自己的帐号及密码试运行。这种方法的好处是显而易见的，你可以按这个方法将前面的代码改造一下。）

PackBytes函数将Post出去的数据转化为一个ASCII数组，另外vHeaders的值必须以“+ Chr(10) + Chr(13)”结束。

 

代码没有什么好解释的，现在已经进入到Shdocvw.dll这个“库”中去了，而前面所说的WebBrowser及Internet Explorer都是这个库中所包含的“类”。大家可以打开对象浏览器看看它们互相之间的关系。

在WebBrowser中发送POST请求

本来这一部分内容也应该放在第二章，但一方面为了醒目，另一方面，这种方法实际上与Internet Explorer对象有很大的联系及相似性，所以特意将之放在Internet Explorer对象之后介绍。

 

现在我们要用到的也是WebBrowser的“Navigate”方法，其函数原型如下所示：

Sub Navigate(URL As String, [Flags], [TargetFrameName], [PostData], [Headers])

 

大家不妨与第三章中Internet Explorer对象的“Navigate”方法比较一下，一模一样，原来是同一个接口！！

新建一个工程，部件中勾选中 “Microsoft Internet Controls”，添加一个WebBrowser1、一个Command1在窗体上，可以把WebBrowser1适当拉大一点，Form1中添加以下代码：

      Private Sub Command1_Click()

      ReDim aByte(0) As Byte '''' Array of bytes to hold data to post

      cPostData = "login_name=帐号&password=密码&cookietime=0&x=42&y=10"

      PackBytes aByte(), cPostData

      Dim vPost As Variant

      vPost = aByte '''' Assign the byte array to a VARIANT

      Dim vHeaders As Variant

      vHeaders = "Content-Type: application/x-www-form-urlencoded" + Chr(10) + Chr(13)

      WebBrowser1.Navigate "http://www.csdn.net/member/logon.asp", , , vPost, vHeaders

      End Sub

      Private Sub PackBytes(ByteArray() As Byte, ByVal PostData As String)

     iNewBytes = Len(PostData) - 1   '''' Get rid of the null termination

      If iNewBytes < 0 Then

       Exit Sub

      End If

      ReDim ByteArray(iNewBytes)

      For i = 0 To iNewBytes

       ch = Mid(PostData, i + 1, 1)

       If ch = Space(1) Then

         ch = "+"

       End If

       Debug.Print ch, Asc(ch)

       ByteArray(i) = Asc(ch)

      Next

    End Sub

（请参考第三章中的代码。）

通过这四篇文章的介绍，我想读者一定不光是对VB登陆Web服务器有了更深的认识，而且同时对HTTP协议、Cookie、Session也加深了理解！