BI神器Power Query（17）-- PQ制作时间维度表（6）

在上一篇博客中，通过Text.From函数创建了“年份”、“季度”和“月份”列数据列，如下图所示。

大家都知道在Excel中日期格式有很多种，可以根据用户的使用习惯选择不同的样式，在PQ中创建新列时也可以通过类似的格式化字符串来获得不同的日期格式。

依次单击【添加列】=>【自定义列】，在【添加自定义列】对话框中，指定【新列名】为“月份2”，输入公式=Date.ToText([Date],"MMM")，其中[Date]含义是引用Date列，单击【确定】按钮完成插入列。Date.ToText函数用于将日期转换为指定格式。

选中“月份2”列，在【公式编辑栏】中修改公式，添加“, type text”（注意需要有逗号）将结果转换为文本类型，结果如下图所示，轻松转换为中文月份。

使用类似的方法添加“星期”，数据为“周一”的形式，如下图所示。

选中【Date】列，依次单击【日期】下拉按钮=>【天】=>【星期几】插入新列。注意：在下拉菜单的【天】中而不是【周】中。

编辑PQ公式修改列标题为“星期2”，结果如下图所示。

在【高级编辑器】中查看PQ公式如下。

let
    FirstDate = #date(2018,1,1),
    LastDate = #date(2019,12,31), 
    CalDates = {Number.From(FirstDate) .. Number.From(LastDate)},
    转换为表 = Table.FromList(CalDates, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    更改的类型 = Table.TransformColumnTypes(转换为表,{{"Column1", type date}}),
    插入的日期 = Table.AddColumn(更改的类型, "Date", each DateTime.Date([Column1]), type date),
    已添加自定义 = Table.AddColumn(插入的日期, "DateText", each Date.ToText([Date],"yyyyMMdd"), type text),
    复制的列 = Table.DuplicateColumn(已添加自定义, "DateText", "DateInt"),
    更改的类型1 = Table.TransformColumnTypes(复制的列,{{"DateInt", Int64.Type}}),
    插入的年份 = Table.AddColumn(更改的类型1, "Year", each Date.Year([Date]), type number),
    插入的月份 = Table.AddColumn(插入的年份, "Month", each Date.Month([Date]), type number),
    插入的某一日 = Table.AddColumn(插入的月份, "Day", each Date.Day([Date]), type number),
    插入的季度 = Table.AddColumn(插入的某一日, "Quarter", each Date.QuarterOfYear([Date]), type number),
    插入的每年的某一周 = Table.AddColumn(插入的季度, "WeekOfYear", each Date.WeekOfYear([Date]), type number),
    年份 = Table.AddColumn(插入的每年的某一周, "年份", each "Y" & Text.From([Year]), type text),
    季度 = Table.AddColumn(年份, "季度", each "Q" & Text.From([Quarter]), type text),
    月份 = Table.AddColumn(季度, "月份", each Text.From([Month]) & "月", type text),
    月份2 = Table.AddColumn(月份, "月份2", each Date.ToText([Date],"MMM"),type text),
    星期 = Table.AddColumn(月份2, "星期", each Date.ToText([Date],"ddd"),type text),
    星期2 = Table.AddColumn(星期, "星期2", each Date.DayOfWeekName([Date]),type text)
in
    星期2

---

未完待续 … …

相关文章链接如下：
PQ制作时间维度表（1）
PQ制作时间维度表（2）
PQ制作时间维度表（3）
PQ制作时间维度表（4）
PQ制作时间维度表（5）
PQ制作时间维度表（6）
PQ制作时间维度表（7）