32位汇编语言学习笔记(36)--repne scasb指令



repne scasb指令，用于扫描字符串，计算字符串的长度，如下两条指令：
cld
repne scasb
对应的等价指令是：
scans:inc edi
    dec ecx
    je loopdone
    cmp byte [edi-1],al
    jne scans
loopdone:
下面看一个示例程序：

section .data

	EditBuff: db 'abcdefghijklm#',10
	BUFFERLEN equ $-EditBuff
	FILLCHR	  equ 35 ;'#'
	
section .text

WriteStr:
	push eax		; Save pertinent registers
	push ebx
	mov eax,4		; Specify sys_write call
	mov ebx,1		; Specify File Descriptor 1: Stdout
	int 80H			; Make the kernel call
	pop ebx			; Restore pertinent registers
	pop eax
	ret			; Go home
	
	global	_start
_start:
	nop
	
	mov ecx,EditBuff		
	mov edx,BUFFERLEN	
	call WriteStr
	
	cld
	mov al, FILLCHR
	mov edi,EditBuff	
	mov ecx,0000ffffh	
	repne scasb
	mov byte [edi-1], '$'
				
    mov ecx,EditBuff		
	mov edx,BUFFERLEN	
	call WriteStr

Exit:	mov eax,1		; Code for Exit Syscall
	mov ebx,0		; Return a code of zero	
	int 80H			; Make kernel call

程序分析：
cld //控制edi指向的字符串地址变化方向是从低到高
 mov al, FILLCHR  //al=’#’
 mov edi,EditBuff  //edi= EditBuff
 mov ecx,0000ffffh //ecx=65535
 repne scasb //扫描edi指向的字符串，扫描方向从低位地址向高位地址，如果遇到字节等于al或者ecx计数为0，则结束扫描。
 mov byte [edi-1], '$' //因为每次循环都会把edi加1，因此edi-1才是等于al那个字节（对于本例ecx肯定不会为0）。所以本条指令会把’#’替换成’$’。

makefile文件内容：

scasbdemo: scasbdemo.o
	ld -o scasbdemo scasbdemo.o
scasbdemo.o: scasbdemo.asm
	nasm -f elf -g -F stabs scasbdemo.asm -l scasbdemo.lst

测试：

[root@bogon scasbdemo]# make
nasm -f elf -g -F stabs scasbdemo.asm -l scasbdemo.lst
ld -o scasbdemo scasbdemo.o
[root@bogon scasbdemo]# ./scasbdemo 
abcdefghijklm#
abcdefghijklm$