8086汇编实现猜数字游戏（2分）

---

前言

昨天晚上去做实验了，老师要求凑够3分，自夏季学期二叉树遍历的课设打击，我自知做难题力不从心，上次我没得选择，这次我有了选择的余地，就挑了一道1分的大小写转换和一道2分的猜数字游戏，来完成本次的汇编实验

---

一、猜数字游戏题目要求

• 游戏由两个玩家（甲、乙）共同完成：
➢首先由甲随意输入一个5位十进制整数，按回车结束
➢之后立即输出足够的回车换行，将该数清屏
➢甲将电脑交给乙进行猜测，乙输入一个数，输出“bigger”、
“smaller”、“exactly!”三个结果
➢猜测不对则继续，猜测正确则输出总共猜测的轮次数，程序结束。

二、代码设计与测试1.0（2021/10/21）

1.全部代码（第一种想法）

代码如下（CSDN没有汇编用的语法高亮，建议用VSCODE环境，汇编、链接、运行一步到位，太香啦~~~~~~~~）：

		.model  small
		.data
big 	db	'bigger', 0dh, 0ah, '$'
sma     db  'smaller', 0dh, 0ah, '$'
exact   db  'exactly!', 0dh, 0ah, '$'
crlf	db	0dh, 0ah, '$'
num     dw  ? 
        .stack
	    dw	10 dup(?)	;设置堆栈段
btm	    dw	?			;用来输出猜数次数
		.code
start:	mov	ax, @data
		mov	ds, ax
        mov	sp, offset btm;堆栈指针指向栈底
        mov cl, 2		;左移次数
        xor bx, bx
        xor dx, dx
input:  mov ah, 1		;输入被猜数
        int 21h
        cmp al, 0dh
        jz  clear		;回车输入结束，跳走
        shl bx, 1
        mov dx, bx
        shl dx, cl
        add bx, dx		;将数乘10，初始为0
        sub al, 30h		;调整输入数
        and ax, 00ffh
        add bx, ax		;将输入数加到bx
        jmp input
clear:  mov cx, 25		;回车25次清屏
clr:    lea dx, crlf
        mov ah, 9
        int 21h
        loop clr
        mov cl, 2
        xor ch, ch
        mov num, bx		;将数保存
begin:  xor bx, bx
        inc ch			;ch记录猜数次数
input2: mov ah, 1
        int 21h
        cmp al, 0dh
        jz  comp
        shl bx, 1
        mov dx, bx
        shl dx, cl
        add bx, dx
        sub al, 30h
        and ax, 00ffh
        add bx, ax
        jmp input2		;输入猜测数，回车跳到比较判断区
comp:   cmp bx, num		;比较
        jz  exa
        jb  s
        jmp b  
s:      lea dx, sma		;小了，重猜
		mov	ah, 9
		int	21h
        jmp begin
b:      lea dx, big		;大了，重猜
		mov	ah, 9
		int	21h
        jmp begin
exa:    lea dx, exact	;对了
		mov	ah, 9
		int	21h
        mov bl, 10
        mov al, ch		;将猜测次数存入al
        xor cx, cx
count:  xor ah, ah
        div bl			;除10，al为商，ah为余数
        cmp al, 0		;除完商为0，猜数次数各数位已被完全拆开
        jz  done
        mov cl, ah
        push cx			;除10后的余数进栈
        jmp count
done:   xor dx, dx		;这里是输出猜数次数个位数
        mov dl, ah		;或者多位数的最高位的数值
        add dl, 30h
        mov ah, 2
        int 21h
        cmp sp, offset btm;栈空，次数输出完毕
        jz  over
show:   pop dx			;出栈，调整，输出
        add dl, 30h
        mov ah, 2
        int 21h
        cmp sp, offset btm;栈空，次数输出完毕
        jnz show
over:   mov	ax, 4c00h
		int	21h
		end	start

2.测试

输入了一个数12345，下一秒要按回车了

按下回车，清屏啦（长图预警！！！其实也没有很长）

猜了3次，猜对啦，提示正确，猜测次数正确。

回车按了100多次，最后输入正确答案，也是正确的。

输了一个749，存到BX中，debug看是正确的。

3.遇到的问题和解决的方法

相比于1分的大小写转换，这道猜数字游戏的难点明显变多了；相比于4分题目的手足无措，这道猜数字游戏的解题方法还是有迹可循的。
（1）如何存一个十进制数？
我们知道，8086汇编21h中断只给出了输入字符的功能，并没有给出输入数字的功能。为了输入数，我通过百度搜索到了一种方法，即每次输入，将之前所输入的结果乘10（通过左移实现），再把所输入的数加进去，注意输入的是字符数字，要减30h。
例如，要输入123，初始存着的是0，输入1后，0×10+1=1存入；输入2后，1×10+2=12存入；输入3后，12×10+3=123存入。此时，需要的数已存好。

（2）如何输出猜测次数？
我将猜测的次数先用ch存了，最后猜完，ch中存的是猜测次数的数值，但是8086汇编只能以字符形式输出，数值不能直接输出，经过存数的经验，我想到的方法是通过除10，将余数进栈，全部进栈完后出栈输出。我们以猜了123次为例，虽然正常不会猜那么多次。
123÷10=12……3，3进栈，商继续除。
12÷10=1……2，2进栈，商继续除。
1÷10=0……1，此时商为0，我将余数1调整为ASCII码的’1’输出，然后2出栈，输出’2’，最后3出栈，输出’3’，我们便得到了猜测的次数。

（3）编写代码时时常会碰到的小问题
由于我四个通用寄存器都用上了，所以要时常去考虑指令对寄存器产生的影响，如loop指令、div指令，也正因为会产生影响，我在输入被猜测数时的乘10没有采用MUL指令，而是通过左移实现，尽可能减少影响。编写代码时出现的问题常常是因为没有注意所导致的。

4.仍存在的问题/bug

虽然现在已经可以完成猜数字游戏的功能了，但还是存在一定问题，我们知道5位十进制数的范围是在10000~99999之间，但是16位的寄存器能存的数值是最大只能到65535，所以在超过这个范围时，猜数时“大了”、“小了”的提示会错误。
当然，输入者输入5位以下的数自然是没问题的。
此外，我们不能保证输入者输入的是否是数字，万一他想输字母呢？我么得办法。我能有多骄傲，不堪一击好不好。
当然，可能还存在我还没发现的问题，希望大家指正。

总结1.0

我之所以选择做这道题，一个主要原因是它的逻辑并不复杂，所以，在编写代码的过程中，主要的难题放在了正确输入猜测数和怎么输出猜测次数上，主要的心力放在了考虑指令和寄存器之间的影响上。
在解决问题的过程上，我学会了一种8086汇编语言存数和输出数据的方式，也通过不断的debug认真考虑了指令和寄存器之间的影响，收获颇丰。
最终，任务完成，嗯。（并没有）

三、代码设计与测试2.0（2021/10/25）

最近事也多，难得周一只有早上第一节计网课，时间有所空出来。我便去问了几位学习成绩好的同学，他们做的是4分的题目《亲密数对问题》，我就想，他们肯定也会遇到数字过大无法用16位保存的问题，于是去请教。他们也承认，确实数字过大会出差错，还给到我一些思路，比如双字、再多用几个寄存器之类的，但是我由于感到繁琐，并没有着手去实施。
灵感总是突然降临，我吃完晚饭在学校里散步时突然想到课上的人名比较问题，联想到数字比较，我们比较数字是怎么比的？不就是先看两个数的数位个数，不一致就直接比出来了，一致再一位一位去比，那我把要猜的数字看成字符串用串操作指令去比较就行了。于是花了一些时间对原来的代码进行大改，并对最后的输出猜数次数进行了优化。

1.全部代码（第二种想法）

		.model  small
		.data
big 	db	    'bigger', 0dh, 0ah, '$'
sma     db      'smaller', 0dh, 0ah, '$'
exact   db      'exactly!', 0dh, 0ah, 'Your guess times:','$'
imf     db      'Please input a number'
crlf	db	    0dh, 0ah, '$'
maxlen	db      6
actlen	db      ?
nmbuf	db      6 dup(0)
gmaxlen	db      6
gactlen	db      ?
gnmbuf	db      6 dup(0)
        .stack
	    dw      20 dup(?)
btm	    dw	    ?
		.code
start:	mov	    ax, @data
		mov	    ds, ax
        mov 	es, ax
        cld                 ;方向标志为正向
        mov	    sp, offset btm;堆栈指针指向栈底
        lea     dx, imf  ;提示输入
        mov     ah, 9
        int     21h
input:  lea     dx, maxlen
        mov     ah, 0ah
        int     21h         ;输入被猜数
clear:  mov     cx, 25		;回车25次清屏
        dec     ah
clr:    lea     dx, crlf
        int     21h
        loop    clr
        xor     bx, bx      ;bx存放猜测次数
input2: inc     bx
        lea     dx, gmaxlen
        mov     ah, 0ah
        int     21h         ;输入所猜测数
        mov     ch, actlen
        mov     cl, gactlen
        cmp     cl, ch      ;先比较数位位数，不一致直接分出大小
        jz      equal
        jg      bigg
smal:   lea     dx, sma     ;小了，重猜
	    mov	    ah, 9
	    int	    21h
        jmp     input2
bigg:   lea     dx, big     ;大了，重猜
	    mov	    ah, 9
	    int	    21h
        jmp     input2
equal:  and     cx, 00ffh   ;数位相同，具体比较
        lea     di, nmbuf
        lea     si, gnmbuf
        repe    cmpsb       ;相同则继续比
        jz      exct
        jg      bigg
        jmp     smal
exct:   lea     dx, exact   ;对了，输出
	    mov	    ah, 9
	    int	    21h
        mov     ax, bx
        mov     bx, 10
count:  xor     dx, dx      ;每次除法之前dx清零，不清会有错误 
        div     bx
        cmp     ax, 0
        jz      over
        push    dx
        jmp     count
over:   add     dx, 0030h
        mov     ah, 2
        int     21h
        cmp     sp, offset btm
        jz      done
show:   pop     dx
        add     dx, 0030h
        mov     ah, 2
        int     21h
        cmp     sp, offset btm
        jnz     show
done:   mov	    ax, 4c00h
		int	    21h
		end	    start

2.测试

依旧是先输入一个数，不过这次的数超过了65535的限制。

在一阵回车过后，我开始了猜数

这是数位不一致的结果，3位数肯定比5位数小，自然就返回samller，大的情况也同样，不过要说明一点，我缓冲区设置了6个字节，所以包含回车在内，只能存5位数，对于超过5位的输入，程序是不接收的，给我也省了事。

最终猜完后的结果如下，是正确的。

可以看出，我还加了文字提示，更加友好了。

3.所优化的内容

（1）用户的奇葩输入在一定程度上有了改善，具体可见“4.仍存在的问题”，保证用户输入的内容不会超过5位
（2）提供了文字提示，用户友好性有了提示
（3）在堆栈部分进行了优化，原先除法除数是8位，需要不停调整寄存器的内容，程序有些凌乱，修改后更易于阅读。

4.仍存在的问题

为了节省脑细胞，我没有去考虑用户输入的不是数字的情况，不过不是数字也不影响猜数，正好本来是让乙猜，现在甲也可以参与猜数了。不过相比于第一个程序一位一位读，回车、回退这些非数字输入导致的错误已经可以排除了。

总结2.0

思路对解决问题很重要，一个复杂的思路，也许对，但很耗费精力。换一种思路，说不定就对了。