函数调用约定

前言：
    文章讲述了几种主要程序语言中的函数调用约定；详细说明时主要以VC6中的函数调用约定为主,阐释方式主要是以C++程序编译后得到的汇编代码来进行说明;

     我所使用的编译器和平台：WindowsXP + 赛扬1G + VC6(主要工具)/Delphi6/C++Builder6;


    一：函数调用约定;
        函数调用约定是函数调用者和被调用的函数体之间关于参数传递、返回值传递、堆栈清除、寄存器使用的一种约定;
        它是需要二进制级别兼容的强约定,函数调用者和函数体如果使用不同的调用约定,将可能造成程序执行错误,必须把它看作是函数声明的一部分;

    二：常见的函数调用约定;

    VC6中的函数调用约定;


            调用约定        堆栈清除    参数传递
            __cdecl         调用者      从右到左,通过堆栈传递
            __stdcall       函数体      从右到左,通过堆栈传递
            __fastcall      函数体      从右到左,优先使用寄存器(ECX,EDX),然后使用堆栈
            thiscall        函数体      this指针默认通过ECX传递,其它参数从右到左入栈


    __cdecl是C/C++的默认调用约定; VC的调用约定中并没有thiscall这个关键字,它是类成员函数默认调用约定;
    C/C++中的main(或wmain)函数的调用约定必须是__cdecl,不允许更改;
    默认调用约定一般能够通过编译器设置进行更改,如果你的代码依赖于调用约定,请明确指出需要使用的调用约定;


    Delphi6中的函数调用约定;


            调用约定        堆栈清除    参数传递
            register        函数体      从左到右,优先使用寄存器(EAX,EDX,ECX),然后使用堆栈
            pascal          函数体      从左到右,通过堆栈传递
            cdecl           调用者      从右到左,通过堆栈传递(与C/C++默认调用约定兼容)
            stdcall         函数体      从右到左,通过堆栈传递(与VC中的__stdcall兼容)
            safecall        函数体      从右到左,通过堆栈传递(同stdcall)

    Delphi中的默认调用约定是register,它也是我认为最有效率的一种调用方式,而cdecl是我认为综合效率最差的一种调用方式;
    VC中的__fastcall调用约定一般比register效率稍差一些;

    C++Builder6中的函数调用约定;


            调用约定        堆栈清除    参数传递
            __fastcall      函数体      从左到右,优先使用寄存器(EAX,EDX,ECX),然后使用堆栈 (兼容Delphi的register)
            (register与__fastcall等同)
            __pascal        函数体      从左到右,通过堆栈传递
            __cdecl         调用者      从右到左,通过堆栈传递(与C/C++默认调用约定兼容)
            __stdcall       函数体      从右到左,通过堆栈传递(与VC中的__stdcall兼容)
            __msfastcall    函数体      从右到左,优先使用寄存器(ECX,EDX),然后使用堆栈(兼容VC的__fastcall)

 

    常见的函数调用约定中,只有cdecl约定需要调用者来清除堆栈;
    C/C++中的函数支持参数数目不定的参数列表,比如printf函数;由于函数体不知道调用者在堆栈中压入了多少参数,
    所以函数体不能方便的知道应该怎样清除堆栈,那么最好的办法就是把清除堆栈的责任交给调用者;
    这应该就是cdecl调用约定存在的原因吧;

    VB一般使用的是stdcall调用约定;(ps：有更强的保证吗)
    Windows的API中,一般使用的是stdcall约定;(ps: 有更强的保证吗)
    建议在不同语言间的调用中(如DLL)最好采用stdcall调用约定,因为它在语言间兼容性支持最好;

    三:函数返回值传递方式
       其实，返回值的传递从处理上也可以想象为函数调用的一个out形参数； 函数返回值传递方式也是函数调用约定的一部分；
       有返回值的函数返回时：一般int、指针等32bit数据值(包括32bit结构)通过eax传递，(bool,char通过al传递，short通过 ax传递),特别的__int64等64bit结构(struct) 通过edx,eax两个寄存器来传递(同理：32bit整形在16bit环境中通过dx,ax传递); 其他大小的结构(struct)返回时把其地址通过eax返回；(所以返回值类型不是1,2,4,8byte时，效率可能比较差)
       参数和返回值传递中，引用方式的类型可以看作与传递指针方式相同；
       float/double(包括Delphi中的extended)都是通过浮点寄存器st(0)返回；


    四：通过VC中的C++例子和产生出的汇编清单来对函数调用约定进行说明;

    (ps:后面虽然列出了很多汇编,但是我做了很详细的注释,我希望那些对汇编感到“恐惧”的人
    也能顺利的阅读; 并为那些想在VC中使用汇编的人提供一些帮助

    A:
    测试代码：


    int x;
    int __cdecl add(int a,int b) { return a+b; }//使用__cdecl调用约定
    int main(int argc, char* argv[])
    {
        x=add(1,2);
        return 0;
    }

 

    ; Debug模式编译后得到的汇编代码


    PUBLIC      ?x@@3HA                    ; x
    _BSS        SEGMENT
    ?x@@3HA     DD        01H DUP (?)      ; x变量
    _BSS        ENDS
    PUBLIC      ?add@@YAHHH@Z              ; add
    PUBLIC      _main
    EXTRN       __chkesp:NEAR
    ;           COMDAT       _main
    _TEXT       SEGMENT

    _main       PROC NEAR                  ; COMDAT        //main函数体

      push    ebp         ; //保存ebp的值到堆栈,退出函数前用pop ebp恢复
      mov     ebp, esp    ; //ebp指向当前堆栈; 函数中可以通过ebp来进行堆栈访问
      sub     esp, 64     ; //在堆栈中开辟64byte局部空间

                          ; //说明：这三条汇编指令是很多函数体开始的惯用法;
                          ; //用ebp指向堆栈(不会改变);并通过ebp来访问参数和局部变量;

push    ebx         ; //一般按照函数间调用的约定,函数中可以自由使用eax,ecx,edx;
      push    esi         ; //其它寄存器如果需要使用则需要保存,用完时恢复；也就是寄存器的使用约定； 这也使函数调用约定的一部分；
      push    edi         ; //即:在函数中调用了别的函数后,eax,ecx,edx很可能已经改变,
                          ; //而其它寄存器(ebx,esi,edi,ebp)的值可以放心继续使用(esp除外)

      lea    edi, DWORD PTR [ebp-64]
      mov    ecx, 16                 ; 00000010H
      mov    eax, -858993460         ; ccccccccH
      rep stosd                      ; //前面开辟的(16*4)byte局部空间全部填充0xCC
                                     ; //注意: 0xCC是调试中断(__asm int 3)的指令码,所以可以想象,当
                                     ; //程序错误的跳转到这个区域进行执行时将产生调试中断

      push   2                       ; //代码: x=add(1,2);
      push   1                       ; //从右到左入栈  (__cdecl调用约定!!!)
      call   ?add@@YAHHH@Z           ; 调用add函数;call指令将把下一条指令的地址(返回地址)压入堆栈
      add    esp, 8                  ; add函数调用完以后,调用者负责清理堆栈 (__cdecl调用约定!!!)
                                     ; 两个int型参数共使用了8byte空间的堆栈
      mov    DWORD PTR ?x@@3HA, eax  ; 将add函数的返回值存入x变量中,可以看出add函数的返回值放在eax中

      xor    eax, eax      ; //原代码:return 0;   执行eax清零,main函数的返回值0放在eax中

      pop    edi
      pop    esi
      pop    ebx           ; //恢复edi,esi,ebx寄存器
      add    esp, 64       ; //恢复64byte局部空间
      cmp    ebp, esp
      call    __chkesp     ; //到这里时应该ebp==esp, Debug版进行确认,如果不等,抛出异常等
      mov    esp, ebp
      pop    ebp           ; //恢复ebp寄存器
      ret    0
    _main     ENDP
    _TEXT     ENDS

    ;//下面是add函数的代码,就不用解释的像上面那么详细了


    ;        COMDAT  ?add@@YAHHH@Z
    _TEXT            SEGMENT
    _a$ = 8                                ;//参数a相对于堆栈偏移8
    _b$ = 12                               ;//参数b相对于堆栈偏移12

    ?add@@YAHHH@Z PROC NEAR                ; add, COMDAT        //add函数体

      push        ebp
      mov         ebp, esp
      sub         esp, 64                  ; 00000040H
      push        ebx
      push        esi
      push        edi
      lea         edi, DWORD PTR [ebp-64]
      mov         ecx, 16                  ; 00000010H
      mov         eax, -858993460          ; ccccccccH
      rep stosd

      mov         eax, DWORD PTR _a$[ebp]  ;将参数a的值移动到eax
      add         eax, DWORD PTR _b$[ebp]  ;将参数b的值累加到eax; 可以看出返回值通过eax返回

      pop         edi
      pop         esi
      pop         ebx
      mov         esp, ebp
      pop         ebp
      ret         0                     ; 函数体不管堆栈的参数清理 (__cdecl调用约定!!!)
                                        ; ret指令将取出call指令压入的返回地址,并跳转过去继续执行

    ?add@@YAHHH@Z ENDP                  ; add
    _TEXT        ENDS
    END

    ; 再来看一下Release模式编译后得到的汇编代码
    ; 可以看出,这比Debug模式少了很多的汇编指令,速度当然可能更快了;不再做详细说明了,请对照上面的解释


    PUBLIC        ?x@@3HA                   ; x
    _BSS          SEGMENT
    ?x@@3HA       DD        01H DUP (?)     ; x
    _BSS          ENDS
    PUBLIC        ?add@@YAHHH@Z             ; add
    PUBLIC        _main
    ;             COMDAT            _main
    _TEXT         SEGMENT

    _main         PROC NEAR                 ; COMDAT        //main函数体

      push    2
      push    1                       ; //从右到左入栈  (__cdecl调用约定!!!)
      call    ?add@@YAHHH@Z           ; //调用add函数;
      mov     DWORD PTR ?x@@3HA, eax  ; x
      add     esp, 8                  ; //调用者负责清理堆栈 (__cdecl调用约定!!!)

      xor     eax, eax
      ret     0
    _main        ENDP
    _TEXT        ENDS

    ;            COMDAT   ?add@@YAHHH@Z
    _TEXT        SEGMENT
    _a$ = 8
    _b$ = 12

    ?add@@YAHHH@Z PROC NEAR            ; add, COMDAT        //add函数体

      mov   eax, DWORD PTR _b$[esp-4]  ;将参数b的值移动到eax
      mov   ecx, DWORD PTR _a$[esp-4]  ;将参数a的值移动到ecx
      add   eax, ecx                   ;将ecx的值累加到eax; 返回值通过eax传递
      ret   0                          ;函数体不管堆栈的参数清理 (__cdecl调用约定!!!)
    ?add@@YAHHH@Z ENDP                 ; add
    _TEXT         ENDS
    END

 

    下面的分析中将只给出Release模式编译后的汇编代码

    B:
    声明add函数为__stdcall调用约定

    int x;
    int __stdcall add(int a,int b) { return a+b; }
    int main(int argc, char* argv[])
    {
        x=add(1,2);
        return 0;
    }
;来看产生的汇编代码：

 

    ; //main函数体
      push    2
      push    1                        ; //从右到左入栈
      call    ?add@@YGHHH@Z            ; add
      mov     DWORD PTR ?x@@3HA, eax   ; x
      xor     eax, eax
      ret     0

    ; //add函数体
      mov     eax, DWORD PTR _b$[esp-4]
      mov     ecx, DWORD PTR _a$[esp-4]
      add     eax, ecx
      ret     8                        ; //函数体负责清栈 ;两个int型参数共使用了8byte空间的堆栈


    C:
    声明add函数为__fastcall调用约定

    int x;
    int __fastcall add(int a,int b) { return a+b; }
    int main(int argc, char* argv[])
    {
        x=add(1,2);
        return 0;
    }

    ;来看产生的汇编代码：


    ; //main函数体
      mov    edx, 2                    ; b通过寄存器edx传递
      mov    ecx, 1                    ; a通过寄存器ecx传递
      call   ?add@@YIHHH@Z             ; add
      mov    DWORD PTR ?x@@3HA, eax    ; x
      xor    eax, eax
      ret    0

    ; //add函数体
      lea    eax, DWORD PTR [ecx+edx]  ; //a,b参数值已经在ecx,edx中,该句将这两个值的和放到eax作为返回值;
      ret    0                         ; //这里应该函数体负责清栈 ;但因为两个参数已经通过寄存器传递
                                       ; //了,没有使用堆栈,所以ret 0;


    D:
    来看一下类的成员函数的调用：


    struct T
    {
            int start0;
            T():start0(1){}
            int  add(int a,int b); //类成员函数;只要不明确声明调用约定则默认使用thiscall调用约定;
    };
    int  T::add(int a,int b) { return (*this).start0+a+b; }

    int x;
    int main(int argc, char* argv[])
    {
            T t;
            x=t.add(1,2);
            return 0;
    }


    来看产生的汇编代码：


    ; //main函数体
      push    ecx                         ; //保存ecx
      push    2
      push    1                           ; //参数从右到左入栈
      lea     ecx, DWORD PTR _t$[esp+12]  ; //t的地址保存到ecx
      mov     DWORD PTR _t$[esp+12], 1    ; //执行t::start0=1;
      call    ?add@T@@QAEHHH@Z            ; //调用T::add函数,这时ecx中存放了t的的地址(this指针);
      mov     DWORD PTR ?x@@3HA, eax      ; x
      xor     eax, eax
      pop     ecx
      ret     0

    ; //T::add函数体
      mov     eax, DWORD PTR [ecx]        ; //通过this指针(保存在ecx)将start0的值移动到eax
      mov     ecx, DWORD PTR _a$[esp-4]   ; //把a的值移动到ecx; this的值将丢失,但函数体中已经不需要了
      add     eax, ecx                    ; //将a的值累加到eax
      mov     ecx, DWORD PTR _b$[esp-4]   ; //把b的值移动到ecx;
      add     eax, ecx                    ; //将b的值累加到eax
      ret     8                           ; //函数体负责清栈 ;


    五: 其他

    1.在VC中实现一个函数体时可以使用__declspec(naked)声明,它告诉编译器,不要为函数体自动产生开始和结束码;
    2.在VC6中,想得到汇编代码清单,设置方法为：

    引用:[Project]->[Setting...]->[C++]->[Category:]->[Listing Files]->[Listing file type:]->[Assembily ,...]

    3.VC6中嵌入汇编代码的方式为：

                __asm { <汇编语句s> }
             或 __asm <一条汇编语句>

    4.VC6中重新设定函数使用的默认调用约定的方法是：
    引用:
    在[Project]->[Setting...]->[C++]->[Project Options:]中增加编译设置
    比如：/Gd 代表__cdecl; /Gr 代表__fastcall; /Gz 代表__stdcall

 

 

 

 

 

 

  使用C/C++语言开发软件的程序员经常碰到这样的问题：有时候是程序编译没有问题，但是链接的时候总是报告函数不存在（经典的LNK 2001错误），有时候是程序编译和链接都没有错误，但是只要调用库中的函数就会出现堆栈异常。这些现象通常是出现在C和C++的代码混合使用的情况下或在C++程序中使用第三方的库的情况下（不是用C++语言开发的），其实这都是函数调用约定（Calling Convention）和函数名修饰（Decorated Name）规则惹的祸。函数调用方式决定了函数参数入栈的顺序，是由调用者函数还是被调用函数负责清除栈中的参数等问题，而函数名修饰规则决定了编译器使用何种名字修饰方式来区分不同的函数，如果函数之间的调用约定不匹配或者名字修饰不匹配就会产生以上的问题。本文分别对C和C++这两种编程语言的函数调用约定和函数名修饰规则进行详细的解释，比较了它们的异同之处，并举例说明了以上问题出现的原因。
函数调用约定（Calling Convention）

    函数调用约定不仅决定了发生函数调用时函数参数的入栈顺序，还决定了是由调用者函数还是被调用函数负责清除栈中的参数，还原堆栈。函数调用约定有很多方式，除了常见的__cdecl，__fastcall和__stdcall之外，C++的编译器还支持thiscall方式，不少C/C++编译器还支持 naked call方式。这么多函数调用约定常常令许多程序员很迷惑，到底它们是怎么回事，都是在什么情况下使用呢？下面就分别介绍这几种函数调用约定。


1.__cdecl

    编译器的命令行参数是/Gd。__cdecl方式是C/C++编译器默认的函数调用约定，所有非C++成员函数和那些没有用__stdcall或 __fastcall声明的函数都默认是__cdecl方式，它使用C函数调用方式，函数参数按照从右向左的顺序入栈，函数调用者负责清除栈中的参数，由于每次函数调用都要由编译器产生清除（还原）堆栈的代码，所以使用__cdecl方式编译的程序比使用__stdcall方式编译的程序要大很多，但是 __cdecl调用方式是由函数调用者负责清除栈中的函数参数，所以这种方式支持可变参数，比如printf和windows的API wsprintf就是__cdecl调用方式。对于C函数，__cdecl方式的名字修饰约定是在函数名称前添加一个下划线；对于C++函数，除非特别使用extern "C"，C++函数使用不同的名字修饰方式。


2.__fastcall

    编译器的命令行参数是/Gr。__fastcall函数调用约定在可能的情况下使用寄存器传递参数，通常是前两个 DWORD类型的参数或较小的参数使用ECX和EDX寄存器传递，其余参数按照从右向左的顺序入栈，被调用函数在返回之前负责清除栈中的参数。编译器使用两个@修饰函数名字，后跟十进制数表示的函数参数列表大小，例如：@function_name@number。需要注意的是__fastcall函数调用约定在不同的编译器上可能有不同的实现，比如16位的编译器和32位的编译器，另外，在使用内嵌汇编代码时，还要注意不能和编译器使用的寄存器有冲突。


3.__stdcall
 
    编译器的命令行参数是/Gz，__stdcall是Pascal程序的缺省调用方式，大多数Windows的API也是__stdcall调用约定。 __stdcall函数调用约定将函数参数从右向左入栈，除非使用指针或引用类型的参数，所有参数采用传值方式传递，由被调用函数负责清除栈中的参数。对于C函数，__stdcall的名称修饰方式是在函数名字前添加下划线，在函数名字后添加@和函数参数的大小，例如：_functionname@number

4.thiscall

    thiscall只用在C++成员函数的调用，函数参数按照从右向左的顺序入栈，类实例的this指针通过ECX寄存器传递。需要注意的是thiscall不是C++的关键字，不能使用thiscall声明函数，它只能由编译器使用。

5.naked call

    采用前面几种函数调用约定的函数，编译器会在必要的时候自动在函数开始添加保存ESI，EDI，EBX，EBP寄存器的代码，在退出函数时恢复这些寄存器的内容，使用naked call方式声明的函数不会添加这样的代码，这也就是为什么称其为naked的原因吧。naked  call不是类型修饰符，故必须和_declspec共同使用。

    VC的编译环境默认是使用__cdecl调用约定，也可以在编译环境的Project Setting...菜单－》C/C++ ＝》Code  Generation项选择设置函数调用约定。也可以直接在函数声明前添加关键字__stdcall、__cdecl或__fastcall等单独确定函数的调用方式。在Windows系统上开发软件常用到WINAPI宏，它可以根据编译设置翻译成适当的函数调用约定，在WIN32中，它被定义为 __stdcall。

 

函数名字修饰（Decorated Name）方式

    函数的名字修饰（Decorated Name）就是编译器在编译期间创建的一个字符串，用来指明函数的定义或原型。LINK程序或其他工具有时需要指定函数的名字修饰来定位函数的正确位置。多数情况下程序员并不需要知道函数的名字修饰，LINK程序或其他工具会自动区分他们。当然，在某些情况下需要指定函数的名字修饰，例如在C++程序中，为了让LINK程序或其他工具能够匹配到正确的函数名字，就必须为重载函数和一些特殊的函数（如构造函数和析构函数）指定名字装饰。另一种需要指定函数的名字修饰的情况是在汇编程序中调用C或C++的函数。如果函数名字，调用约定，返回值类型或函数参数有任何改变，原来的名字修饰就不再有效，必须指定新的名字修饰。C和C++程序的函数在内部使用不同的名字修饰方式，下面将分别介绍这两种方式。

1. C编译器的函数名修饰规则

    对于__stdcall调用约定，编译器和链接器会在输出函数名前加上一个下划线前缀，函数名后面加上一个“@”符号和其参数的字节数，例如_functionname@number。__cdecl调用约定仅在输出函数名前加上一个下划线前缀，例如_functionname。__fastcall调用约定在输出函数名前加上一个“@”符号，后面也是一个“@”符号和其参数的字节数，例如@functionname@number。  
 
2. C++编译器的函数名修饰规则

    C++的函数名修饰规则有些复杂，但是信息更充分，通过分析修饰名不仅能够知道函数的调用方式，返回值类型，参数个数甚至参数类型。不管 __cdecl，__fastcall还是__stdcall调用方式，函数修饰都是以一个“?”开始，后面紧跟函数的名字，再后面是参数表的开始标识和按照参数类型代号拼出的参数表。对于__stdcall方式，参数表的开始标识是“@@YG”，对于__cdecl方式则是“@@YA”，对于__fastcall方式则是“@@YI”。参数表的拼写代号如下所示：
X--void  
D--char  
E--unsigned char  
F--short  
H--int  
I--unsigned int  
J--long  
K--unsigned long（DWORD）
M--float  
N--double  
_N--bool
U--struct
....
指针的方式有些特别，用PA表示指针，用PB表示const类型的指针。后面的代号表明指针类型，如果相同类型的指针连续出现，以“0”代替，一个“0”代表一次重复。U表示结构类型，通常后跟结构体的类型名，用“@@”表示结构类型名的结束。函数的返回值不作特殊处理，它的描述方式和函数参数一样，紧跟着参数表的开始标志，也就是说，函数参数表的第一项实际上是表示函数的返回值类型。参数表后以“@Z”标识整个名字的结束，如果该函数无参数，则以“Z”标识结束。下面举两个例子，假如有以下函数声明：
int Function1(char *var1,unsigned long);

其函数修饰名为“?Function1@@YGHPADK@Z”，而对于函数声明：
void Function2();

其函数修饰名则为“?Function2@@YGXXZ” 。

 

    对于C++的类成员函数（其调用方式是thiscall），函数的名字修饰与非成员的C++函数稍有不同，首先就是在函数名字和参数表之间插入以“@”字符引导的类名；其次是参数表的开始标识不同，公有（public）成员函数的标识是“@@QAE”,保护（protected）成员函数的标识是“@@IAE”,私有（private）成员函数的标识是“@@AAE”，如果函数声明使用了const关键字，则相应的标识应分别为“@@QBE”，“@@IBE”和“@@ABE”。如果参数类型是类实例的引用，则使用“AAV1”，对于const类型的引用，则使用“ABV1”。下面就以类CTest为例说明C++成员函数的名字修饰规则：
class CTest
{
......
private:
    void Function(int);
protected:
    void CopyInfo(const CTest &src);
public:
    long DrawText(HDC hdc, long pos, const TCHAR* text, RGBQUAD color, BYTE bUnder, bool bSet);
    long InsightClass(DWORD dwClass) const;
......
};

 

对于成员函数Function，其函数修饰名为“?Function@CTest@@AAEXH@Z”，字符串“@@AAE”表示这是一个私有函数。成员函数CopyInfo只有一个参数，是对类CTest的const引用参数，其函数修饰名为“?CopyInfo@CTest@@IAEXABV1@@Z”。 DrawText是一个比较复杂的函数声明，不仅有字符串参数，还有结构体参数和HDC句柄参数，需要指出的是HDC实际上是一个HDC__结构类型的指针，这个参数的表示就是“PAUHDC__@@”，其完整的函数修饰名为“?DrawText@CTest@@QAEJPAUHDC__@@JPBDUtagRGBQUAD@@E_N@Z”。InsightClass是一个共有的const函数，它的成员函数标识是“@@QBE”，完整的修饰名就是“?InsightClass@CTest@@QBEJK@Z”。

无论是C函数名修饰方式还是C++函数名修饰方式均不改变输出函数名中的字符大小写，这和PASCAL调用约定不同，PASCAL约定输出的函数名无任何修饰且全部大写。

3.查看函数的名字修饰

    有两种方式可以检查你的程序中的函数的名字修饰：使用编译输出列表或使用Dumpbin工具。使用/FAc，/FAs或/FAcs命令行参数可以让编译器输出函数或变量名字列表。使用dumpbin.exe /SYMBOLS命令也可以获得obj文件或lib文件中的函数或变量名字列表。此外，还可以使用 undname.exe 将修饰名转换为未修饰形式。

 
函数调用约定和名字修饰规则不匹配引起的常见问题

    函数调用时如果出现堆栈异常，十有八九是由于函数调用约定不匹配引起的。比如动态链接库a有以下导出函数：
long MakeFun(long lFun);

动态库生成的时候采用的函数调用约定是__stdcall，所以编译生成的a.dll中函数MakeFun的调用约定是_stdcall，也就是函数调用时参数从右向左入栈，函数返回时自己还原堆栈。现在某个程序模块b要引用a中的MakeFun，b和a一样使用 C++方式编译，只是b模块的函数调用方式是__cdecl，由于b包含了a提供的头文件中MakeFun函数声明，所以MakeFun在b模块中被其它调用MakeFun的函数认为是__cdecl调用方式，b模块中的这些函数在调用完MakeFun当然要帮着恢复堆栈啦，可是MakeFun已经在结束时自己恢复了堆栈，b模块中的函数这样多此一举就引起了栈指针错误，从而引发堆栈异常。宏观上的现象就是函数调用没有问题（因为参数传递顺序是一样的），MakeFun也完成了自己的功能，只是函数返回后引发错误。解决的方法也很简单，只要保证两个模块的在编译时设置相同的函数调用约定就行了。

 

    在了解了函数调用约定和函数的名修饰规则之后，再来看在C++程序中使用C语言编译的库时经常出现的LNK 2001错误就很简单了。还以上面例子的两个模块为例，这一次两个模块在编译的时候都采用__stdcall调用约定，但是a.dll使用C语言的语法编译的（C语言方式），所以a.dll的载入库a.lib中MakeFun函数的名字修饰就是“_MakeFun@4”。b包含了a提供的头文件中MakeFun函数声明，但是由于b采用的是C++语言编译，所以MakeFun在b模块中被按照C++的名字修饰规则命名为“?MakeFun@@YGJJ@Z”，编译过程相安无事，链接程序时c++的链接器就到a.lib中去找“?MakeFun@@YGJJ@Z”，但是a.lib中只有“_MakeFun@4”，没有“?MakeFun@@YGJJ@Z”，于是链接器就报告：

error LNK2001: unresolved external symbol ?MakeFun@@YGJJ@Z

解决的方法和简单，就是要让b模块知道这个函数是C语言编译的，extern "C"可以做到这一点。一个采用C语言编译的库应该考虑到使用这个库的程序可能是C++程序（使用C++编译器），所以在设计头文件时应该注意这一点。通常应该这样声明头文件：

#ifdef _cplusplus
extern "C" {
#endif

long MakeFun(long lFun);

#ifdef _cplusplus
}
#endif

 

这样C++的编译器就知道MakeFun的修饰名是“_MakeFun@4”，就不会有链接错误了。

    许多人不明白，为什么我使用的编译器都是VC的编译器还会产生“error LNK2001”错误？其实，VC的编译器会根据源文件的扩展名选择编译方式，如果文件的扩展名是“.C”，编译器会采用C的语法编译，如果扩展名是 “.cpp”，编译器会使用C++的语法编译程序，所以，最好的方法就是使用extern "C"。