PL/SQL游标的使用

使用游标


使用显示游标


为了处理SELECT语句返回多行数据，开发人员可以使用显示游标，使用
显示游标包括定义游标、打开游标、提取数据和关闭游标




1，定义游标


在使用显示游标之前，必须首先在定义部分定义游标。定义游标用于指定
游标所对应的SELECT语句，如法如下


CURSOR cursor_name is select_statement;


cursor_name用于指定游标的名称，select_statement用于指定游标所对应
的SELECT语句


2.打开游标


当打开游标时，Oracle会执行游标所对应的SELECT语句，并且将SELECT语句
的结果暂存放到结果集中语法如下


OPEN cursor_name;


该游标名必须是在定义部分已经定义的游标




3.提取数据
在打开游标之后，SELECT语句的结果被临时存放到游标结果集中。
为了处理结果集中的数据，需要使用FETCH语句提取游标数据。
语法如下：




语法一：FETCH cursor_name intovariable,variable2....;


语法二：FETCH cursor_name
BULK COLLECT INTO collect1,collect2,...[limit rows];


如上所示，variable用于指定接收游标数据的变量；collect用于指定
接收游标结果的集合变量。注意，当使用语法一时，必须要使用循环
语句处理结果集的所有数据。


4.关闭游标
在提取并处理了结果集的所有数据之后，就可以关闭游标并释放其结果集
语法如下


CLOSE cursor_name;


显示游标属性


显示游标属性用于返回式游标的执行信息，这些属性包括%isopen,
%found,%notfound和rowcount.当使用显示游标属性时，必须要在显示
游标属性之前带有显示游标名作为前缀（游标名.属性名）


1.%ISOPEN
该属性用确定游标是否已经打开，则值为TRUE，如果游标没有打开
则，返回值为FALSE，如下所示
 if c1%isopne then--如果游标打开，则执行相应的操作
...
else
open c1;
end if
2.%found
该属性用于检查是否从结果集中提取到了数据。如果提取到了数据，
则返回值为TRUE，如果未提取到数据，则返回值为FALSE.
loop
fetch c1 into var1,var2--提取数据到变量中
if c1%found then--如果提取到数据，则进行处理
        ...      --如果未提取到数据，则退出循环
else


           exit
      end if 
end loo;


3 %NOTFOUND
该属性与%found属性刚好相反，如果提取到了数据，则返回值
为FALSE；如果没有提取到数据，则返回TRUE,如下所示


LOOP
fetch c1 into var1,var2; --提取数据到变量
exit when c1%notfound;
...
end LOOP;


4.%ROWCOUNT
该属性用于返回当前行为止已经提取到实际行数。示例如下：


loop
FETCH c1 into my_ename,my_deptno;
if c1%TOWCOUNT>10 then
...
end if
...
end loop;


3.显示游标的使用示例


在显示游标中使用FETCH...into语句


 declare
   cursor yy_fj_person_cursor is
     select person_name, salary from yy_fj_persons where person_id = 21;
   v_name yy_fj_persons.person_name%type;
   v_sal  yy_fj_persons.salary%type;
 begin
   open yy_fj_person_cursor;
   loop
     fetch yy_fj_person_cursor
       into v_name, v_sal;
     exit when yy_fj_person_cursor%notfound;--notfound 当取到值时notfound为false
     dbms_output.put_line(v_name || ':' || v_sal);
   end loop;
   close yy_fj_person_cursor;
 end;


在显示游标中，使用FETCH...BULK COLLECT INTO 语句提取所有数据示例如下
 declare
   cursor yy_fj_peersons_cursor is 
       select person_name from yy_fj_persons;
   type name_table_type is table of varchar2(10);--声明一个表的类型name_table_type 
   person_name name_table_type; --声明一个变量person_name 类型为name_table_type
 begin
   open yy_fj_peersons_cursor;
   fetch yy_fj_peersons_cursor bulk collect
     into person_name;
   for i in 1 .. person_name.count loop
     dbms_output.put_line(person_name(i));
   end loop;
   close yy_fj_peersons_cursor;
 end;


在显示游标中使用FETCH...BULK COLLECT INTO..LIMIT语句提取部分数据
当使用FETCH..BULK COLLECT INTO 语句提取数据时，默认情况下会提取结果集
的所有数据。如果结果集含有大量的数据，并且使用VARRAY集合变量接收数据，那么可能需要
限制每次提取的行数。
declare
   type name_array_type is varray(5) of varchar2(10);--创建数组类型
   name_array name_array_type;--创建变量name_array 类型为name_array_type
   cursor yy_fj_persons_cursor is
     select person_name from yy_fj_persons;
   v_rows    int := 2;
   v_count int := 0;
 begin
   open yy_fj_persons_cursor;
   loop
     fetch yy_fj_persons_cursor bulk collect
       into name_array limit v_rows;--限制输出的行数2行
     dbms_output.put_line('用户名：');
     for i in 1 .. (yy_fj_persons_cursor%rowcount - v_count) loop
       dbms_output.put_line(name_array(i) || ' ');
     end loop;
     dbms_output.new_line;
     v_count := yy_fj_persons_cursor%rowcount;
     dbms_output.put_line(v_count);          --游标指针逐渐的累加
     exit when yy_fj_persons_cursor%notfound;--当可以取到值时，notfound值为false不退出，取不到值为true退出
   end loop;
   close yy_fj_persons_cursor;
 end;