VBA快速合并数据

实例需求：原始数据保存在工作表的A列至C列，现需要根据材料编号合并交付日期和交付数量，并且交付日期的日期格式采用两位数字年份简写格式，合并后的数据保存在E列和F列，如下图所示。

示例代码如下。

Sub demo()
    Dim objDict, arrData, arrItms, i
    Set objDict = CreateObject("scripting.dictionary")
    With Sheets(sht)
        arrData = .[a1].CurrentRegion.Value
        For i = 2 To UBound(arrData)
            arrData(i, 2) = Format(arrData(i, 2), "yy/m/d")
            If objDict.exists(arrData(i, 1)) Then
                arrItms = Array(objDict(arrData(i, 1)), arrData(i, 2), arrData(i, 3))
            Else
                arrItms = Array(arrData(i, 2), arrData(i, 3))
            End If
            objDict(arrData(i, 1)) = Join(arrItms, ",")
        Next
        .Range("E:F").Clear
        .Range("E1:F1") = Array("物料编号", "交期")
        With objDict
            .[e2].Resize(.Count, 1) = Application.Transpose(.keys)
            .[f2].Resize(.Count, 1) = Application.Transpose(.items)
        End With
    End With
    Set objDict = Nothing
End Sub

【代码解析】
第3行代码创建字典对象。
第5行代码将数据读取到数组中。
第6~14行代码循环处理每行数据。
第7行代码使用Format函数格式化B列的日期。
第8行代码判断字典中是否已经存在相同的材料编号。
如果存在，第9行代码将把已有数据、交付日期和交付数量保存在数组中。
如果不存在，第11行代码将只把交付日期和交付数量保存在数组中。
第13行代码使用Join函数更新字典的值，实现合并交付日期和交付数量。
第15行代码清空E列和F列。
第16行代码设置E列和F列的标题行。
第18行代码将字典的键（即材料编号）写入E列。
第19行代码将字典的值（即合并后的交期）写入F列。
第22行代码释放对象变量占用的系统资源。