SourceInsight Macro编程-1

最新推荐文章于 2022-06-13 23:39:44 发布
最新推荐文章于 2022-06-13 23:39:44 发布
阅读量758 收藏 1
点赞数
文章标签： source insight 宏编程
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/rever2009/article/details/70244156
版权 
自己动手编写了几个很不错的宏定义，分享出来，希望可以帮助大家。
//去掉字符串左边的空格
macro TrimLeft(szLine)
{
    nLen = strlen(szLine)
    if(nLen == 0)
    {
        return szLine
    }
    nIdx = 0
    while( nIdx < nLen )
    {
        if( ( szLine[nIdx] != " ") && (szLine[nIdx] != "\t") )
        {
            break
        }
        nIdx = nIdx + 1
    }
    return strmid(szLine,nIdx,nLen)
}
//去掉字符串右边的空格
macro TrimRight(szLine)
{
    nLen = strlen(szLine)
    if(nLen == 0)
    {
        return szLine
    }
    nIdx = nLen
    while( nIdx > 0 )
    {
        nIdx = nIdx - 1
        if( ( szLine[nIdx] != " ") && (szLine[nIdx] != "\t") )
        {
            break
        }
    }
    return strmid(szLine,0,nIdx+1)
}
//去掉字符串两边空格
macro TrimString(szLine)
{
    szLine = TrimLeft(szLine)
    szLIne = TrimRight(szLine)
    return szLine
}
//对选择的代码添加 或取消#if 0  #endif 包围
macro AddOrDelMacroComment()
{
 hwnd=GetCurrentWnd()
 sel=GetWndSel(hwnd)
 lnFirst=GetWndSelLnFirst(hwnd)
 lnLast=GetWndSelLnLast(hwnd)
 hbuf=GetCurrentBuf()
 if (LnFirst == 0) 
 {
   szIfStart = ""
 } 
 else 
 {
   szIfStart = GetBufLine(hbuf, LnFirst-1) //被选择的第一行的上一行的内容
 }
 szIfEnd = GetBufLine(hbuf, lnLast+1) //被选择的代码块的最后一行的下一行内容

 szCodeStart = GetBufLine(hbuf, LnFirst) //被选择的代码块的第一行内容
 szCodeEnd = GetBufLine(hbuf, lnLast)//被选择的代码块的最后一行内容
 start_space_count = 0 //第一行代码的前面的空白个数  只计算Tab个数,忽略空格
 end_space_count = 0  //最后一行的代码的前面的空白个数
 insert_space_count = 0 //我们要插入的#if 0 字符串前面应该插入多少个Tab
 index = 0
 while(index<strlen(szCodeStart))
 {
  if(AsciiFromChar(szCodeStart[index])== 9) //9是Tab字符的ASCII
  {
   start_space_count = start_space_count +1
  }
  index = index + 1 
 }
 index = 0
 while(index<strlen(szCodeEnd))
 {
  if(AsciiFromChar(szCodeEnd[index])== 9)
  {
   end_space_count=end_space_count+1
  }
  index = index + 1 
 }
 //代码块的第一行和最后一行前面的Tab个数,取比较小的那个值
 if(start_space_count<end_space_count)
 {
  insert_space_count = start_space_count -1
 }
 else
 {
  insert_space_count = end_space_count -1
 }
 str_start_insert=""
 str_end_insert=""
 index=0
 while(index<insert_space_count)
 {
  str_start_insert=str_start_insert#" "  //这里添加的Tab字符
  str_end_insert=str_end_insert#" "  //这里添加的也是Tab字符
  index = index + 1 
 }
 str_start_insert=str_start_insert#"#if 0"    //在#if 0 开始符号和结束符号前都添加Tab字符,比代码行前面的空白少一个
 str_end_insert=str_end_insert#"#endif"    
 if (TrimString(szIfStart) == "#if 0" && TrimString(szIfEnd) =="#endif") {
         DelBufLine(hbuf, lnLast+1)
         DelBufLine(hbuf, lnFirst-1)
         sel.lnFirst = sel.lnFirst - 1
         sel.lnLast = sel.lnLast - 1
 } 
 else 
 {
         InsBufLine(hbuf, lnFirst, str_start_insert)
         InsBufLine(hbuf, lnLast+2, str_end_insert)
         sel.lnFirst = sel.lnFirst + 1
         sel.lnLast = sel.lnLast + 1
 }
 SetWndSel( hwnd, sel )
}
/* 获取当前时间 */
macro GetCurrentTime()
{
  time = GetSysTime(1);

  /* year */
  str = time.year; 
  
  /* month */
  if(time.month < 10)
    str = cat("@str@-0",time.month);
  else
    str = cat("@str@-",time.month);

  /* day */
  if(time.day < 10)
    str = cat("@str@-0",time.day);
  else
    str = cat("@str@-",time.day);

  return str;
 
}
/* 添加函数注释，选中函数名使用此宏自动添加函数名 */
macro InsertFuncComment()
{
    var comments
    var hBuff
    var line
    var fun
    var author

    author = " "
    
    hBuff = GetCurrentBuf()
    fun = GetBufSelText(hBuff)
    line = GetBufLnCur(hBuff)
    
    InsBufLine(hBuff, line++, "/*******************************************************************************")
    
    comments = " * Function Name  : "
    comments = cat(comments,fun)
    InsBufLine(hBuff, line++, comments)

    comments = " * Description    : "
    InsBufLine(hBuff, line++, comments)
    
    comments = " * Input          : "
    InsBufLine(hBuff, line++, comments)
    
    comments = " * Output         : "
    InsBufLine(hBuff, line++, comments)

    comments = " * Return         : "
    InsBufLine(hBuff, line++, comments)

    comments = " * Author         : "
    comments = cat(comments, author)
    InsBufLine(hBuff, line++, comments)
    
    comments = " * Date           : "
    comments = cat(comments, GetCurrentTime());
    InsBufLine(hBuff, line++, comments)   
    
    InsBufLine(hBuff, line++, "*******************************************************************************/")

    SaveBuf(hBuff)
}

/* 添加文件头和文件结束尾 */
macro InsertFileComment()
{
    var comments
    var hBuff
    var line
    var line_count
    var mender
    var file_name 
    var file_name_len 
    var i

    mender = "Modified by Zhang Ruisong on "
    
    hBuff = GetCurrentBuf()
    line = GetBufLnCur(hBuff)
   
    file_name = GetBufName(hBuff)
    file_name_len = strlen(file_name)
    if(0 == file_name_len)
    {
      file_name = nil
    }
    else
    {
      i = file_name_len
      while("\\" != file_name[--i])
      {
      }
      file_name = strmid(file_name,i+1,file_name_len)
    }

    str_year = GetSysTime(1)
    str_year = str_year.year
    InsBufLine(hBuff, line++, "/******************** (C) COPYRIGHT @str_year@ Company *******************************")
    
    comments = "* File Name       : "
    comments = cat(comments, file_name)
    InsBufLine(hBuff, line++, comments)
    
    comments = "* Author          : "
    InsBufLine(hBuff, line++, comments)
    
    comments = "* Version         : "
    InsBufLine(hBuff, line++, comments)
 
    comments = "* Date            : "
    comments = cat(comments, GetCurrentTime());
    InsBufLine(hBuff, line++, comments)

    comments = "* Description     : "
    InsBufLine(hBuff, line++, comments)

    comments = "* Function list   : "
    InsBufLine(hBuff, line++, comments)
    
    comments = "* History         : "
    InsBufLine(hBuff, line++, comments)
    
    InsBufLine(hBuff, line++, "*******************************************************************************/")

    SaveBuf(hBuff)

    line_count = GetBufLineCount(hBuff)
    InsBufLine(hBuff, line_count, "/* End Of File */");

    SaveBuf(hBuff)
}





macro InsertSpaceComment()
{
    hbuf = GetCurrentBuf();
    ln_count = GetBufLineCount(hbuf);


    ln = 0;
    while (ln< ln_count)
    {
        str_line = GetBufLine(hbuf,ln);   /* 获取当前行 */
        str_modify = 0;


        str = str_line;
        i = 0;
        str_len = strlen(str);
        while (nil != str[i])
        {
            offset = 1;
            
            /* switch check */
            if (i + 6 < str_len)
            {
                offset = 7;
                if ("switch(" == strmid(str,i,i + offset))
                {
                    
                    str_len = strlen(str);
                    str_head = strmid(str, 0, i + offset - 1);
                    str_tail = strmid(str, i + offset - 1, str_len);


                    str_head = cat(str_head, " ");
            
                    i = strlen(str_head);
                    str = cat(str_head, str_tail); 


                    str_modify = 1;
                    continue;
                }
            }
            
            /* while check */
            if (i + 5 < str_len)
            {
                offset = 6;
                if ("while(" == strmid(str,i,i + offset))
                {
                    
                    str_len = strlen(str);
                    str_head = strmid(str, 0, i + offset - 1);
                    str_tail = strmid(str, i + offset - 1, str_len);


                    str_head = cat(str_head, " ");
            
                    i = strlen(str_head);
                    str = cat(str_head, str_tail); 


                    str_modify = 1;
                    continue;
                }
            }
            
            /* for check */
            if (i + 3 < str_len)
            {
                offset = 4;
                if ("for(" == strmid(str,i,i + offset))
                {
                    str_len = strlen(str);
                    str_head = strmid(str, 0, i + offset - 1);
                    str_tail = strmid(str, i + offset - 1, str_len);


                    str_head = cat(str_head, " ");
            
                    i = strlen(str_head);
                    str = cat(str_head, str_tail); 


                    str_modify = 1;
                    continue;
                }
            }
            
            /* if check */
            if (i + 2 < str_len)
            {
                offset = 3;
                if("if(" == strmid(str,i,i + offset))
                {
                    str_len = strlen(str);
                    str_head = strmid(str, 0, i + offset - 1);
                    str_tail = strmid(str, i + offset - 1, str_len);


                    str_head = cat(str_head, " ");
            
                    i = strlen(str_head);
                    str = cat(str_head, str_tail);  


                    str_modify = 1;
                    continue;
                }
            }


            /* other check*/
            if (i + 1 < str_len)
            {
                offset = 2;
                /* , ; check */
                if (("," == str[i] || ";" == str[i]) && str[i+1] != " ") 
                {
                    /* 换行 */
                    if (";" == str[i] && str[i+1] == "\n")
                    {
                        
                    }
                    /* 非换行 */
                    else
                    {
                        str_len = strlen(str);
                        str_head = strmid(str, 0, i + offset - 1);
                        str_tail = strmid(str, i + offset - 1, str_len);


                        str_head = cat(str_head, " ");
                
                        i = strlen(str_head);
                        str = cat(str_head, str_tail);  


                        str_modify = 1;
                        continue;  
                    }
                }


                /* 单目运算符 check */
//                if (("&" == str[i] && str[i+1] != " " && str[i+1] != "&" && str[i+1] != "=")
//                  ||("|" == str[i] && str[i+1] != " " && str[i+1] != "|" && str[i+1] != "=")
//                {
//                    str_len = strlen(str);
//                    str_head = strmid(str, 0, i + offset - 1);
//                    str_tail = strmid(str, i + offset - 1, str_len);
//
//                    str_head = cat(str_head, " ");
//            
//                    i = strlen(str_head);
//                    str = cat(str_head, str_tail);  
//
//                    str_modify = 1;
//                    continue;  
//                }
                
            }


            /* 向前检查 */
//            if (i > 0)
//            {
//                offset = 0;
//                /* 单目运算符 check */
//                if (("&" == str[i] && str[i-1] != " ")
//                  ||("|" == str[i] && str[i-1] != " ")
//                {
//                    str_len = strlen(str);
//                    str_head = strmid(str, 0, i + offset - 1);
//                    str_tail = strmid(str, i + offset - 1, str_len);
//
//                    str_head = cat(str_head, " ");
//            
//                    i = strlen(str_head);
//                    str = cat(str_head, str_tail);  
//
//                    str_modify = 1;
//                    continue;  
//                }
//            }
    
            i++;
        }


        if (1 == str_modify)
        {
            PutBufLine(hbuf, ln, str);
        }
        
        ln++;
    }
}

Jenson_2017
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
Source Insight Marco研究（语法篇）
04-01 1604
Source Insight宏语法与C相似，编写好的宏以.em文件存储。要使用宏先需要把.em文件加入到当前工程或是Base工程中，然后为其分配一个快捷键或是菜单项，之后就可以使用键盘或是点击菜单来调用宏。si的宏语法“不是”大小写敏感的，且每行语句不强制要求以分号结束，语法元素之间的空格将被自动忽略，变量名必须以字母开头。1. 宏定义方法如下，可以传递参数，可以有返回值，但和一些脚本语言一样
source insight macro
ee230的专栏
04-24 594
https://www.sourceinsight.com/download/macro-files/ 为了提高代码编辑效率，source insight提供了macro功能，非常方便。 Source Insight Macro Files autoexp.em Automatically expands C statements like if, for, wh...
source insight常用macro语言脚本
05-02
source insight常用macro语言脚本，加速你的代码编写。很多功能都是很实用的，比如快速注解、取消注解多行代码功能
Source Insight Token Macro
06-23
因为source insight不展开宏，导致WRK、CRT、C头文件等解析不完全，用SI的Token Macro可以解决这个问题。 使用方法很简单，多务必把它们重命名为C.tom，并放到对应工程目录下！！ 原理请看：http://blog.csdn.net/better0332/archive/2010/06/23/5689193.aspx
sourceinsight常用宏
星痕_Raphael
04-18 708
// sourceinsight常用宏   // //作者: 佚名 时间:2005-02-03 11:03 出处:互连网  //摘要: sourceinsight常用宏  // // //说明: //   该宏文件实现一些编码程中能会到的功能, 如添加文件头、函数说明和宏定义等, 使用时能自动添加文件名、函数名和当前日期. // //使用说明: //   1. Project->Open Proj
sourceinsight 便捷插件 符合Doxygen的注释标准
12-16
1. **Quicker.em**：这可能是SourceInsight的一个快捷键配置文件，允许用户自定义快捷键以快速执行与Doxygen注释相关的操作，如插入预定义的注释模板。通过这样的设置，用户可以提高工作效率，不必每次都手动输入...
SourceInsight base project including macro files
01-05
在这个“SourceInsight base project including macro files”中，我们主要关注的是与宏相关的自定义功能。 **1. 创建C++类命令** 在SourceInsight中，通过宏可以自定义快捷方式来快速创建C++类。这通常涉及到生成...
sourceInsight宏定义
01-11
在本文中，我们将深入探讨如何在Source Insight中创建和使用宏定义，以及它们如何帮助优化编程工作流程。 1. **创建宏定义** 在Source Insight中，你可以通过`Edit -> Define Macro`菜单选项来创建新的宏。这将...
SourceInsight4.0使用的Quicker.em宏定义
12-25
**源码分析神器SourceInsight 4.0与Quicker.em宏定义** SourceInsight是一款深受程序员喜爱的源代码分析工具，它以其强大的代码浏览、查找、跳转和编辑功能，极大地提升了开发者的工作效率。而Quicker.em是针对...
Source Insight宏语言实践
weixin_30389003的博客
07-22 162
Source Insight 作为一款优秀的代码浏览和编辑器应用十分广泛，对于一些重复使用的功能，我们可以定义相关的宏来提高开发效率。 1:宏的编写 Source Insight Help文档中Macro Language Guide一节详细的介绍了宏的编写，结构和C语言相似，通过阅读文档，相信就可以编写出各种功能强大的宏。这里我编写了一个简单的添加函数注释的宏。 View Code ...
SourceInsight处理源代码行的macro
最新发布
04-04
sourceinsight宏，tab转空格，去除一行前面和后面的空格等。 支持仅对选择的文本进行操作。
Source Insight使用进阶篇——宏语言使用
06-17
Source Insight是阅读和编写代码的好东东，基本上也算得上是经典之作了，虽然还有一点点小bug，不过对于我们这些C程序员来说可是一旦拥有别无所求。但是大家可能很少用到Source Insight的宏语言(Source Insight macro language)。Source Insight中的宏语言类同于MS Office中的VBA，也具有程序化执行用户预定义操作的通用宏语言功能。VBA功能的强大就不用多作说明了，而Source Insight的宏语言也不逊色。以下就以项目中一次实际应用为例进行说明。
source insight 宏语言使用
05-03
source insight 宏语言使用 在函数名添加前缀。
特别好用的Source Insight宏
10-11
GLOBAL.CF3，一个特好用的Sourceinsight宏。 操作如下：Options --> Load Configuration --》 Load，然后选择文件位置即可。
符合 Doxygen 注释风格的 SourceInsight 宏
Litost_Cheng的博客
01-05 2199
Source-Insight-Macro 一、简介 1.自定义组织信息 2.Doxygen风格的函数注释以及Todo标签 3.Doxygen格式的单行注释风格 二、FAQ 1.关于SourceInsight版本问题 2.关于Doexgen使用问题 三、参考与链接 Source-Insight-Macro 一、简介   该仓库旨在为 C/C++ 的开发人员提供一套符合 Doxygen...
Source_insight配置宏注释宏定义_方便快捷生成规范的函数注释和文件头注释
weixin_50183638的博客
05-10 1315
Source_insight配置宏注释宏定义_方便快捷生成规范的函数注释和文件头注释 配置这个注释宏定义其实就是修改，Source Insight（SI）中有一个Base工程，是安装完SI后自动生成的一个工程，该工程里只有一个Utils.em文件，该文件是常用编辑宏的一个集合。 1、文件注释 macro InsertFileHeader() { //get crrunt time szTime = GetSysTime(1) Day = szTime.Day
SourceInsight宏插件(非常好用，强力推荐)
parasoft的专栏
12-20 5693
转载自： https://www.cnblogs.com/hwli/p/8622853.html 对于一直使用sourceinsight编辑C/C++代码的工程师们，sourceinsight是一个非常好用的编辑工具可以任意定位，跳转，回退，本人一直使用该工具做C/C++开发，sourceinsight能够满足我的大部分需求，但是有些功能没有总觉得是一个缺憾。源码链接:链接：https://p...
source insight 添加自定义macro
weixin_30596165的博客
06-24 378
　　打开C:\Documents and Settings\xxxx\My Documents\Source Insight\Projects\Base文件夹下的em文件，可以看到都是由macro定义的一系列函数，附件是我改写的一个比较简单的注释宏，大家可以将它复制粘贴到该em文件里，然后按类似操作为这个宏设置一个快捷键 　　当然我们还可以自己创建em文件，创建后保存到C:\Documents ...
source insight 宏进阶功能
有趣的编程
06-13 585
列举几个SI常用的宏 注释与解除注释 路径定位 界面错乱 打开文件....
Source Insight与PC-Lint集成教程
Source Insight 是一款强大的源代码查看和编辑器，它支持多种编程语言，包括 C 和 C++。将 PC-Lint 集成到 Source Insight 中，开发者可以在编写代码的同时实时获取代码质量反馈，提高开发效率。 集成 PC-Lint 到 ...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值