洛谷 2330 繁忙的都市

题目描述
    城市C是一个非常繁忙的大都市，城市中的道路十分的拥挤，于是市长决定对其中的道路进行改造。城市C的道路是这样分布的：城市中有n个交叉路口，有些交叉路口之间有道路相连，两个交叉路口之间最多有一条道路相连接。这些道路是双向的，且把所有的交叉路口直接或间接的连接起来了。每条道路都有一个分值，分值越小表示这个道路越繁忙，越需要进行改造。但是市政府的资金有限，市长希望进行改造的道路越少越好，于是他提出下面的要求：
1．改造的那些道路能够把所有的交叉路口直接或间接的连通起来。
2．在满足要求1的情况下，改造的道路尽量少。
3．在满足要求1、2的情况下，改造的那些道路中分值最大的道路分值尽量小。
任务：作为市规划局的你，应当作出最佳的决策，选择那些道路应当被修建。

输入格式：
    第一行有两个整数n,m表示城市有n个交叉路口，m条道路。接下来m行是对每条道路的描述，u, v, c表示交叉路口u和v之间有道路相连，分值为c。(1≤n≤300，1≤c≤10000)
输出格式：
    两个整数s, max，表示你选出了几条道路，分值最大的那条道路的分值是多少。
输入样例#1：
4 5
1 2 3
1 4 5
2 4 7
2 3 6
3 4 8
输出样例#1：

3 6

解题思路：

    简单的库鲁斯卡尔算法。

代码：

var
  n,m,j,i,min,ans:longint;
  a:array[0..10000,1..3]of longint;
  v,f:array[0..500]of longint;


function getfather(x:longint):longint;
begin
  if f[x]=x then exit(x);
  f[x]:=getfather(f[x]);
  exit(f[x]);
end;


procedure qsort(l,r:longint);
var
  i,j,t:longint;
begin
  i:=l;j:=r;t:=a[(l+r)div 2,3];
  repeat
    while a[i,3]<t do inc(i);
    while a[j,3]>t do dec(j);
    if i<=j then
      begin
        a[0]:=a[i];
        a[i]:=a[j];
        a[j]:=a[0];
        inc(i);dec(j);
      end;
  until i>j;
  if l<j then qsort(l,j);
  if i<r then qsort(i,r);
end;


procedure merge(x,y:longint);
var
  i,j:longint;
begin
  i:=getfather(x);j:=getfather(y);
  f[i]:=j;
end;


function judge(x,y:longint):boolean;
var
  i,j:longint;
begin
  i:=getfather(x);
  j:=getfather(y);
  exit(i=j);
end;


begin
  readln(n,m);
  for i:=1 to m do
    readln(a[i,1],a[i,2],a[i,3]);
  qsort(1,m);
  for i:=1 to n do
    f[i]:=i;
  i:=0;
  repeat
    inc(i);
    if judge(a[i,1],a[i,2]) then continue
    else begin
           inc(ans);
           merge(a[i,1],a[i,2]);
         end;
  until ans=n-1;
  writeln(n-1,' ',a[i,3]);
end.