bat 脚本删除7天前的文件

文件格式: 
    F:\xxx\test\20180909.rar
    F:\xxx\test\20180910.rar

@echo off 
echo ##################################################################
echo # delete DataBackup
echo ##################################################################
set sourceDir="F:\xxx\test"

set DaysAgo=7

for /f "tokens=2 delims==" %%a in ('wmic path win32_operatingsystem get LocalDateTime /value') do (
  set t=%%a
)

call :DateToDays =%t:~0,4% %t:~4,2% %t:~6,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%%DstMonth%%DstDay%

for /f %%i in ('dir /b %sourceDir%') do  (
    rem echo "%%i"
    call :DeleteFile =%%i %DstDate% %sourceDir%
)

pause>nul

goto :eof
:DeleteFile %fileName% %day% %dir%
setlocal ENABLEEXTENSIONS
set fileName=%1&set day=%2&set dir=%3
set /a s=%fileName:~0,8%
rem echo s=%s%
if %day% gtr %s% ( 
	echo delete %fileName%
	del /a /f /q "%dir%\%fileName%"
    )
endlocal& goto :EOF

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF