VBA之正则表达式（25）-- 提取规格

实例需求：待处理字符串如下。

ABC1550R71PF1333K, 33nF,50V; X117R/ 0402

处理规则：仅提取其中如下图黄色部分，注意不提取第一个逗号之前的任何4位数字

示例代码如下。

Sub Demo1()
    Dim strWord As String
    Dim objRegExp As Object, objMH As Object
    Set objRegExp = CreateObject("VBSCRIPT.REGEXP")
    strWord = "ABC1550R71PF1333K, 33nF,50V; X117R/ 0402"
    With objRegExp
        .Global = True
        .ignoreCase = True        
        .Pattern = "(?:[^a-z])(\d{4})|[^a-z\d](\d{1,2}[a-z]{1,})"
        Set objMatch = .Execute(strWord)
        If objMatch.Count > 0 Then
            For Each objMH In objMatch
               Debug.Print IIf(objMH.submatches(0) = "", objMH.submatches(1), objMH.submatches(0))
            Next
        End If
    End With
    Set objRegExp = Nothing
End Sub

运行代码结果如下。

33nF
50V
0402

【代码解析】
第4行代码创建正则表达式对象。
第5行代码设置初始字符串变量。
第9行代码设置匹配模式。
第10行代码执行正则匹配。
如果匹配成功，第12~14行代码使用For…Next循环结构在立即窗口中输出匹配结果。

正则表达式	说明
(?:[^a-z])	非提取匹配组，用于匹配非英文字符
(\d{4})	匹配4位数字
[^a-z\d]	匹配一个非英文和数字
(\d{1,2}[a-z]{1,}	匹配1~2位数字，其后为一个或者多个英文字符

注意三个匹配组，有的是第一个匹配组，有的是第二个匹配组，第13行使用IIF进行判断。

---

仔细观察3个需要提取的匹配组，其共同的特征是：

• 之前一个字符是空格或者逗号
• 前2两个字符都是数字（假设数字部分最长为4位）
  根据这两个特征，可以将正则匹配模式进行简化。

示例代码如下。

Sub Demo2()
    Dim strWord As String
    Dim objRegExp As Object, objMH As Object
    Set objRegExp = CreateObject("VBSCRIPT.REGEXP")
    strWord = "ABC1550R71PF1333K, 33nF,50V; X117R/ 0402"
    With objRegExp
        .Global = True
        .ignoreCase = True
        .Pattern = "\b\d{1,4}([a-z]{1,2})*\b"
        Set objMatch = .Execute(strWord)
        If objMatch.Count > 0 Then
            For Each objMH In objMatch
               Debug.Print objMH
            Next
        End If
    End With
    Set objRegExp = Nothing
End Sub

【代码解析】

正则表达式	说明
\b	匹配单词边界
\d{1,4}	匹配1~4位数字
([a-z]{1,2})*	匹配1~2个英文字符，也可以不存在

匹配结果如下图所示。