经过两天的注释，大致了解了mini2440的启动流程，期间查阅了大量的网上资料，借此机会分享下注释的代码。希望对大家学习有所帮助。
由于本人能力有限，欢迎大家指正错误！！不胜感激！
;=========================================
; NAME: 2440INIT.S
; DESC: C start up codes
; Configure memory, ISR ,stacks
; Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20:purnnamu: Add some functions for testing STOP,Sleep mode
; 2003.03.14:DonGo: Modified for 2440.
;2010.11.30:GuQSir for this code more Chinese Notes.
;=========================================
PRESERVE8
GET option.inc
GET memcfg.inc ;定义存储器配置
GET 2440addr.inc ;定义了寄存器符号
BIT_SELFREFRESH EQU (1<<22) ;相当于c里面 #define BIT_SELFREFRESH (1<<22) 第22位置1
; 用于节电模式中，SDRAM自动刷新
;Pre-defined constants 处理器工作模式 ARM处理器中有一个程序状态寄存器CPRS，它的后五位决定ARM的工作模式 M[4:0]
USERMODE EQU 0x10 ;用户模式
FIQMODE EQU 0x11 ;快速中断模式
IRQMODE EQU 0x12 ;中断模式
SVCMODE EQU 0x13 ;管理模式
ABORTMODE EQU 0x17 ;中止模式
UNDEFMODE EQU 0x1b ;未定义模式
MODEMASK EQU 0x1f ;系统模式 ;M[4:0]
NOINT EQU 0xc0
;The location of stacks 定义处理器各种模式下堆栈地址常量
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~ _STACK_BASEADDRESS定义在option.inc中
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
/********************************************************************************
检查tasm.exe里是否设置了采用THUMB(16位)代码(armasm -16 ...@ADS 1.0)
*********************************************************************************/
GBLL THUMBCODE ; 定义THUMBCODE全局变量
[ {CONFIG} = 16 ;如果发现是采用用16 THUMB位代码的话，相当于if (CONFIG==16)
THUMBCODE SETL {TRUE} ;把THUMBCODE设置为TURE
CODE32 ;把处理器从新设置成为ARM模式即使用ARM代码模式CODE32
| ;如果处理器现在就是ARM模式，相当于else
THUMBCODE SETL {FALSE};把THUMBCODE设置为FALSE就行了
]
MACRO ;一个根据THUMBCODE把PC寄存的值保存到LR的宏
MOV_PC_LR
[ THUMBCODE
bx lr ;在ARM模式中要使用BX指令转跳到THUMB指令,并转换模式，bx指令会根据PC最后一位来确定是否进入Thumb状态lr,链接寄存器
| ;else
mov pc,lr ;如果目标地址也是ARM指令的话就采用这种方式
]
MEND ;宏定义结束标志
MACRO ;和上面的宏MACRO一样,只是多了一个相等的条件
MOVEQ_PC_LR
[ THUMBCODE
bxeq lr
|
moveq pc,lr
]
MEND
/********************************************************************************
下面这个宏是用于第一次查表过程的实现中断向量的重定向,如果你比较细心的话就是发现
在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表是采用型如Handle***的方式的.
而在程序的ENTRY处(程序开始处)采用的是b Handler***的方式.
在这里Handler***就是通过HANDLER这个宏和Handle***进立联系的.
这种方式的优点就是正真定义的向量数据在内存空间里,而不是在ENTRY处的ROM(FLASH)空间里,
这样,我们就可以在程序里灵活的改动向量的数据了.
---------------------------------------------------------------------------------
这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字
空间都有一个标号，以Handle***命名。
在向量中断模式下使用“加载程序”来执行中断服务程序。
这里就必须讲一下向量中断模式和非向量中断模式的概念
向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的;
指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址函数中
节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下
代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会自动跳转到HandlerADC函数中
非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，
系统将interrupt pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断函数中
该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳
到对应中断源的处理代码中。
;H|------| H|------| H|------| H|------| H|------|
; |/ / / | |/ / / | |/ / / | |/ / / | |/ / / |
; |------|<----sp |------| |------| |------| |------|<------sp
;L| | |------|<----sp L|------| |-isr--| |------| isr==>pc
; | | | | |--r0--|<----sp L|---r0-|<----sp L|------| r0==>r0
; (0) (1) (2) (3) (4)
*********************************************************************************/
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel ;标号
sub sp,sp,#4 ;decrement sp(to store jump address) 减少sp(用于存放跳转地址)
stmfd sp!,{r0} ;PUSH the work register to stack(lr does not push because it return to original address)
;把工作寄存器压入栈 (lr does not push because it return to original address)
ldr r0,=$HandleLabel;load the address of HandleXXX to r0 /将HandleXXX的地址放入 r0
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX
;把HandleXXX所指向的内容(也就是中断程序的入口)放入r0
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack 把中断服务程序(ISR)压入栈 （str存储字数据）
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)用出栈的方式恢复r0的原值和为pc设定新值(也就完成了到ISR的转跳)
MEND
/********************************************************************************
这里用IMPORT伪指令(和c语言的extren一样)引入|Image$$RO$$Base|,|Image$$RO$$Limit|...
这些变量是通过ADS的工程设置里面设定的RO Base和RW Base设定的,
最终由编译脚本和连接程序导入程序.
那为什么要引入IMPORT伪指令,最简单的用处是可以根据它们拷贝自已
*********************************************************************************/
IMPORT |Image$$ER_ROM1$$RO$$Base| ; Base of ROM code ROM代码段开始地址
IMPORT |Image$$ER_ROM1$$RO$$Limit| ; End of ROM code (=start of ROM data) ROM代码段结束地址+
IMPORT |Image$$RW_RAM1$$RW$$Base| ; Base of RAM to initialise 要初始化的RAM开始地址
IMPORT |Image$$RW_RAM1$$ZI$$Base| ; Base and limit of area area(需要清除的RAM区域)的开始地址
IMPORT |Image$$RW_RAM1$$ZI$$Limit| ; to zero initialise area的结束地址
;这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数
IMPORT MMU_SetAsyncBusMode
IMPORT MMU_SetFastBusMode ;
IMPORT Main ; The main entry of mon program
;代码入口下面就是arm的代码
AREA RESET,CODE,READONLY
ENTRY ;定义程序的入口(for debug)
EXPORT __ENTRY ;导出符号ENTRY
__ENTRY
ResetEntry
;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD can not be used here because the linker generates error.
ASSERT :DEF:ENDIAN_CHANGE ;ASSERT 是断言伪指令,语法是:ASSERT +逻辑表达式，判断ENDIAN_CHANGE是否已定义
/************************************************************************************
ASSERT用来表示程序的编译必须满足一定的条件，如果逻辑表达式不满足，则编译器会报错，并终止汇编。
例如：
ASSERT ver>7 ;保证ver>7 编译器才会正常编译
DEF 是逻辑伪操作符，格式为： :DEF:label，DEF运算符判断是否定义某个符号，
例如：
：DEF：ABC如果符号ABC已经定义，则结果为真，否则为假。
------------------------------------------------------------------------------------------
三句带DCD注释的指令能且只能执行一句，并且前三句若执行跳转后，处理程序的最后一句也是
（b ResetHandler ） 不会执行。
3、" [ " 相当于 if
" | "相当于else
" ] " 相当于endif
*************************************************************************************/
[ ENDIAN_CHANGE ;下面是大小端判断在Option.inc里已经设为FALSE ARM如何进行大小端设置、转换？仔细看，下面这段代码就是！
ASSERT :DEF:ENTRY_BUS_WIDTH ;判断WNTRY_BUS_WIDTH 是否已经定义
[ ENTRY_BUS_WIDTH=32 ;如果已经定义了ENTRY_BUS_WIDTH，则判断是不是为32
b ChangeBigEndian ;DCD 0xea000007 ;在bigendian中，地址为A的字单元包括字节单元A，A+1，A+2，A+3，字节单元由高位到低位为A，A+1，A+2，A+3
;地址为A的字单元包括半字单元A，A+2，半字单元由高位到低位为A，A+2
]
[ ENTRY_BUS_WIDTH=16 ;如果已经定义了ENTRY_BUS_WIDTH，则判断是不是为32
andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00 也是b ChangeBigEndian指令，只是由于总线不一样而取机器码的顺序不一样
] ;先取低位->高位 上述指令是通过机器码装换而来的
[ ENTRY_BUS_WIDTH=8
streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea ;也是b ChangeBigEndian指令，只是由于总线不一样而取机器码的顺序不一样
]
|
b ResetHandler ;转换完毕为FALSE跳转到复位程序入口
] ;异常中断向量地址表
b HandlerUndef ;handler for Undefined mode 0x04 未定义异常
b HandlerSWI ;handler for SWI interrupt 0x08 软中断异常
b HandlerPabort ;handler for PAbort 0x0c 取址中止异常
b HandlerDabort ;handler for DAbort 0x10 数据中止异常
b . ;reserved 0x14 预定地，保留地
b HandlerIRQ ;handler for IRQ interrupt 0x18 中断异常
b HandlerFIQ ;handler for FIQ interrupt 0x1c 快速中断异常
;@0x20
b EnterPWDN ; Must be @0x20.
/*************************************************************************************
以下这段是改变大小端存储格式
通过设置CP15的C1的位7，设置存储格式为Bigendian，三种总线方式
*************************************************************************************/
ChangeBigEndian ;这里 ENTRY_BUS_WIDTH=16
;@0x24
[ ENTRY_BUS_WIDTH=32
DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian
DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
;对存储器控制寄存器操作，指定内存模式为Big-endian
;因为刚开始CPU都是按照32位总线的指令格式运行的，如果采用其他的话，CPU别不了，必须转化
;但当系统初始化好以后，则CPU能自动识别
]
[ ENTRY_BUS_WIDTH=16
DCD 0x0f10ee11
DCD 0x0080e380
DCD 0x0f10ee01
;因为采用Big-endian模式，采用16位总线时，物理地址的高位和数据的地位对应
;所以指令的机器码也相应的高低对调
]
[ ENTRY_BUS_WIDTH=8
DCD 0x100f11ee
DCD 0x800080e3
DCD 0x100f01ee
]
DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
IsrIRQ
sub sp,sp,#4 ;reserved for PC ;预留一个地址来保存服务子程序的地址
stmfd sp!,{r8-r9} ;将r8，r9 依次放入sp指向的地址后面
ldr r9,=INTOFFSET ;偏移量地址给r9 INTOFFSET是一个内部寄存器，存放着中断偏移量
ldr r9,[r9] ;把地址里面的内容给r9
ldr r8,=HandleEINT0 ;第二个中断向量表入口，先装入r8
;查表方法，r8(入口)+index*4(因为一条指令是4 bytes),
;这就是中断要找的那一项.找到了表项,装入!
add r8,r8,r9,lsl #2 ;将INTOFFSET和HandleEINT0结合起来 地址对齐，因为每个中断向量占4个字节，即isr = IvectTable + Offeset * 4
ldr r8,[r8] ;装入中断服务程序的入口
str r8,[sp,#8] ;把入口也入栈,准备再次使用用查表方式/str不是入栈，只是把r0值放到 sp+8 这个地址上面
ldmfd sp!,{r8-r9,pc}; 施招,弹出栈,顺便一个个出栈把r8弹出到PC,O了,跳转成功!
LTORG ;声明文字池,因为我们用了ldr伪指令
;==========================================================================================================
; ENTRY CPU从这开始复位：板子上电复位开始后程序从位于0x0开始执行b ResetHandler 程序从跳转到这里执行
; 板子上电后执行如下几个工作
;===========================================================================================================
ResetHandler
ldr r0,=WTCON ;watch dog disable 关看门狗
ldr r1,=0x0 ;bit[5]: 0 - disable; 1 - enable (reset 默认)
str r1,[r0]
ldr r0,=INTMSK
ldr r1,=0xffffffff ;all interrupt disable 屏蔽所有中断
str r1,[r0]
ldr r0,=INTSUBMSK
ldr r1,=0x7fff ;all sub interrupt disable 关闭子中断
str r1,[r0]
[ {TRUE} ;点亮LED设置点，布尔值；
;rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display
ldr r0,=GPBCON
ldr r1,=0x00555555
str r1,[r0]
ldr r0,=GPBDAT
ldr r1,=0x07fe
str r1,[r0]
]
/***************************************************************************************************
;To reduce PLL lock time, adjust the LOCKTIME register.
;为了减少PLL lock time 调整LOCKTIME 寄存器
PLL 锁相环，作用将外部晶振的频率倍增到一个较高的频率
S3C2440有两个锁相环即MPLL和UPLL，MPLL用于CPU及其他外围设备，通过MPLL会产生三个时钟频率：FCLK HCLK PCLK
FCLK就是CPU的运行时钟频率 HCLK驱动AHB总线设备（如SDRAM）PCLK驱动APB设备（如UART设备）
UPLL用于USB模块。
***************************************************************************************************/
;初始化PLL
ldr r0,=LOCKTIME ;PLL 重置延时
ldr r1,=0xffffff ;由于配置或其他原因导致主频变化时 高16为对应UPLL ;低16为对应MPLL
str r1,[r0] ;PLL新的输出需要一个稳定的过渡时间
[ PLL_ON_START ;如果PLL没有启动
; Added for confirm clock divide. for 2440.
; Setting value Fclk:Hclk:Pclk
ldr r0,=CLKDIVN ;设置分频数
ldr r1,=CLKDIV_VAL ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6. option.inc中定义CLKDIV_VAL=5
str r1,[r0] ;存储的数据表示分频数即5
/**************************************************************************************************
MMu如何设置
***************************************************************************************************/
; MMU_SetAsyncBusMode and MMU_SetFastBusMode over 4K, so do not call here
; call it after copy
; [ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]
;program has not been copied, so use these directly
[ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
|
mrc p15,0,r0,c1,c0,0
bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF
mcr p15,0,r0,c1,c0,0
]
;Configure UPLL 配置UPLL 用于USB模块 最终频率为16.9344MHz
ldr r0,=UPLLCON
ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV)
str r1,[r0]
nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
nop
nop
nop
nop
nop
nop
;Configure MPLL
ldr r0,=MPLLCON ;设置源数据地址(伪指令加载标号地址)
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=16.9344MHz
str r1,[r0] ;将r1的字数据存储到r0指向的内存单元中
]
;Check if the boot is caused by the wake-up from SLEEP mode. 检查是不是从sleep模式中恢复
ldr r1,=GSTATUS2 ;(伪指令加载标号地址)
ldr r0,[r1] ;将r1地址单元的数据加载到r1中
tst r0,#0x2 ;位测试指令 测试倒数第二位是不是0
;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
bne WAKEUP_SLEEP ;如果不是0则跳到 WAKEUP_SLEP
EXPORT StartPointAfterSleepWakeUp ;导出符号 StartPointAfterSleepWakeUp 干什么用？
StartPointAfterSleepWakeUp
/********************************************************************************
;设置内存控制器等寄存器的值,因为这些寄存器是连续排列的,所以采用如下办法对这些
;寄存器进行连续设置.其中用到了SMRDATA的数据,这在代码后面有定义
*********************************************************************************/
;Set memory control registers
;ldr r0,=SMRDATA
adrl r0, SMRDATA ;be careful!
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
/***********************************************************************************
;%表示搜索，B表示反向-back(F表示向前-forward)，0为局部标号(0~99)
;%B 代表向前索引 标号为0的行
;BNE指令是“不相等（或不为0）跳转指令
****************************************************************/
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;When EINT0 is pressed, Clear SDRAM 如果 EINT0 产生(这中断就是我们按键产生的), 就清除SDRAM ;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; check if EIN0 button is pressed
ldr r0,=GPFCON
ldr r1,=0x0
str r1,[r0]
ldr r0,=GPFUP
ldr r1,=0xff
str r1,[r0]
ldr r1,=GPFDAT
ldr r0,[r1]
bic r0,r0,#(0x1e<<1) ; bit clear
tst r0,#0x1
bne %F1 ;%F 表示向后索引标号为1的行
;如果没有按,就跳到后面的1标号处 => Initialize stacks
; Clear SDRAM Start 清除SDARM的代码
ldr r0,=GPFCON
ldr r1,=0x55aa
str r1,[r0]
; ldr r0,=GPFUP
; ldr r1,=0xff
; str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x0
str r1,[r0] ;LED=****
mov r1,#0
mov r2,#0
mov r3,#0
mov r4,#0
mov r5,#0
mov r6,#0
mov r7,#0
mov r8,#0
ldr r9,=0x4000000 ;64MB
ldr r0,=0x30000000
0
stmia r0!,{r1-r8}
subs r9,r9,#32
bne %B0
;Clear SDRAM End OVER结束
1
;Initialize stacks
bl InitStacks ;初始化堆栈
;===========================================================
ldr r0, =BWSCON
ldr r0, [r0]
ands r0, r0, #6 ;OM[1:0] != 0, NOR FLash boot 从NOR Flash启动或者直接从内存中运行
bne copy_proc_beg ;do not read nand flash 不读取 Nand Flash
adr r0, ResetEntry ;OM[1:0] == 0, NAND FLash boot OM[1:0] == 0, 为从NAND FLash启动
cmp r0, #0 ;if use Multi-ice, 再比较入口地址是不是0地址处
/***************************************************************
如果不为0 则表示主板设置从NAND启动，？
***************************************************************/
bne copy_proc_beg ;do not read nand flash for boot 跳到 copy_proc_beg 这种情况也不读取nandflash
;nop
;===========================================================
nand_boot_beg ;这段代码完成从nand读代码到RAM
mov r5, #NFCONF ;设定nand的控制寄存器 ？ 用2440配置nand
;set timing value
ldr r0, =(7<<12)|(7<<8)|(7<<4)
str r0, [r5]
;enable control
ldr r0, =(0<<13)|(0<<12)|(0<<10)|(0<<9)|(0<<8)|(1<<6)|(1<<5)|(1<<4)|(1<<1)|(1<<0)
str r0, [r5, #4]
bl ReadNandID ;读取nand的ID 结果保存在r5中
mov r6, #0 ;给r6赋0
ldr r0, =0xec73 ;设置ID号 0xec73
cmp r5, r0 ;进行比较
beq %F1 ;如果相等 向前跳转到 标号1
ldr r0, =0xec75 ;设置标号 0xec75
cmp r5, r0 ;比较
beq %F1 ;如果相等 向前跳转到 标号1
mov r6, #1 ;如果不相等 给r6赋1
1
bl ReadNandStatus ;跳转到 ReadNandStatus 调用 ReadNandStatus 结果存放在r1中
mov r8, #0 ;给r8赋0 nand的第一页 （r8是页数变量）
ldr r9, =ResetEntry ;加载ResetEntry 地址到r9 要复制nand起始地址,r9指向在RAM中的起始地址
/***************************************************************
; 在这里使用的是ldr伪指令,而不是上面用的adr伪指令,它加载的是ResetEntry
; 的绝对地址,也就是我们期望的RAM中的地址,在这里,它和|Image$$RO$$Base|一样
; 也就是说,我如我们编译程序时RO BASE指定的地址在RAM里,而把生成的文件拷到
; NAND里运行,由ldr加载的r9的值还是定位在内存
***************************************************************/
2
ands r0, r8, #0x1f ;凡r8为0x1f(32)的整数倍-1,eq有效,ne无效 ：r0 = r8 & #0x1f =0 & #0x1f=0 ;若结果为0,则标志位Z=1
bne %F3 ;这句的意思是对每个块(32页)进行检错
mov r0, r8 ;
bl CheckBadBlk ; 调用函数CheckBadBlk 检查NADA的坏区 返回非零值表示块区不是坏的
cmp r0, #0 ;比较r0和0 相等则是坏块
addne r8, r8, #32 ; 不相等则r8=r8+#32,如果当前块坏了，跳过读取操作。 1 block=32 pages
bne %F4 ;没有坏区的话就向后跳转到标号4处！ ; 不相等跳到4处检查下一块？
3
mov r0, r8 ;当前页号送到r0
mov r1, r9 ;当前目标地址送到r1
bl ReadNandPage ;读nand一页 512B
add r9, r9, #512 ;缓冲区地址加512 即一页
add r8, r8, #1 ;页数增加1
4
cmp r8, #4096 ; 一共读取4096页即2048KBytes 2048*512=？
bcc %B2 ;如果r8小于4096（没读完）就返回前面标号2处
mov r5, #NFCONF ;DsNandFlash 关闭nand芯片
ldr r0, [r5, #4]
bic r0, r0, #1
str r0, [r5, #4]
ldr pc, =copy_proc_beg ;调用 copy_proc_beg
;===========================================================
copy_proc_beg
adr r0, ResetEntry ; ResetEntry 值给r0
/***********************************************************************************
注意，这里使用的是adr，而不是ldr。使用ldr说明ResetEntry是个绝对地址，这个地址是在程序
链接的时候是确定的。而使用adr则说明ResetEntry的地址和当前代码的执行位置有关，它是一个相对的地址。
***********************************************************************************/
ldr r2, BaseOfROM ; BaseOfROM 值给r2
cmp r0, r2 ;比较r0r2
ldreq r0, TopOfROM ; 相等的话加载TopOfROM到r0 相等说明程序是从nandflash或者sdram中运行的。
;不相等是从norflash运行的
beq InitRam ;相等的话跳转到InitRam
/***********************************************************************************
下面这个是针对代码在NOR FLASH时的拷贝方法
;功能为把从ResetEntry起,TopOfROM-BaseOfROM大小的数据拷到BaseOfROM
;TopOfROM和BaseOfROM为|Image$$RO$$Limit|和|Image$$RO$$Base|
;|Image$$RO$$Limit|和|Image$$RO$$Base|由连接器生成
;为生成的代码的代码段运行时的起启和终止地址
;BaseOfBSS和BaseOfZero为|Image$$RW$$Base|和|Image$$ZI$$Base|
;|Image$$RW$$Base|和|Image$$ZI$$Base|也是由连接器生成
;两者之间就是初始化数据的存放地放
/************************************************************************************
以下代码是针对代码在NOR FLASH时的拷贝方法,这个程序 从norflash也要copy程序
************************************************************************************/
ldr r3, TopOfROM
0
ldmia r0!, {r4-r7} ;复制代码
stmia r2!, {r4-r7}
cmp r2, r3
bcc %B0
sub r2, r2, r3 ;r2=BaseOfROM-TopOfROM=(-)代码长度
;上面拷贝时每次拷贝4个双字（32位）大小，但是RO段大小不一定是4的整数倍，所以可能多拷贝了几个双字大小，r2-r3得到多拷贝的个数
sub r0, r0, r2 ;r0=ResetEntry-(-)代码长度=ResetEntry+代码长度 r0-(r2-r3)可以使r0指向在boot nand中RO的结束地址
InitRam ;复制SW区域
ldr r2, BaseOfBSS ;BaseOfBSS赋给r2
ldr r3, BaseOfZero ;BaseOfZero赋给r3
0
cmp r2, r3 ;比较r2和r3 （BaseOfBSS和BaseOfZero ）
ldrcc r1, [r0], #4
strcc r1, [r2], #4
bcc %B0
mov r0, #0
ldr r3, EndOfBSS
1
cmp r2, r3
strcc r0, [r2], #4
bcc %B1
ldr pc, =%F2 ;goto compiler address
2
; [ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]
;bl Led_Test
/*===========================================================
进入C函数最后一步,把我们用查二级向量表的中断配置到一级向量表(即异常向量表)里.
;=========================================================== */
; Setup IRQ handler
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there is not 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
; ;Copy and paste RW data/zero initialized data
; ldr r0, =|Image$$ER_ROM1$$RO$$Limit| ; Get pointer to ROM data
; ldr r1, =|Image$$RW_RAM1$$RW$$Base| ; and RAM copy
; ldr r3, =|Image$$RW_RAM1$$ZI$$Base|
;
; ;Zero init base => top of initialised data
; cmp r0, r1 ; Check that they are different
; beq %F2
;1
; cmp r1, r3 ; Copy init data
; ldrcc r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
; strcc r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
; bcc %B1
;2
; ldr r1, =|Image$$RW_RAM1$$ZI$$Limit| ; Top of zero init segment
; mov r2, #0
;3
; cmp r3, r1 ; Zero init
; strcc r2, [r3], #4
; bcc %B3
[ :LNOT:THUMBCODE
bl Main ;Do not use main() because ......
;ldr pc, =Main ;
b .
]
[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ;Do not use main() because ......
b .
CODE32
]
;function initializing stacks
InitStacks
;Do not use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack ; UndefStack=0x33FF_5C00
orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack ; AbortStack=0x33FF_6000
orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack ; IRQStack=0x33FF_7000
orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack ; FIQStack=0x33FF_8000
bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack ; SVCStack=0x33FF_5800
;USER mode has not be initialized.
mov pc,lr
;The LR register will not be valid if the current mode is not SVC mode.
;===========================================================
ReadNandID ; 读Nand芯片ID将结果放在r5中
mov r7,#NFCONF
ldr r0,[r7,#4] ;NFChipEn(); ; NFChipEn();启动Nand芯片
bic r0,r0,#2
str r0,[r7,#4] ;启动Nand
mov r0,#0x90 ;WrNFCmd(RdIDCMD); ;WrNFCmd(RdIDCMD) ;0x90为读ID指令
strb r0,[r7,#8] ;NFCmd
mov r4,#0 ;WrNFAddr(0); ;WrNFAddr(0)
strb r4,[r7,#0xc] ;NFADDR
1 ;while(NFIsBusy());
ldr r0,[r7,#0x20] ;NFSTAT 等待写完毕
tst r0,#1 ;测试组后一位是不是0
beq %B1 ;是0 则向前跳转到标号1
ldrb r0,[r7,#0x10] ;id = RdNFDat()<<8; ; id = RdNFDat()<<8 ; NFDATA,读出Nand芯片id前8位
mov r0,r0,lsl #8 ; r0 << #8再存进r0
ldrb r1,[r7,#0x10] ;id |= RdNFDat(); ; id |= RdNFDat() ; NFDATA,读出Nand芯片id后8位
orr r5,r1,r0 ; r5 = r1|r0
ldr r0,[r7,#4] ;NFChipDs(); ;NFChipDs();关闭Nand芯片
orr r0,r0,#2
str r0,[r7,#4]
mov pc,lr ;返回
ReadNandStatus ;读取Nand芯片状态将结果放在r1中,此处没有用到返回值
mov r7,#NFCONF
ldr r0,[r7,#4] ;NFChipEn(); ; NFChipEn();启动Nand芯片
bic r0,r0,#2
str r0,[r7,#4] ;启动Nand
mov r0,#0x70 ;WrNFCmd(QUERYCMD); ;WrNFCmd(QUERYCMD);读取Nand芯片状态
strb r0,[r7,#8] ;写命令
ldrb r1,[r7,#0x10] ;r1 = RdNFDat(); ;r1 = RdNFDat();Busy : "0" Ready : "1"
ldr r0,[r7,#4] ;NFChipDs();
orr r0,r0,#2
str r0,[r7,#4]
mov pc,lr ;NFChipDs();关闭Nand芯片
WaitNandBusy ;等待Nand内部操作完毕
mov r0,#0x70 ;WrNFCmd(QUERYCMD);
mov r1,#NFCONF
strb r0,[r1,#8] ;读取Nand芯片状态
1 ;while(!(RdNFDat()&0x40));
ldrb r0,[r1,#0x10]
tst r0,#0x40
beq %B1
mov r0,#0 ;WrNFCmd(READCMD0);
strb r0,[r1,#8] ;发送读指令0x00，是整页读取
mov pc,lr ;返回
CheckBadBlk ;检查坏块返回值非0表明当前块不是坏块。
mov r7, lr
mov r5, #NFCONF
bic r0,r0,#0x1f ;addr &= ~0x1f;
ldr r1,[r5,#4] ;NFChipEn() 启动nand芯片
bic r1,r1,#2
str r1,[r5,#4]
mov r1,#0x50 ;WrNFCmd(READCMD2)
strb r1,[r5,#8] ;读校验码
mov r1, #5;6 ;6->5
strb r1,[r5,#0xc] ;WrNFAddr(5);(6) 6->5
strb r0,[r5,#0xc] ;WrNFAddr(addr)
mov r1,r0,lsr #8 ;WrNFAddr(addr>>8)
strb r1,[r5,#0xc]
cmp r6,#0 ;if(NandAddr)
movne r0,r0,lsr #16 ;WrNFAddr(addr>>16)
strneb r0,[r5,#0xc]
; bl WaitNandBusy ;WaitNFBusy()
;do not use WaitNandBusy, after WaitNandBusy will read part A!
mov r0, #100
1
subs r0, r0, #1
bne %B1
2
ldr r0, [r5, #0x20]
tst r0, #1
beq %B2
ldrb r0, [r5,#0x10] ;RdNFDat()
sub r0, r0, #0xff
mov r1,#0 ;WrNFCmd(READCMD0)
strb r1,[r5,#8]
ldr r1,[r5,#4] ;NFChipDs()
orr r1,r1,#2
str r1,[r5,#4]
mov pc, r7
ReadNandPage ;读Nand页
mov r7,lr
mov r4,r1 ;读进缓冲区首地址
mov r5,#NFCONF
ldr r1,[r5,#4] ;NFChipEn() 启动nand芯片
bic r1,r1,#2
str r1,[r5,#4]
mov r1,#0 ;WrNFCmd(READCMD0)
strb r1,[r5,#8]
strb r1,[r5,#0xc] ;WrNFAddr(0)
strb r0,[r5,#0xc] ;WrNFAddr(addr)
mov r1,r0,lsr #8 ;WrNFAddr(addr>>8)
strb r1,[r5,#0xc]
cmp r6,#0 ;if(NandAddr)
movne r0,r0,lsr #16 ;WrNFAddr(addr>>16)
strneb r0,[r5,#0xc]
ldr r0,[r5,#4] ;InitEcc()
orr r0,r0,#0x10
str r0,[r5,#4]
bl WaitNandBusy ;WaitNFBusy()
mov r0,#0 ;for(i=0; i<512; i++)
1
ldrb r1,[r5,#0x10] ;buf[i] = RdNFDat()
strb r1,[r4,r0] ;读进缓冲区地址加1
add r0,r0,#1 ;每循环一次r0= r0 + #1
bic r0,r0,#0x10000
cmp r0,#0x200 ;判断R0是否等于512
bcc %B1
ldr r0,[r5,#4] ;NFChipDs();关闭nand芯片
orr r0,r0,#2
str r0,[r5,#4]
mov pc,r7 ;返回
;===========================================================
LTORG ;声明文字池
;GCS0->SST39VF1601
;GCS1->16c550
;GCS2->IDE
;GCS3->CS8900
;GCS4->DM9000
;GCS5->CF Card
;GCS6->SDRAM
;GCS7->unused
SMRDATA DATA ;这是一块连续的地址，用于存放 存储器总线宽度&等待控制寄存器
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK<=75Mhz.
DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)
DCD 0x32 ;SCLK power saving mode, BANKSIZE 128M/128M
DCD 0x30 ;MRSR6 CL=3clk
DCD 0x30 ;MRSR7 CL=3clk
BaseOfROM DCD |Image$$ER_ROM1$$RO$$Base|
TopOfROM DCD |Image$$ER_ROM1$$RO$$Limit|
BaseOfBSS DCD |Image$$RW_RAM1$$RW$$Base|
BaseOfZero DCD |Image$$RW_RAM1$$ZI$$Base|
EndOfBSS DCD |Image$$RW_RAM1$$ZI$$Limit|
ALIGN
;Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on.
; 5. The location of the following code may have not to be changed.
;void EnterPWDN(int CLKCON);
EnterPWDN ;进入掉电模式（关机powerdown）
mov r2,r0 ;r2=rCLKCON 保存原始数据 0x4c00000c 使各模块的时钟处于输入状态 r0为该函数输入参数clkcon
tst r0,#0x8 ;SLEEP mode? 测试bit[3] Sleep mode
bne ENTER_SLEEP ;C=0 即TST结果非0 bit[3]=1
ENTER_STOP ;如果不是sleep 则进入stop（待机模式）
ldr r0,=REFRESH ;0x48000024 DRAM/SDRAM refresh config
ldr r3,[r0] ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH ;???????????????
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;wait until self-refresh is issued. may not be needed.
0 subs r1,r1,#1
bne %B0
ldr r0,=CLKCON ;enter STOP mode.
str r2,[r0]
mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off
; Entering SLEEP mode, only the reset by wake-up is available.
ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
str r3,[r0]
MOV_PC_LR
;进入睡眠模式
ENTER_SLEEP
;NOTE.
;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.
ldr r0,=REFRESH
ldr r1,[r0] ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.
0 subs r1,r1,#1
bne %B0
ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17) ;Set SCLK0=0, SCLK1=0, SCKE=0.
str r0,[r1]
ldr r0,=CLKCON ; Enter sleep mode
str r2,[r0]
b . ;CPU will die here.
WAKEUP_SLEEP ;从SLEEP模式下唤醒函数段
;Release SCLKn after wake-up from the SLEEP mode.
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.
str r0,[r1]
;Set memory control registers
ldr r0,=SMRDATA ;be careful! ;得到SMRDATA的地址
ldr r1,=BWSCON ;BWSCON Address ;得到BWSCON的地址
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
bne %B0
ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after SLEEP wake-up
ldr r0,[r1]
mov pc,r0
;=====================================================================
; Clock division test
; Assemble code, because VSYNC time is very short
;=====================================================================
EXPORT CLKDIV124
EXPORT CLKDIV144
CLKDIV124
ldr r0, = CLKDIVN
ldr r1, = 0x3 ; 0x3 = 1:2:4
str r1, [r0]
; wait until clock is stable
nop
nop
nop
nop
nop
ldr r0, = REFRESH ;SDRAM刷新控制寄存器
ldr r1, [r0]
bic r1, r1, #0xff
bic r1, r1, #(0x7<<8) ;设置刷新计数的值
orr r1, r1, #0x470 ; REFCNT135
str r1, [r0]
nop
nop
nop
nop
nop
mov pc, lr
CLKDIV144
ldr r0, = CLKDIVN
ldr r1, = 0x4 ; 0x4 = 1:4:4
str r1, [r0]
; wait until clock is stable
nop
nop
nop
nop
nop
ldr r0, = REFRESH
ldr r1, [r0]
bic r1, r1, #0xff
bic r1, r1, #(0x7<<8)
orr r1, r1, #0x630 ; REFCNT675 - 1520
str r1, [r0]
nop
nop
nop
nop
nop
mov pc, lr
ALIGN
AREA RamData, DATA, READWRITE ;相应中断跳转的地址存放处
^ _ISR_STARTADDRESS ; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4
;Do not use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0 # 4
HandleEINT1 # 4
HandleEINT2 # 4
HandleEINT3 # 4
HandleEINT4_7 # 4
HandleEINT8_23 # 4
HandleCAM # 4 ; Added for 2440.
HandleBATFLT # 4
HandleTICK # 4
HandleWDT # 4
HandleTIMER0 # 4
HandleTIMER1 # 4
HandleTIMER2 # 4
HandleTIMER3 # 4
HandleTIMER4 # 4
HandleUART2 # 4
;@0x33FF_FF60
HandleLCD # 4
HandleDMA0 # 4
HandleDMA1 # 4
HandleDMA2 # 4
HandleDMA3 # 4
HandleMMC # 4
HandleSPI0 # 4
HandleUART1 # 4
HandleNFCON # 4 ; Added for 2440.
HandleUSBD # 4
HandleUSBH # 4
HandleIIC # 4
HandleUART0 # 4
HandleSPI1 # 4
HandleRTC # 4
HandleADC # 4
;@0x33FF_FFA0
END
136
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
