最长的前缀

http://blog.sina.com.cn/s/blog_75727b140100uky5.html

题目如下：

　　在 生物学中，一些生物的结构是用包含其要素的大写字母序列来表示的。生物学家对于把长的序列分解成较短的（称之为元素的）序列很感兴趣。

　　如果一个集合 P 中的元素可以通过并运算（允许重复；并，即∪，相当于 Pascal 中的 “+” 运算符）组成一个序列 S ，那么我们认为序列 S 可以分解为 P 中的元素。并不是所有的元素都必须出现。举个例子，序列 ABABACABAAB 可以分解为下面集合中的元素：

　　{A, AB, BA, CA, BBC}

　　序列 S 的前面 K 个字符称作 S 中长度为 K 的前缀。设计一个程序，输入一个元素集合以及一个大写字母序列，计算这个序列最长的前缀的长度。

　　PROGRAM NAME: prefix

　　INPUT FORMAT

　　输入数据的开头包括 1..200 个元素（长度为 1..10 ）组成的集合，用连续的以空格分开的字符串表示。字母全部是大写，数据可能不止一行。元素集合结束的标志是一个只包含一个 “.” 的行。集合中的元素没有重复。接着是大写字母序列 S ，长度为 1..200,000 ，用一行或者多行的字符串来表示，每行不超过 76 个字符。换行符并不是序列 S 的一部分。

假设这个字符串中的前缀可以达到第i位，而最后一位在集合中的字符串为后面j位，那么也就是说字符串的第一位到第i-j位都可以分解成集合中的元素。我们就可以用一个Boolean的数组记录可以达到的前缀的数位为true，如果b[i-j]为true，而字符串中j+1位到i位为集合中的元素，那么b[i]也为true。这样就成了动态规划了。输入时采用字符输入而非字符串比较省时间。最后输出Boolean数组中最大的一位。

program usaco231;
var s:array[1..300]of string;
    a:array[1..300]of longint;
    b:array[-10..200000]of boolean;
    ss,z:ansistring;
    c:char;
    n,m,i,j:longint;

procedure init;
begin
    m:=1;  c:='a';
    while c<>'.' do
    begin
        read(c);
        if c in ['A'..'Z'] then s[m]:=s[m]+c else inc(m);
    end;
    ss:='';
    while not eof do
    begin
        readln(z);
        ss:=ss+z;
    end;
    n:=length(ss); b[0]:=true;
    for i:=1 to m do a[i]:=length(s[i]);
end;

procedure work;
begin
    for i:=1 to n do
       for j:=1 to m do if b[i-a[j]] then
           if copy(ss,i-a[j]+1,a[j])=s[j] then
           begin
               b[i]:=true;
               break;
           end;

    for i:=n downto 0 do if b[i] then
    begin
        writeln(i);
        exit;
    end;
end;

begin
    init;
    work;
end.