本文介绍了SAP开发中不同方式实现ALV（List Viewer）的细节，包括函数模块、OO方式、SALV类以及开源类库Falv。作者提出了一种新的方法，即ZCL_ALV_MULTI类，可以便捷地创建多屏幕ALV，并且支持事件处理。通过示例代码展示了如何创建双击事件、按钮事件等，并提供了相关事件处理的类模板。此外，文章还提供了一个DEMO程序来说明如何使用这个新方法。
对于SAP的开发者来说，ALV大家并不陌生，这也可能是在开发的过程中接触最多的东西，
到目前为止，本人用过的用于实现Alv的方式有以下几种:
1. Function的alv: REUSE_ALV_GRID_DISPLAY
REUSE_ALV_GRID_DISPLAY_LVC( 升级版 ) 增加了对于单元格的处理
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
EXPORTING
i_callback_program = lv_repid
is_variant = ls_variant
i_callback_pf_status_set = 'ALV_STATUS'
i_callback_user_command = 'USER_COMMAND'
is_layout_lvc = gs_layout
it_fieldcat_lvc = gt_field
TABLES
t_outtab = gt_data
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
缺点:alv的事件处理相对麻烦一点，无法满足同时显示多个ALV的需求
2. ooalv: cl_gui_alv_grid
gcl_alv->set_table_for_first_display（
EXPORTING
is_layout = ls_layout
i_save = 'A'
is_variant = ls_variant
CHANGING
it_outtab = gt_head
it_fieldcatalog = lt_fcat ）.
3. salv cl_salv_table
TRY.
cl_salv_table=>factory( IMPORTING r_salv_table = cl_salv
CHANGING t_table = gt_data ).
CATCH cx_salv_msg.
ENDTRY.
SALV可以像使用函数方式那样生成alv，不需要创建屏幕，而且可以在后台运行
感觉更像是 ooalv的 的升级版
4. Falv zcl_falv
lcl_falv=>create( CHANGING ct_table = gt_data )-display( ).
一个开源的ALV类，能够更加方便的实现一个ALV
目前来说Falv是个人使用最多的一个是实现ALV的方式，更便捷，更快速
但是以上的ALV都没有办法快速的实现一个多ALV的展示方法
通常如果我们要展示一个上下屏，或者左右屏的alv都需要先创建一个屏幕
在屏幕的PBO里使用类 cl_gui_custom_container 屏（需要在屏幕绘制控制区域）按需绘制好，然后跟alv做绑定
或者cl_gui_docking_container来跟屏幕做关联生成一个存放alv的容器，再调用splliter的类来分割容器
那有没有办法能够像上面的Falv一样能够快速的来生成多个ALV呢，经过一段时间的构思，它来了
TRY.
NEW zcl_alv_multi(
it_mapping = VALUE #( ( objid = '1' tabname = 'GT_VBAK' )
( objid = '2' tabname = 'GT_VBAP' ) )
iv_mode = '21' )->call_screen( ).
CATCH zcx_alv_error INTO lcx.
ENDTRY.
像Falv一样能够快捷的实现一个多屏幕的ALV，通过 it_mapping 来构建 alv 跟内表的关联，通过iv_mode来实现alv的展示效果
11 单屏
12 横向两个alv
13 横向三个
21 纵向两个
31 纵向三个 依次类推
而且，已经将alv的事件类继承进去，只需要在代码中创建一个cl_alv_event（必须要是这个名字，因为后边会从堆栈中查找该子类）的事件子类即可，通过类的属性objid来控制区分是第几个alv
大部分的alv事件 F1 F4 双击 按钮 点击按钮后 修改单元格等事件都已涵盖，按需重定义方法即可,下面是demo程序的相关代码
"事件类，只能使用cl_alv_event 来命名
CLASS cl_alv_event DEFINITION INHERITING FROM zcl_alv_event_receiver.
PUBLIC SECTION.
METHODS double_click REDEFINITION."双击
METHODS user_command REDEFINITION."点击按钮后
METHODS toolbar REDEFINITION."按钮
METHODS hotspot_click REDEFINITION."单击
METHODS change_fieldcat REDEFINITION."更改fieldcat
ENDCLASS.
CLASS cl_alv_event IMPLEMENTATION.
按钮事件在第一个alv中增加保存按钮
METHOD toolbar.
DATA:ls_toolbar TYPE stb_button.
DEFINE mar_toolbar.
ls_toolbar-function = &1.
ls_toolbar-text = &2.
ls_toolbar-quickinfo = &3.
ls_toolbar-icon = &4.
APPEND ls_toolbar TO e_object->mt_toolbar .
CLEAR ls_toolbar.
END-OF-DEFINITION.
CASE objid.
WHEN '1'.
mar_toolbar 'SAVE' '' '保存' icon_system_save.
WHEN '2'.
WHEN OTHERS.
ENDCASE.
ENDMETHOD.
METHOD user_command.
CASE e_ucomm.
WHEN 'SAVE'.
MESSAGE '保存成功' TYPE 'I' DISPLAY LIKE 'S'.
"如果是刷新当前的alv,只需要使用get_alv_grid即可
TRY.
refresh( get_alv_grid( ) ).
CATCH zcx_alv_error INTO DATA(cx).
ENDTRY.
ENDCASE.
ENDMETHOD.
双击第一个alv的销售订单来过滤出第二个alv的销售订单行项目，double_click方法也已经进行代码封装，e_data就是当前双击行的内容
METHOD double_click.
CASE objid.
WHEN '1'.
"按照销售订单来过滤第二个alv
ASSIGN e_data->* TO FIELD-SYMBOL(<ls_data>).
这里使用filter的方式来过滤alv，调用set_filter即可按照字段来生成相关参数
DATA(lt_filter) = set_filter( EXPORTING i_fields = VALUE #( ( name = 'VBELN' ) )
i_data = e_data ).
这里要刷新第二个alv，首先使用ge_alv_grid的方法获取到第二个alv，然后刷新即可
TRY.
get_alv_grid( '2' )->set_filter_criteria( lt_filter ).
refresh( get_alv_grid( '2' ) ).
CATCH zcx_alv_error INTO DATA(cx).
ENDTRY.
ENDCASE.
ENDMETHOD.
单击事件，单击第一个alv的vbeln 来跳转到va03 ，同doubleclick一样，直接使用e_data即可
METHOD hotspot_click.
CASE objid.
WHEN '1'.
"单击vbeln来跳转到va03
ASSIGN e_data->* TO FIELD-SYMBOL(<ls_data>).
ASSIGN COMPONENT e_column_id-fieldname OF STRUCTURE <ls_data> TO FIELD-SYMBOL(<value>).
CASE e_column_id-fieldname.
WHEN 'VBELN'.
SET PARAMETER ID 'AUN' FIELD <value>.
CALL TRANSACTION 'VA03' AND SKIP FIRST SCREEN.
ENDCASE.
ENDCASE.
ENDMETHOD.
这里是设置alv的fieldcat，系统会自动根据内表生成fieldcat，这里只需要对ct_fcat的字段进行增删改即可
METHOD change_fieldcat.
LOOP AT ct_fcat ASSIGNING FIELD-SYMBOL(<ls_fcat>).
CASE <ls_fcat>-fieldname.
WHEN 'VBELN'.
<ls_fcat>-hotspot = abap_true.
ENDCASE.
ENDLOOP.
ENDMETHOD.
layout由于基本上每个alv的使用方法一样，这里就没有重定义，使用的父类的，如果有需要也可以重定义
ENDCLASS.
START-OF-SELECTION.
gt_vbak = VALUE #( ( vbeln = '1' erdat = sy-datum )
( vbeln = '2' erdat = sy-datum )
( vbeln = '3' erdat = sy-datum ) ).
gt_vbap = VALUE #(
( vbeln = '1' posnr = '1' )
( vbeln = '1' posnr = '2' )
( vbeln = '1' posnr = '3' )
( vbeln = '2' posnr = '1' )
( vbeln = '2' posnr = '2' )
( vbeln = '3' posnr = '1' )
( vbeln = '3' posnr = '2' )
( vbeln = '3' posnr = '3' )
( vbeln = '3' posnr = '4' ) ).
"调用alv展示
" iv_mode 12 13代表 竖向 2/3 个alv， 21 31代表横向 2/3 个alv
"系统会根据tcode自动获取tcode的描述作为标题，如果想指定，iv_title 给值即可
CASE abap_true.
WHEN p_1."单个屏幕
TRY.
NEW zcl_alv_multi(
it_mapping = VALUE #( ( objid = '1' tabname = 'GT_VBAK' ) ) )->call_screen( ).
CATCH zcx_alv_error INTO DATA(lcx).
ENDTRY.
"单个屏幕的也推荐使用falv
WHEN p_2."多个屏幕
TRY.
NEW zcl_alv_multi(
it_mapping = VALUE #( ( objid = '1' tabname = 'GT_VBAK' )
( objid = '2' tabname = 'GT_VBAP' ) )
iv_mode = '21' )->call_screen( ).
CATCH zcx_alv_error INTO lcx.
ENDTRY.
WHEN OTHERS.
ENDCASE.
实现效果如下
ALV事件类以及构建类
第一次发表公众号文章，排版不好，请见谅，话不多说，直接上安装包
链接：https://pan.baidu.com/s/1lo1VV2ImsI06Hg0x0YPVRQ
提取码，请关注后发送信息 我想要 进行获取，感谢！！！！
如果你在使用中觉得好，请帮忙多多分享，如有使用BUG请公众号联系本人解决
请使用abapgit进行安装，对于abapgit的介绍以及相关安装方法请参照下图连接博主氢氦的文章
https://www.cnblogs.com/hhelibeb/p/7735421.html
扫一扫
1366
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
