bootloader分析

; *******************************************************
; * NAME    : 44BINIT.S         *
; * Version : 10.April.2000        *
; * Description:          *
; * C start up codes         *
; * Configure memory, Initialize ISR ,stacks   *
; * Initialize C-variables        *
; * Fill zeros into zero-initialized C-variables  *
; *******************************************************
 
    ;GET option.a
    ;GET memcfg.a
    GET memcfg.s

;Memory Area
;GCS6 64M 16bit(8MB) DRAM/SDRAM(0xc000000-0xc7fffff)
;APP    RAM=0xc000000~0xc7effff
;44BMON RAM=0xc7f0000-0xc7fffff
;STACK    =0xc7ffa00    

;Interrupt Control
INTPND     EQU 0x01e00004  ;指示中断请求状态寄存器,每一位代变一种中断请求
INTMOD     EQU 0x01e00008  ;中断模式寄存器,有两种中断模式对应位为:1代表fip mode ,0代表riq mode
INTMSK     EQU 0x01e0000c  ;确定哪个中断源被屏蔽 屏蔽的中断源将不被服务
I_ISPR     EQU 0x01e00020  ;中断服务挂起寄存器
I_CMST     EQU 0x01e0001c  ;当前主寄存器irq优先级

;Watchdog timer
WTCON     EQU 0x01d30000  ;看门狗定时器控制寄存器

;Clock Controller
PLLCON     EQU 0x01d80000  ;pll控制寄存器
CLKCON     EQU 0x01d80004  ;时钟控制寄存器
LOCKTIME    EQU 0x01d8000c  ;锁定时间计数值寄存器
 
;Memory Controller
REFRESH     EQU 0x01c80024  ;Dram/sdram刷新控制寄存器

;BDMA destination register
BDIDES0     EQU 0x1f80008  ;???DMA???
BDIDES1     EQU 0x1f80028  ;???DMA???

;Pre-defined constants
USERMODE    EQU 0x10   ;0b10000 用户模式
FIQMODE     EQU 0x11   ;0b10001 FIQ模式
IRQMODE     EQU 0x12   ;0b10010 IRQ模式
SVCMODE     EQU 0x13   ;0b10011 管理模式
ABORTMODE   EQU 0x17   ;0b10111 中止模式
UNDEFMODE   EQU 0x1b   ;0b11011 未定义
MODEMASK    EQU 0x1f   ;0b11111 mode mask
NOINT     EQU 0xc0   ;0b1100 0000 ???关中断???

;=========================================================================================================================
;check if tasm.exe is used.
;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译）

    GBLL    THUMBCODE    ;global logical variable, init. to {false}
    [ {CONFIG} = 16      ;[=if,{CONFIG}:build-in variable defined by ARM assembler,16=assembing Thumbcode.
THUMBCODE SETL {TRUE}   ;SETL:set the logic variable
    CODE32               ;changing from Thumb state to Arm state
    |                    ;|=else
THUMBCODE SETL {FALSE}
    ]                    ;]=endif

    [ THUMBCODE
    CODE32               ;for start-up code for Thumb mode???
    ]

;=========================================================================================================================
;注意下面这段程序是个宏定义,下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开
;这段程序用于把中断服务程序的首地址装载到pc中

;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。
;每个字空间都有一个标号，以Handle***命名。

    MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
    sub     sp,sp,#4     ;decrement sp(to store jump address)
    stmfd   sp!,{r0}     ;PUSH the work register to stack(lr does't push because it return to original address)
    ldr     r0,=$HandleLabel;load the address of HandleXXX to r0
    ldr     r0,[r0]         ;load the contents(service routine start address) of HandleXXX
    str     r0,[sp,#4]     ;store the contents(ISR) of HandleXXX to stack
    ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)
    MEND
 
;=========================================================================================================================
;一个arm程序由RO,RW,ZI三个断组成 其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量（对于GNU工具 对应的概念是TEXT ,DATA,BSS）
;bootloader要将RW段复制到ram中并将ZI段清零 编译器使用下列段来记录各段的起始和结束地址
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址加1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址加1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址加1
;这些标号的值是通过编译器的设定来确定的 如编译软件中对ro-base和rw-base的设定，例如 ro-base=0xc000000 rw-base=0xc5f0000

    IMPORT |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
    IMPORT |Image$$RW$$Base|   ; Base of RAM to initialise
    IMPORT |Image$$ZI$$Base|   ; Base and limit of area
    IMPORT |Image$$ZI$$Limit|  ; to zero initialise;

    IMPORT  Main    ; The main entry of mon program

;=========================================================================================================================
;下面为代码段

    AREA    Init,CODE,READONLY

    ENTRY
;****************************************************************************
;异常表
 ;上电和复位后,程序开始从位于0x0处开始执行.程序从这里开始执行跳转到标号为ResetHandler处执行
    b      ResetHandler                      ;    Reset       
    ldr    pc, =(_IRQ_BASEADDRESS + 0x04)    ;    HandlerUndef
    ldr    pc, =(_IRQ_BASEADDRESS + 0x08)    ;    HandlerSWI
    ldr    pc, =(_IRQ_BASEADDRESS + 0x0C)    ;    HandlerPabort
    ldr    pc, =(_IRQ_BASEADDRESS + 0x10)    ;    HandlerDAbort
    ldr    pc, =(_IRQ_BASEADDRESS + 0x14)    ;    HandlerReserved
    ldr    pc, =(_IRQ_BASEADDRESS + 0x18)    ;    HandlerIRQ
    ldr    pc, =(_IRQ_BASEADDRESS + 0x1C)    ;    HandlerFIQ
;***************************************************************************   
 ;***IMPORTANT NOTE***
 ;If the H/W vectored interrutp mode is enabled, The above two instructions should
 ;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controller.
 ; b HandlerIRQ  ->  subs pc,lr,#4
 ; b HandlerIRQ  ->  subs pc,lr,#4

;中断表
 ;向量中断模式和非向量中断模式的概念
 ;A)  向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，
 ;    通过跳转指令系统就直接跳转到对应地址.ADC中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC ,
 ;    当ADC中断产生的时候系统会自动跳转到HandlerADC函数中
 
 ;B)  向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位,
 ;    然后跳转到位于0x18处的统一中断函数中,该函数通过读取interrupt pending寄存器中对应标志位,来判断中断源,
 ;    并根据优先级关系再跳到对应中断源的处理代码中
 
VECTOR_BRANCH
    ldr pc,=HandlerEINT0    ;mGA    H/W interrupt vector table
    ldr pc,=HandlerEINT1    ; 
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567 ;
    ldr pc,=HandlerTICK     ;mGA
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT     ;
    ldr pc,=HandlerUERR01   ;mGB
    b .
    b .
    ldr pc,=HandlerTIMER0   ;mGC
    ldr pc,=HandlerTIMER1   ;
    ldr pc,=HandlerTIMER2   ;
    ldr pc,=HandlerTIMER3   ;
    ldr pc,=HandlerTIMER4   ;
    ldr pc,=HandlerTIMER5   ;mGC
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC     ;
    ldr pc,=HandlerSIO     ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD
    b .
    b .
    ldr pc,=HandlerRTC     ;mGKA
    b .      ;
    b .      ;
    b .      ;
    b .      ;
    b .      ;mGKA
    b .
    b .
    ldr pc,=HandlerADC     ;mGKB
    b .      ;
    b .      ;
    b .      ;
    b .      ;
    b .      ;mGKB
    b .
    b .
;0xe0=EnterPWDN
    ldr pc,=EnterPWDN

;=============================================================================================================================
;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理函数（对于向量中断）
    LTORG 

HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort

HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0

;*************************************************************************
;IRQ  ==the program put this phrase to 0xc000000
;???可能是给用户程序使用的异常表???
ExceptionHanlderBegin
    b      .
    ldr    pc, MyHandleUndef            ;    HandlerUndef
    ldr    pc, MyHandleSWI              ;    HandlerSWI
    ldr    pc, MyHandlePabort           ;    HandlerPabort
    ldr    pc, MyHandleDabort           ;    HandlerDAbort
    b .                                 ;    HandlerReserved
    ldr    pc, MyHandleIRQ              ;    HandlerIRQ
    ldr    pc, MyHandleFIQ              ;    HandlerFIQ
   
MyHandleUndef  DCD  HandleUndef         ;reserve a word(32bit)
MyHandleSWI    DCD  HandleSWI
MyHandlePabort DCD  HandlePabort
MyHandleDabort DCD  HandleDabort
MyHandleIRQ    DCD  HandleIRQ
MyHandleFIQ    DCD  HandleFIQ

ExceptionHanlderEnd
;*************************************************************************

;============================================================================================================================
;以下两个例程都可以用来处理非向量中断
;具体判断I_ISPR中各位是否置1 :置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务
;One of the following two routines can be used for non-vectored interrupt.

IsrIRQ ;using I_ISPR register.
    sub     sp,sp,#4       ;reserved for PC
    stmfd   sp!,{r8-r9}  

 ;IMPORTANT CAUTION
 ;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.

    ldr     r9,AddrISPR;=I_ISPR       <=> ldr r9,=I_ISPR
    ldr     r9,[r9]

 cmp  r9, #0x0 ;If the IDLE mode work-around is used,
      ;r9 may be 0 sometimes.
 beq  %F2

    mov     r8,#0x0
0
    movs    r9,r9,lsr #1  ;将最低位送入C
    bcs     %F1
    add     r8,r8,#4   ;r8充当索引
    b     %B0

1
    ldr     r9,AddrHandleADC;=HandleADC 找到中断表的首地址
    add     r9,r9,r8  ;首地址+索引 = 中断服务地址
    ldr     r9,[r9]   ;加载中断服务
    str     r9,[sp,#8]  ;放入事先预留的堆栈位置
    ldmfd   sp!,{r8-r9,pc} ;进入中断服务

2
 ldmfd sp!,{r8-r9}  ;???IDLE MODE故不进行中断服务，返回了事???
 add  sp,sp,#4
 subs pc,lr,#4
 
AddrISPR;There is no this phrases in original 44binit.s  为什么不直接写ldr r9,=I_ISPR 和ldr r9,=HandleADC，而要这么做呢???
    DCD     I_ISPR
AddrHandleADC   
    DCD     HandleADC
IsrIRQEnd 

;****************************************************
;* START           *
;****************************************************
;上电和复位后 程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行
ResetHandler

 ;1.禁止看门狗
    ldr     r0,=WTCON     ;watch dog disable
    ldr     r1,=0x0   
    str     r1,[r0]

 ;屏蔽所有中断
    ldr     r0,=INTMSK
    ldr     r1,=0x07ffffff  ;all interrupt disable
    str     r1,[r0]

    ;****************************************************
    ;* Set clock control registers      *
    ;****************************************************
 ;2.根据工作频率设置pll
  ;计算公式
  ;Fpllo=(m*Fin)/(p*2^s)
  ;m=MDIV+8,p=PDIV+2,s=SDIV
  ;Fpllo必须大于20Mhz小于66Mhz
  ;Fpllo*2^s必须小于170Mhz
  ;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
  ;#elif (MCLK==40000000)
  ;#define PLL_M (0x48)
  ;#define PLL_P (0x3)
  ;#define PLL_S (0x2)
  ;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
  ;硬件使用晶振为10Mhz,即Fin=10Mhz
  ;Fpllo=80*10/5*2^2=40Mhz
    ldr r0,=LOCKTIME
    ldr r1,=0xfff
    str r1,[r0]

    [ PLLONSTART
 ldr r0,=PLLCON   ;temporary setting of PLL
 ldr r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz
 str r1,[r0]
    ]

    ldr     r0,=CLKCON  
    ldr     r1,=0x7ff8     ;All unit block CLK enable 
    str     r1,[r0]

    ;****************************************
    ;*  change BDMACON reset value for BDMA *  
    ;****************************************
    ldr     r0,=BDIDES0      
    ldr     r1,=0x40000000   ;BDIDESn reset value should be 0x40000000 
    str     r1,[r0]

    ldr     r0,=BDIDES1     
    ldr     r1,=0x40000000   ;BDIDESn reset value should be 0x40000000 
    str     r1,[r0]

    ;****************************************************
    ;* Set memory control registers     *  
    ;****************************************************
    ldr     r0,=SMRDATA
    ldmia   r0,{r1-r13}
    ldr     r0,=0x01c80000  ;BWSCON Address
    stmia   r0,{r1-r13}

    ;****************************************************
    ;* Initialize stacks        *
    ;****************************************************
    ldr     sp, =SVCStack ;
    bl     InitStacks
   
    ;****************************************************
    ;* Setup IRQ handler        *
    ;****************************************************
 ;Setup IRQ handler 主体就是将0x0处的异常表搬运到_IRQ_BASEADDRESS，并设置irq服务(none vector mode)
 ;为什么要这么做？中断发生时不是自动转到0x0处的中断异常表吗？
 ;莫非日后，再修改此表使他指向_IRQ_BASEADDRESS处？这样都在ram中,加快速度???
 ;————不是的！！！看一下分析即可知道。
 
 
 ;下面这段代码看似将_IRQ_BASEADDRESS + 0x100之后的0x100全部初始化为_IRQ_BASEADDRESS
 ;事实上，结合44b.h中的isr部分就清楚了，那里是安装isr的地方，而起始地址正是_IRQ_BASEADDRESS + 0x100！
 ;当irq到来时，无论是非vector mode还是vector mode，都要跳转到HandleXXX处，
 ;而HandleXXX的首地址正是(_IRQ_BASEADDRESS+0x100)！
 
 ;再回顾一下中断或异常到来后的行为：
 ; 1,异常发生
 ; 2,转到0x0为首地址的异常表
 ; 3,根据异常类型，转入某个项，比如SWI
 ;  ldr    pc, =(_IRQ_BASEADDRESS + 0x08)    ;    HandlerSWI
 ; 4，那么(_IRQ_BASEADDRESS + 0x08)处放的是什么呢？
 ;  见下表
 ;    ^ (_IRQ_BASEADDRESS)
 ;    HandleReset     # 4
 ;    HandleUndef     # 4
 ;    HandleSWI       # 4
 ;    ...
 ; 由此可知HandleSWI是位于_IRQ_BASEADDRESS + 0x08处的，而44b.h中定义：
 ;  #define pISR_SWI (*(unsigned *)(_IRQ_BASEADDRESS+0x8))
 ; 我们可以安装这个异常处理函数！
 
 ; irq到来时，情况差不多。
 ; A) 如果是vector mode
 ;  那么直接载入0x20开始的指令，比如ldr pc,=HandlerEINT4567 ;
 ;  HandlerEINT4567的定义可知：
 ;        ^ (_IRQ_BASEADDRESS+0x100)
 ;     HandleADC     # 4
 ;     HandleRTC     # 4
 ;     ...
 ;     HandleEINT4567  # 4
 ;  他位于_IRQ_BASEADDRESS+0x154处，而44b.h中定义：
 ;   #define pISR_EINT4567 (*(unsigned *)(_IRQ_BASEADDRESS+0x154))//0x74))
 ;  于是我们可以安装处理函数。
 ;
 ; B) 如果是none vector mode
 ;  那么仅在装入HandlerEINT4567时方法不同，它是通过判断程序来完成的，剩下的步骤还是相同的。
 
 
    ldr     r0,=(_IRQ_BASEADDRESS + 0x100)
    ldr     r2,=_IRQ_BASEADDRESS
    add     r3,r0, #0x100            ;r3指向_IRQ_BASEADDRESS+0x200处
0   
    CMP     r0, r3      ;do what?  <- 哈哈，我知道了，居然你们立宇泰的人不知道！！！
    STRCC   r2, [r0], #4;cc:Carry clear;save R2 to R0 address, R0 + 4=R0。
    BCC     %B0
   
 ;----------------------------------------------------------------------------------------
 ;将0x0处的vector table 拷贝到 _IRQ_BASEADDRESS(0xc000000)
    ldr     r1,=_IRQ_BASEADDRESS           
    ldr     r0,=ExceptionHanlderBegin ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    ldr     r3,=ExceptionHanlderEnd
0   
    CMP     r0, r3              ;put the vector table at _IRQ_BASEADDRESS(0xc000000)
    LDRCC   r2, [r0], #4  
    STRCC   r2, [r1], #4
    BCC     %B0
           
 ;----------------------------------------------------------------------------------------
 ;下面代码将非向量模式下的中断判断处理函数拷贝到_IRQ_BASEADDRESS+0x80(0xc000080)
    ldr     r1,=DIsrIRQ     ;put the IRQ judge program at _IRQ_BASEADDRESS+0x80(0xc000080)      
    ldr     r0,=IsrIRQ      ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    ldr     r3,=IsrIRQEnd
0   
    CMP     r0, r3
    LDRCC   r2, [r0], #4
    STRCC   r2, [r1], #4
    BCC     %B0

 ;----------------------------------------------------------------------------------------
 ;将非向量模式的中断处理函数装入_IRQ_BASEADDRESS处的HandleIRQ
    ldr     r1, =MyHandleIRQ   ;MyHandleIRQ point to DIsrIRQ
    ldr     r0, =ExceptionHanlderBegin
    ldr     r4, =_IRQ_BASEADDRESS;
    sub     r0, r1, r0   ;计算MyHandleIRQ在ExceptionHanlderBegin这个中断表中的偏移
    ;add     r0, r0, #_IRQ_BASEADDRESS
    add     r0, r0,r4   ;r0指向_IRQ_BASEADDRESS+(MyHandleIRQ的偏移),即0xc000000处的HandleIRQ
    ldr     r1, =DIsrIRQ     ;将非向量模式的中断处理函数装入0xc000000处的HandleIRQ
    str     r1, [r0]   

;    ldr     r0,=HandleIRQ  ;This routine is needed
;    ldr     r1,=IsrIRQ   ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
;    str     r1,[r0]

 ;-----------------------------------------------------------------------------------------
; --- Initialise memory required by C code
    ;********************************************************
    ;* Copy and paste RW data/zero initialized data     *
    ;********************************************************
    LDR     r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
    LDR     r1, =|Image$$RW$$Base| ; and RAM copy
    LDR     r3, =|Image$$ZI$$Base| 
 ;Zero init base => top of initialised data
   
    CMP     r0, r1     ; Check that they are different 确保数据段就是代码段的后面，如果已经是了，就跳过下面搬运
    BEQ     %F1
0  
    CMP     r1, r3     ; Copy init data 将数据段搬运到代码段的后面
    LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4  
    STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
    BCC     %B0
1  
    LDR     r1, =|Image$$ZI$$Limit| ; Top of zero init segment
    MOV     r2, #0
2  
    CMP     r3, r1     ; Zero init 初始化bss段
    STRCC   r2, [r3], #4
    BCC     %B2
   
;--------Now we enter the C code
    [ :LNOT:THUMBCODE   ;if(!thumbcode) arm state;
 BL Main         ;Don't use main() because ...... 为什么呢？
 B .      
    ];

    [ THUMBCODE      ;for start-up code for Thumb mode;
 orr     lr,pc,#1
 bx      lr
 CODE16
 bl      Main     ;Don't use main() because ......
 b       .
 CODE32
   ]

;****************************************************
;* The function for initializing stack    *
;****************************************************
;4.初始化各模式下的栈指针
InitStacks
 ;Don't use DRAM,such as stmfd,ldmfd......
 ;SVCstack is initialized before
 ;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

    mrs     r0,cpsr
    bic     r0,r0,#MODEMASK
    orr     r1,r0,#UNDEFMODE|NOINT
    msr     cpsr_cxsf,r1  ;UndefMode
    ldr     sp,=UndefStack
 
    orr     r1,r0,#ABORTMODE|NOINT
    msr     cpsr_cxsf,r1       ;AbortMode
    ldr     sp,=AbortStack

    orr     r1,r0,#IRQMODE|NOINT
    msr     cpsr_cxsf,r1       ;IRQMode
    ldr     sp,=IRQStack
 
    orr     r1,r0,#FIQMODE|NOINT
    msr     cpsr_cxsf,r1       ;FIQMode
    ldr     sp,=FIQStack

    bic     r0,r0,#MODEMASK|NOINT
    orr     r1,r0,#SVCMODE
    msr     cpsr_cxsf,r1       ;SVCMode
    ldr     sp,=SVCStack

 ;USER mode is not initialized.
    mov     pc,lr ;The LR register may be not valid for the mode changes.

;****************************************************
;* The function for entering power down mode  *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
    mov     r2,r0               ;r0=CLKCON
    ldr     r0,=REFRESH  
    ldr     r3,[r0]
    mov     r1, r3
    orr     r1, r1, #0x400000   ;self-refresh enable
    str     r1, [r0]

    nop     ;Wait until self-refresh is issued. May not be needed.
    nop     ;If the other bus master holds the bus, ...
    nop     ; mov r0, r0
    nop
    nop
    nop
    nop

;enter POWERDN mode
    ldr     r0,=CLKCON
    str     r2,[r0]

;wait until enter SL_IDLE,STOP mode and until wake-up
    ldr     r0,=0x10
0   subs    r0,r0,#1
    bne     %B0

;exit from DRAM/SDRAM self refresh mode.
    ldr     r0,=REFRESH
    str     r3,[r0]
    mov     pc,lr

    ;LTORG

SMRDATA DATA
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized.                     *
;*****************************************************************

;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.

;bank0 16bit BOOT ROM
;bank1 8bit NandFlash
;bank2 16bit IDE
;bank3 8bit UDB
;bank4 rtl8019
;bank5 8bit usb host
;bank6 16bit SDRAM
;bank7 16bit SDRAM
    [ BUSWIDTH=16
    DCD 0x11010101 ;Bank0=16bit BootRom(AT29C010A*2) :0x0 8bit usb host![20:23]=0
    | ;BUSWIDTH=32
 DCD 0x22222220 ;Bank0=OM[1:0], Bank1~Bank7=32bit
    ]
 DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
 DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
 DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
 DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
 DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
 DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
 [ BDRAMTYPE="DRAM"
     DCD ((B6_MT<<15)+(B6_Trcd<<4)+(B6_Tcas<<3)+(B6_Tcp<<2)+(B6_CAN)) ;GCS6 check the MT value in parameter.a
     DCD ((B7_MT<<15)+(B7_Trcd<<4)+(B7_Tcas<<3)+(B7_Tcp<<2)+(B7_CAN)) ;GCS7
 | ;"SDRAM"
  DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
  DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
 ]
 DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT) ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
 DCD 0x10   ;SCLK power down mode, BANKSIZE 32M/32M
 DCD 0x20   ;MRSR6 CL=2clk
 DCD 0x20   ;MRSR7

 ALIGN               ;?

;==========================================================================================================================================
;以下的数据段充分的说明了中断处理程序的存储结构
;分为3个区域
;   1,异常向量表(_IRQ_BASEADDRESS ~ _IRQ_BASEADDRESS+0x4*8)
;   2,none vector mode的判断程序(_IRQ_BASEADDRESS+0x80~...)
;   3,isr表(中断处理服务表)(_IRQ_BASEADDRESS+0x100~...)

;最后还有堆栈区域

 AREA RamData, DATA, READWRITE

    ^ (_IRQ_BASEADDRESS)
HandleReset     # 4
HandleUndef     # 4
HandleSWI       # 4
HandlePabort    # 4
HandleDabort    # 4
HandleReserved  # 4
HandleIRQ       # 4
HandleFIQ       # 4

 
  ^ (_IRQ_BASEADDRESS+0x80)
DIsrIRQ       # 4

;Don't use the label 'IntVectorTable',
;because armasm.exe cann't recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
    ^ (_IRQ_BASEADDRESS+0x100)
HandleADC     # 4
HandleRTC     # 4
HandleUTXD1   # 4
HandleUTXD0   # 4
HandleSIO     # 4
HandleIIC     # 4
HandleURXD1   # 4
HandleURXD0   # 4
HandleTIMER5  # 4
HandleTIMER4  # 4
HandleTIMER3  # 4
HandleTIMER2  # 4
HandleTIMER1  # 4
HandleTIMER0  # 4
HandleUERR01  # 4
HandleWDT     # 4
HandleBDMA1   # 4
HandleBDMA0   # 4
HandleZDMA1   # 4
HandleZDMA0   # 4
HandleTICK    # 4
HandleEINT4567  # 4
HandleEINT3   # 4
HandleEINT2   # 4
HandleEINT1   # 4
HandleEINT0   # 4  

 ^ (_ISR_STARTADDRESS-0x1400)
    
UserStack # 1024 ;c1(c7)fe600
SVCStack # 1024 ;c1(c7)feb00
UndefStack # 1024 ;c1(c7)ff000
AbortStack # 1024 ;c1(c7)ff500
IRQStack # 1024 ;c1(c7)ffa00
FIQStack # 0 ;c1(c7)fff00

  END