Windows下安装Rust

Windows下安装Rust

下载RUSTUP-INIT.EXE文件

在https://www.rust-lang.org/tools/install页面下载rustup-init.exe的32位或64版本安装文件，注意此文件可能下载非常慢，你可以通过百度网盘下载(网盘内为x64版本)。

链接：https://pan.baidu.com/s/13PfQMDUKirk495OyfJnuDw
提取码：6666

设置加速RUSTUP国内加速镜像

# 字节跳动
RUSTUP_DIST_SERVER=https://rsproxy.cn
RUSTUP_UPDATE_ROOT=https://rsproxy.cn/rustup

# 中国科学技术大学
RUSTUP_DIST_SERVER=https://mirrors.ustc.edu.cn/rust-static
RUSTUP_UPDATE_ROOT=https://mirrors.ustc.edu.cn/rust-static/rustup

# 清华大学
RUSTUP_DIST_SERVER=https://mirrors.tuna.tsinghua.edu.cn/rustup

# 上海交通大学
RUSTUP_DIST_SERVER=https://mirrors.sjtug.sjtu.edu.cn/rust-static/

设置临时环境变量

运行cmd.exe在控制窗口中输入如下命令

SET RUSTUP_DIST_SERVER=https://mirrors.ustc.edu.cn/rust-static

运行rustup-init.exe

将已下载好的rustup-init.exe拖放到当前的cmd窗口并按下回车键，在随后窗口输入y并回车，然后输入1再次按回车确认开始自动安装。

下载Rust源文件

安装完成后，执行rustup component add rust-src下载Rust源码，此操作可活动VSCode中 Rust-analyzer插件下载源码操作。

直接使用install.bat脚本进行安装

建议使用此方法安装，install.bat脚本会自动将RUSTUP_DIST_SERVER与RUSTUP_UPDATE_ROOT添加到系统环境变量，脚本源码：

@ECHO OFF
SET DIST_SERVER=https://rsproxy.cn
SET UPDATE_ROOT=https://rsproxy.cn/rustup

REM 检测环境变量是否存在且与设定值相同
IF /I "%RUSTUP_DIST_SERVER%" NEQ "%DIST_SERVER%" (
    SETX "RUSTUP_DIST_SERVER" "%DIST_SERVER%" /M
    SET RUSTUP_DIST_SERVER=%DIST_SERVER%
)

REM 检测环境变量是否存在且与设定值相同
IF /I "%RUSTUP_UPDATE_ROOT%" NEQ "%UPDATE_ROOT%" (
    SETX "RUSTUP_UPDATE_ROOT" "%UPDATE_ROOT%" /M
    SET RUSTUP_UPDATE_ROOT=%UPDATE_ROOT%
)

ECHO 安装Rust
CD /D %~DP0
rustup-init.exe -y -v

ECHO 设置代理配置文件
SET FCFG=%USERPROFILE%\.cargo\config
 >%FCFG% ECHO [source.crates-io]
>>%FCFG% ECHO replace-with = 'rsproxy'
>>%FCFG% ECHO.
>>%FCFG% ECHO [source.rsproxy]
>>%FCFG% ECHO registry = "https://rsproxy.cn/crates.io-index"
>>%FCFG% ECHO.
>>%FCFG% ECHO [registries.rsproxy]
>>%FCFG% ECHO index = "https://rsproxy.cn/crates.io-index"
>>%FCFG% ECHO.
>>%FCFG% ECHO [net]
>>%FCFG% ECHO git-fetch-with-cli = true

ECHO 下载Rust源码
rustup component add rust-src

ECHO.
ECHO.
ECHO.
ECHO 安装完成.
ECHO.
ECHO.
ECHO.
PAUSE>NUL