Salesforce: 通过Trailhead学习Metadata API

学习资源：
https://trailhead.salesforce.com/en/content/learn/modules/apex_metadata_api/apex_metadata_api_updates#

以下仅仅是个人学习笔记

本节创建如下类：
1.UpdatePageLayout
获取Account的Page Layout，并向Page Layout添加一个自定义的Field

public class UpdatePageLayout {
    // Add custom field to page layout
    
    public Metadata.Layout buildLayout() {
        
        // Retrieve Account layout and section获取Page Layout 
        List<Metadata.Metadata> layouts = 
            Metadata.Operations.retrieve(Metadata.MetadataType.Layout, 
            new List<String> {'Account-Account Layout'});
        Metadata.Layout layoutMd = (Metadata.Layout) layouts.get(0);
       
       // 获取Section
        Metadata.LayoutSection layoutSectionToEdit = null;
        List<Metadata.LayoutSection> layoutSections = layoutMd.layoutSections;
        
        // 从多个section中查找目标Section,即名称为“Account Information”的section
        for (Metadata.LayoutSection section : layoutSections) {
            if (section.label == 'Account Information') {
                layoutSectionToEdit = section;
                break;
            }
        }
        
        // Add the field under Account info section in the left column
        // 查找到的Section里面，第0列，添加一个自定义项目，就是“sample_field__c”
        List<Metadata.LayoutColumn> layoutColumns = layoutSectionToEdit.layoutColumns;     
        List<Metadata.LayoutItem> layoutItems = layoutColumns.get(0).layoutItems;
        
        // Create a new layout item for the custom field
        Metadata.LayoutItem item = new Metadata.LayoutItem();
        item.behavior = Metadata.UiBehavior.Edit;
        item.field = 'AMAPI__Apex_MD_API_sample_field__c';
        layoutItems.add(item);
        
        return layoutMd;
    }
}

2. 回调类，实装Metadata.DeployCallback 的Interface

public class PostInstallCallback implements Metadata.DeployCallback {
  
    public void handleResult(Metadata.DeployResult result,
        Metadata.DeployCallbackContext context) {
        
        if (result.status == Metadata.DeployStatus.Succeeded) {
            // Deployment was successful, take appropriate action.
            System.debug('Deployment Succeeded!');
        } else {
            // Deployment wasn’t successful, take appropriate action.
	    System.debug('Deployment Failed!');
        }
    }
}

3. Release容器的生成
   个人理解，把1和2，组装到这个容器里，等待发布。

public class DeployMetadata {
 
    // Create metadata container 
    public Metadata.DeployContainer constructDeploymentRequest() {
        
        Metadata.DeployContainer container = new Metadata.DeployContainer();
        
        // Add components to container         
        Metadata.Layout layoutMetadata = new UpdatePageLayout().buildLayout();     // 第一步的PageLayout放到容器中。
        container.addMetadata(layoutMetadata);
        return container;
    }
    
    // Deploy metadata    发布Metadata
    public void deploy(Metadata.DeployContainer container) {
        // Create callback. 
        PostInstallCallback callback = new PostInstallCallback();
        
        // Deploy the container with the new components. 
        // 这个容器里装的东西要发布。
        Id asyncResultId = Metadata.Operations.enqueueDeployment(container, callback);
    }
}

4. 发布，组装（onInstall）接口类InstallHandler

public class PostInstallScript implements InstallHandler {
    
    // Deploy post-install metadata  
    public void onInstall(InstallContext context) {
        DeployMetadata deployUtil = new DeployMetadata();//3的容器
        Metadata.DeployContainer container = deployUtil.constructDeploymentRequest();  // 3的容器定义到通用的容器类。
        deployUtil.deploy(container);     // 3的容器发布。
    }
}

3=1+2, 4→3 这样把四个类的作用 串起来了。
看上去挺烦的，主要是 Metadata.DeployCallback 和 InstallHandler 的接口，可以查询官网的介绍理解。

Interface：

• Metadata.DeployCallback 和
• InstallHandler

用到的类：

• Metadata.Layout
• Metadata.Metadata
• Metadata.Operations
• Metadata.LayoutSection
• Metadata.LayoutColumn
• Metadata.LayoutItem
• Metadata.DeployContainer
• PostInstallCallback

结果判断用的类

• Metadata.DeployResult
• Metadata.DeployCallbackContext
• Metadata.DeployStatus

几行的代码，用了这么多的类，相互调用，今天初次碰到，脑袋瞬间爆裂。理顺一下也不错。