Sql 传varchar参数(逗号分隔)转成int

 

 

在使用存储过程中，有时需要将一堆的ID合成一个字符串(如:"1,2,3,4..."）当作参数传到存储过程中，这时需要将参数中的ID解放出来，函数如下：

 

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER FUNCTION [dbo].[fnSplitStr] (
    @sText      NVARCHAR(Max),
    @sDelim     CHAR(1)
)

RETURNS @retArray TABLE (
    value   VARCHAR(100)
)
AS
BEGIN
	DECLARE 
		@posStart		BIGINT,
		@posNext		BIGINT,
		@valLen			BIGINT,
		@sValue			NVARCHAR(100);

	IF @sDelim IS NULL 
	BEGIN
		IF LEN(@sText)>100 SET @sText = SUBSTRING(@sText, 1, 100)
		
		INSERT @retArray (value)
		VALUES (@sText);
	END
	ELSE
	BEGIN
		SET @posStart = 1;

		WHILE @posStart <= LEN(@sText)
		BEGIN
			SET @posNext = CHARINDEX(@sDelim, @sText, @posStart);

			IF @posNext <= 0 
				SET @valLen = LEN(@sText) - @posStart + 1;
			ELSE
				SET @valLen = @posNext - @posStart;

			SET @sValue = SUBSTRING(@sText, @posStart, @valLen);
			SET @posStart = @posStart + @valLen + 1;

			IF LEN(@sValue) > 0
			BEGIN
				IF LEN(@sValue)>100 SET @sValue = SUBSTRING(@sValue, 1, 100)
				
				INSERT @retArray (value)
				VALUES (@sValue);
			END
		END
	END
	RETURN
END

在需要解析参数的地方调用：--存储过程、函数、sql语句中

inner join dbo.fnSplitStr(@ids,',') id on t.ID = id.Value

@ids即为参数