【delphi】实现微信公众号，小程序消息加密解密函数

于 2021-02-13 21:37:33 发布
阅读量640 收藏 6
点赞数 1
分类专栏： Delphi 文章标签： 微信公众号 消息加密解密 Delphi 微信公众号 Delphi 消息加密 加密解密
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/sensor_WU/article/details/113803842
版权

在开发微信公众号，小程序的时候，可以配置成明文模式，兼容模式，安全模式。当配置成安全模式的时候，就需要对消息进行加密，解密。说明下，只有被动回复的时候需要进行消息加密，其它主动请求的API不需要对消息进行加密。

在这里插入图片描述
微信官方提供的没有delphi的例子，这里根据官方文档以及C#的例子，更改成delphi的加密解密函数，已经在公众号中使用。核心源代码如下（没有按照对象实现，就是简单的函数实现）：

{2021-02-10 大年29 创建
 主要实现微信 消息加密、解密功能
 参考微信的 C# Demo 实现

 错误代码
  //-40001 ： 签名验证错误
  //-40002 :  xml解析失败
  //-40003 :  sha加密生成签名失败
  //-40004 :  AESKey 非法
  //-40005 :  appid 校验错误
  //-40006 :  AES 加密失败
  //-40007 ： AES 解密失败
  //-40008 ： 解密后得到的buffer非法
  //-40009 :  base64加密异常
  //-40010 :  base64解密异常

}
unit uWX_PUB_Cryptography;

interface
uses
  System.Classes,
  System.SysUtils,
  System.Math,
  System.NetEncoding,

  Xml.XMLIntf,
  Xml.XMLDoc,
  WinApi.ActiveX,

  uWX_PUB_ElAES,
  system.Hash;

const
  WXBizMsgCrypt_OK = 0;
  WXBizMsgCrypt_ValidateSignature_Error = -40001;
  WXBizMsgCrypt_ParseXml_Error = -40002;
  WXBizMsgCrypt_ComputeSignature_Error = -40003;
  WXBizMsgCrypt_IllegalAesKey = -40004;
  WXBizMsgCrypt_ValidateAppid_Error = -40005;
  WXBizMsgCrypt_EncryptAES_Error = -40006;
  WXBizMsgCrypt_DecryptAES_Error = -40007;
  WXBizMsgCrypt_IllegalBuffer = -40008;
  WXBizMsgCrypt_EncodeBase64_Error = -40009;
  WXBizMsgCrypt_DecodeBase64_Error = -40010;


//1. 生成签名函数
function GenarateSinature(sToken, sTimeStamp, sNonce, sMsgEncrypt: string) : string;
//2. 验证签名是否正确
function VerifySignature(sToken, sTimeStamp, sNonce, sMsgEncrypt, sSigture: string) : Boolean;
//3. 解密消息
function DecryptMsg(sMsgSignature, sTimeStamp, sNonce, sPostData, sToken, sAppID, sEncodingAESKey : string; var sMsg: string) : integer;
//4. 加密消息
function EncryptMsg(sReplyMsg, sTimeStamp, sNonce, sToken, sAppid, sEncodingAESKey : string; var sEncryptMsg : string) : integer;
//5. 实际的加密算法
function AES_encrypt(Input, EncodingAESKey, appid : string) : string;
//6. 实际的解密算法
function AES_decrypt(sEncryptMsg, EncodingAESKey : string; var appid : string) : string;
//6. 创建n个长度的随机字符串
function CreateRandCode(Keylen : Word = 16) : string;

//进行

implementation

//1. 生成签名函数
function GenarateSinature(sToken, sTimeStamp, sNonce, sMsgEncrypt: string) : string;
var
   tmpStr: string;
   SB  : TArray<string>;
   i,j : integer;
 begin
   SetLength(SB,4);
   SB[0] := sToken;
   SB[1] := sTimeStamp;
   SB[2] := sNonce;
   SB[3] := sMsgEncrypt;

   for i := low(SB) to High(SB) - 1 do
     for j := low(SB) to High(SB) - i - 1 do
       if SB[j] > SB[j + 1] then
          begin
            tmpStr := SB[j];
            SB[j] := SB[j + 1];
            SB[j + 1] := tmpStr;
          end;

   tmpStr := SB[0] + SB[1] + SB[2] + SB[3];   //这里似乎需要按照 ANSI 字节加密
   //计算签名
   Result :=  THashSHA1.GetHashString(tmpStr);
   Result := Result.Replace('-','').ToLower;


 end;

//2. 验证签名是否正确
function VerifySignature(sToken, sTimeStamp, sNonce, sMsgEncrypt, sSigture: string) : Boolean;
begin
  Result := GenarateSinature(sToken, sTimeStamp, sNonce, sMsgEncrypt) = sSigture;
end;

//3. 解密消息
function DecryptMsg(sMsgSignature, sTimeStamp, sNonce, sPostData, sToken, sAppID, sEncodingAESKey : string; var sMsg: string) : integer;
var
  FXML : IXMLDocument;
  sEncryptMsg : string;
  appid : string;
begin
  Result := -1;  //初始值
  //如果密钥不正确，则直接返回
  if length(sEncodingAESKey) <> 43 then
     Exit(WXBizMsgCrypt_IllegalAesKey);

  //解析除实际需要进行解密的字符串
  CoInitialize(nil);  //CoUninitialize;
  FXML := NewXMLDocument; // TXMLDocument.Create(Self);
  //接收到的数据位于 RequestData 中
  FXML.XML.Text := sPostData;  //收到的具体内容;
  try
    FXML.Active := True;
    sEncryptMsg := FXML.DocumentElement.ChildNodes['Encrypt'].Text;          //需要解密的数据
  except on E: Exception do
    begin
      exit(WXBizMsgCrypt_ParseXml_Error);
    end;
  end;
  CoInitialize(nil);
  //如果签名失败，直接退出
  if not VerifySignature(sToken, sTimeStamp, sNonce, sEncryptMsg, sMsgSignature) then Exit(WXBizMsgCrypt_ValidateSignature_Error);
  //进行数据解密
  try
     sMsg := AES_decrypt(sEncryptMsg, sEncodingAESKey, appid);

  except on E: Exception do
     Exit(WXBizMsgCrypt_DecryptAES_Error);
  end;

  if appid <> sAppID then Exit(WXBizMsgCrypt_ValidateAppid_Error);

  Result := 0;
end;


//4. 加密消息
function EncryptMsg(sReplyMsg, sTimeStamp, sNonce, sToken, sAppid, sEncodingAESKey : string; var sEncryptMsg : string) : integer;
var
  RAW, MsgSigature : string;

   EncryptLabelHead,
   EncryptLabelTail,
   MsgSigLabelHead,
   MsgSigLabelTail,
   TimeStampLabelHead,
   TimeStampLabelTail,
   NonceLabelHead,
   NonceLabelTail : string;

begin
  //如果密钥不正确，则直接返回
  if length(sEncodingAESKey) <> 43 then
     Exit(WXBizMsgCrypt_IllegalAesKey);
  //进行数据加密
  try
    RAW := AES_encrypt(sReplyMsg, sEncodingAESKey, sAppid);
  except on E: Exception do
    Exit(WXBizMsgCrypt_EncryptAES_Error);
  end;

  //计算签名
  MsgSigature := GenarateSinature(sToken, sTimeStamp, sNonce, RAW);

   EncryptLabelHead := '<Encrypt><![CDATA[';
   EncryptLabelTail := ']]></Encrypt>';
   MsgSigLabelHead := '<MsgSignature><![CDATA[';
   MsgSigLabelTail := ']]></MsgSignature>';
   TimeStampLabelHead := '<TimeStamp><![CDATA[';
   TimeStampLabelTail := ']]></TimeStamp>';
   NonceLabelHead := '<Nonce><![CDATA[';
   NonceLabelTail := ']]></Nonce>';


   sEncryptMsg := sEncryptMsg + '<xml>' + EncryptLabelHead + raw + EncryptLabelTail;
   sEncryptMsg := sEncryptMsg + MsgSigLabelHead + MsgSigature + MsgSigLabelTail;
   sEncryptMsg := sEncryptMsg + TimeStampLabelHead + sTimeStamp + TimeStampLabelTail;
   sEncryptMsg := sEncryptMsg + NonceLabelHead + sNonce + NonceLabelTail;
   sEncryptMsg := sEncryptMsg + '</xml>';

end;

//5. 实际的加密算法
function AES_encrypt(Input, EncodingAESKey, appid : string) : string;
var
  Key : TBytes;
  iV  : TBytes;
  Randcode : string;

  bRand, bAppid, btmpMsg, bMsgLen, bMsg : TBytes;
  len : Integer;

  FAESKey256 : TAESKey256;
  FInitVectorBytes : TAESBuffer;
  SM : TMemoryStream;
  TM : TMemoryStream;
  B : TBytes;
  BB : Byte;
  i : integer;
begin
  Key := TNetEncoding.Base64.DecodeStringToBytes(EncodingAESKey);
  SetLength(iv,16);
  move(Key[0],iv[0],16);
  Randcode := {'046db2d37a77bad4'; //}  CreateRandCode(16);

  //组织加密的数据
  bRand   := TEncoding.UTF8.GetBytes(Randcode);
  bAppid  := TEncoding.UTF8.GetBytes(appid);
  btmpMsg := TEncoding.UTF8.GetBytes(Input);
  //消息的实际长度
  len := length(btmpMsg);
  SetLength(bMsgLen,Sizeof(len){4});
  //这一句实现的是低位在前，高位在后，需要调整为高位在前，低位在后
  move(len,bMsgLen[0], Sizeof(len){4});
  //需要调整为高位在前，低位在后
  BB := bMsgLen[0];
  bMsgLen[0] :=  bMsgLen[3];
  bMsgLen[3] := BB;
  BB := bMsgLen[1];
  bMsgLen[1] := bMsgLen[2];
  bMsgLen[2] := BB;

  //设置消息的实际长度
  SetLength(bMsg,Length(bRand) + Length(bMsgLen) + Length(bAppid) + Length(btmpMsg));
  //加密前数据进行组合
  move(bRand[0],bMsg[0],Length(bRand));
  move(bMsgLen[0],bMsg[Length(bRand)],Length(bMsgLen));
  move(btmpMsg[0],bMsg[Length(bRand) + Length(bMsgLen)],Length(btmpMsg));
  move(bAppid[0],bMsg[Length(bRand) + Length(bMsgLen) + Length(btmpMsg)],Length(bAppid));

  //根据微信约定，需要按照256bit位密钥进行补全加密前字符，也就是被加密字节长度必须是32 个字符的整数倍
  len := Length(bMsg);
  BB := len mod 32;   //取32的余数
  BB := 32 - BB;      //完全按照 C# 的官方Demo ，官方Demo 有点瑕疵

  SetLength(bMsg,len + BB);
  for i := len to len + BB do
      bMsg[i] := BB;

  //现在进行 AES 加密
  SM := TMemoryStream.Create;
  TM := TMemoryStream.Create;
  try
    Move(Key[0],FAESKey256[0],Length(Key));
    move(iv[0],FInitVectorBytes[0],16);
    SM.Write(bMsg[0],Length(bMsg));
    EncryptAESStreamCBC(SM, 0, FAESKey256, FInitVectorBytes, TM);
    TM.Position := 0;
    SetLength(B,TM.Size);
    TM.Read(B[0],TM.Size);

    //结果进行Base64编码
    Result := TNetEncoding.Base64.EncodeBytesToString(B);
    Result := Result.Replace(#13#10,'');
  finally
    SM.Free;
    TM.free;
  end;

end;


//6. 实际的解密算法
function AES_decrypt(sEncryptMsg, EncodingAESKey : string; var appid : string) : string;
var
  Key : TBytes;
  iV  : TBytes;
  Randcode : string;

  bRand, bAppid, btmpMsg, bMsgLen, bMsg : TBytes;
  len : Integer;

  FAESKey256 : TAESKey256;
  FInitVectorBytes : TAESBuffer;
  SM : TMemoryStream;
  TM : TMemoryStream;
  B : TBytes;
begin
  Key := TNetEncoding.Base64.DecodeStringToBytes(EncodingAESKey);
  SetLength(iv,16);
  move(Key[0],iv[0],16);

  //1. 进行Base64 解码
  bMsg := TNetEncoding.Base64.DecodeStringToBytes(sEncryptMsg);

  //现在进行 AES 解密密
  SM := TMemoryStream.Create;
  TM := TMemoryStream.Create;
  try
    Move(Key[0],FAESKey256[0],Length(Key));
    move(iv[0],FInitVectorBytes[0],16);
    SM.Write(bMsg[0],Length(bMsg));
    DecryptAESStreamCBC(SM, 0, FAESKey256, FInitVectorBytes, TM);
    TM.Position := 0;
    SetLength(B,TM.Size);
    TM.Read(B[0],TM.Size);  //此时 B中包含全部解密后的数据
  finally
    SM.Free;
    TM.free;
  end;

  //2.1 按顺序取出各个字段数据
  //2.1.1 随机16个字符长度的字符串
  SetLength(bRand, 16);
  move(B[0], bRand[0],16);

  Randcode := TEncoding.UTF8.GetString(bRand);

  //2.2.2 消息的长度
  SetLength(bMsgLen,4);
  move(B[16], bMsgLen[0],4);
  //2.2.3 实际的消息
  len := bMsgLen[0] * 256 * 256 * 256 + bMsgLen[1] * 256 * 256 + bMsgLen[2] * 256 + bMsgLen[3];

  SetLength(btmpMsg,len);
  move(B[20],btmpMsg[0],len);
  //2.2.4 appid 的长度
  SetLength(bAppid,Length(B) - 20 - len);
  move(B[20 + len], bAppid[0], Length(B) - 20 - len);
  //对于最后一个appid字段，需要按照CBC的补齐方式去除最后多余的字符
  if bAppid[length(bAppid) - 1] <= $20 then    //32
     SetLength(bAppid,Length(bAppid) - bAppid[length(bAppid) - 1]);


  appid := TEncoding.UTF8.GetString(bAppid);
  Result := TEncoding.UTF8.GetString(btmpMsg);

end;


//6. 创建那个长度的随机字符串
function CreateRandCode(Keylen : Word = 16) : string;
const
  KeyChar = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz012345679';
var
  i : integer;
begin
  Result := '';
  for I := 0 to KeyLen - 1 do
    begin
     Randomize;
     Result := Result + KeyChar.Substring(RandomRange(0,62),1);
    end;
end;

end.
海纳老吴
关注
  • 1
    点赞
  • 踩
  • 6
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 2
    评论
专栏目录
基于Delphi XE4的微信公众平台接口范例
07-07
这是本人根据微信公众平台接口文档简单得不能再简单的资料编写的一个范例，希望对各位delphi程序员开发微信应用带来点帮助。 文件包中包含两个例程，一个是服务器端的，另一个是为方便在本地测试，模拟微信服务器推送信息的小工具，均有源码。 要测试本范例，需要一个微信公众账号，一个有公网IP的服务器，本范例自带web服务器，所以请先停掉服务器上已有的web服务再运行。 本范例在Delphi XE4 Update1上开发。
微信easywechat的40001错误与500的python问题记录
最新发布
webnoties的专栏
05-24 287
由于easywechat默认文件缓存，而项目又分为了前后端2个目录，所以导致了缓存获取access_token失效的问题。（如后台更新了token，这时前台的token就会失效，反之亦然）40001：缓存在不同的目录文件。导致互相踢出了access_token，即过期了。500:查日志发现循环调用数据库导致连接异常。解决方法：缓存放到同一个redis中读取。把数据从for循环中拿到外面读取。
Delphi 开发微信公众平台 （二）- 用户管理
weixin_30496431的博客
05-06 243
一、用户标签管理 开发者可以使用用户标签管理的相关接口，实现对公众号的标签进行创建、查询、修改、删除等操作，也可以对用户进行打标签、取消标签等操作。 1、创建标签 /// <summary> /// 创建标签 /// </summary> /// <remarks> /// 一个公众号，最多可以创建100个标签。 /// </remar...
DelphiWebMVC微信公众号开发
07-11 588
开发微信公众号一般用php，java 等工具开发，很少用delphi开发，这里基于delphiwebmvc 开发的微信公众号部分代码进行开源。 开源地址：https://gitee.com/pearroom/Wechat DelphiWebMVC框架下的微信公众号管理平台 完成公众号文本...
【delphi】开发微信小程序后台控件（一）（含源代码、演示程序、控件使用帮助）
sensor_WU 博客
12-12 2751
1. 前言 微信小程序已经非常普及，但是遗憾的是官方提供的 SDK 等没有Delphi语言的，这样使用Delphi语言开发微信小程序后台就相对比较困难，需要研究平台API，费时费力，特别是调试API很费时间，有鉴于此，我用Delphi开发的微信小程序控件后台控件，使用该控件，只需要设置微信小程序的平台相关参数，就可以实现微信小程序后台功能。 2. 微信小程序控件介绍 2.1 控件实现基本功能 控件自带 Web 服务，无需安装任何 Web 服务控件！！ 小程序控件实现的功能： 1.JWT 支持 2.微信小程序
Delphi 微信小程序控件 前端小程序演示源程序Api_Demo.rar
12-13
Delphi 开发的微信小程序后台控件前端的小程序演示Demo。配合后端控件，演示小程序的实际功能。需要配合小程序后台，这是前端的小程序源代码。
【Delphi】微信支付控件（二）（半小时让您系统拥有支付功能）源代码、帮助文件、演示程序
sensor_WU 博客
12-18 700
3、控件 Demo 详细说明 3.1 演示程序主界面 3.2 公共功能 3.2.1 编辑控件属性 在此输入控件的属性，可以保存起来。 参数设置正确后，下面的下单地址等会自动生成。 3.2.2 启动支付服务 该菜单启动微信支付功能，与停止支付服务对应。正确设置好控件属性后就可以打开微信支付服务。如果参数这只不正确，打开微信支付服务会出现错误提示！ 例如设置参数如下： 打开微信支付服务 如果在打开微信支付服务的时候出现如下错误，就需要使用 HttpConfig 工具进行配置，因为控件使用的是微软的HT
微信小程序解密Delphi7源码.rar
06-09
在解密微信小程序后台的过程中，开发者可能利用了Delphi 7的高效性能和丰富的库支持，构建了一个能够处理微信小程序接口请求、数据加密解密等任务的服务器端程序。 描述中提到的"100% Delphi 源码"意味着所有代码都...
delphi登陆微信、发送微信消息.zip
12-09
delphi 登陆微信账号之后发送微信消息给用户。值得学习。功能详细，自己慢慢研究把。
delphi微信公众号【支持获取Access token、用户管理、模板消息、客服消息、群发消息、接收消息、被动回复用户消息、素材管理等】D7~XE10通用
07-21
【delphi微信公众号】支持获取Access token、用户管理、模板消息、客服消息、接收消息、被动回复用户消息、素材管理等，D7~XE10通用。微信公众号api文档：...
微信学习开发体验(微信协议/控件/开发/非公号)
06-22
微信学习开发体验版.微信协议,微信控件,微信开发,Delphi,非公众号
delphi小程序---里面都是完整的
11-06
这些小程序都是很完整的，大家可以借鉴借鉴。。
用Delphi XE7 Indy写的微信公众平台示例
01-27
Delphi XE7 Indy的IdHTTP写的微信公众平台，只做了部分功能，希望大家能用上 temp := JSONObject.Values['subscribe'].ToString; Memo1.Lines.Add('subscribe:' + temp); temp := JSONObject.Values['openid'].ToString; Memo1.Lines.Add('openid:' + temp); temp := JSONObject.Values['nickname'].ToString; Memo1.Lines.Add('nickname:' + temp); temp := JSONObject.Values['sex'].ToString; Memo1.Lines.Add('sex:' + temp); temp := JSONObject.Values['city'].ToString; Memo1.Lines.Add('city:' + temp); temp := JSONObject.Values['country'].ToString; Memo1.Lines.Add('country:' + temp); temp := JSONObject.Values['province'].ToString; Memo1.Lines.Add('province:' + temp); temp := JSONObject.Values['language'].ToString; Memo1.Lines.Add('language:' + temp); temp := JSONObject.Values['headimgurl'].ToString; Memo1.Lines.Add('headimgurl:' + temp); temp := JSONObject.Values['subscribe_time'].ToString; Memo1.Lines.Add('subscribe_time:' + temp); temp := JSONObject.Values['remark'].ToString; Memo1.Lines.Add('remark:' + temp);
DELPHI 微信公众平台 订阅号（二）
DELPHI 各种代码
10-22 521
一、采用IdHTTPServer unit fun_send; interface uses Winapi.Windows, System.Classes, IPPeerClient, REST.Client, REST.Types, System.JSON; function rest_get(server_url: string; send_name_strlist: TStringList; send_info_strlist: TStringList): string; func
Delphi 开发微信公众平台 （一）- 定义数据结构
weixin_30512785的博客
05-06 422
先定义数据类型： unit rtcMW.Wechat.Types; interface uses Generics.Collections, Rest.Json, System.Json.SerializeHelper, System.Json.Types, System.Json.Serializers;type TWechatTag = class Id: I...
php开发微信第三方平台遇到的那些坑
bofu123的博客
05-06 2008
php开发第三方平台遇到的那些坑
【delphi】开发微信小程序后台控件（二）（含源代码、演示程序、控件使用帮助）
sensor_WU 博客
12-13 1156
3. 微信小程序控件属性 序号 属性 类型 说明 1 AppID 字符串 小程序的APPID，每个小程序都有一个唯一对应的APPID。微信平台申请获得。 2 AppName 字符串 小程序名称，自己命名 3 AppSecret 字符串 小程序的密钥，每个小程序都有一个密钥，这个密钥和APPID属性对应。微信平台申请获得 4 Generic_BaseURL 字符串 Generic_BaseURL 是通用Web请求的基本地址，设置限制是前后都不能出现 / 字符。例如：SZHN ，不要
Delphi调用微信原生Web开发接口JS-SDK开发小程序及微信支付等的Rest API
pulledup的博客
10-24 3462
Delphi调用微信原生Web开发接口JS-SDK开发小程序及微信支付等 一、概述及API 1、JS-SDK是对之前的 WeixinJSBridge 的一个包装 2017年前，在移动端，受限于设备性能和网络速度，白屏会更加明显。我们团队把很多技术精力放置在如何帮助平台上的Web开发者解决这个问题。因此我们设计了一个 JS-SDK 的增强版本，其中有一个重要的功能，称之为“微信 Web 资源离线存储”。 微信 Web 资源离线存储是面向 Web 开发者提供的基于微...
delphi tidhttpserver 微信小程序
07-25
总结来说，使用 Delphi 的 TidHTTPServer 可以实现微信小程序的各种功能和业务逻辑，提供稳定和灵活的服务器端开发支持。 ### 回答3： Delphi是一种广泛应用于Windows平台的编程语言，它具有强大的开发工具和功能...
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

海纳老吴

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值