windows oracle 启动关闭脚本

需要用windows管理员权限运行，win10下测试通过

::oracle安装时会默认安装7个service，介绍如下
::
::1. Oracle ORCL VSS Writer Service：（非必须启动）
::Oracle卷映射拷贝写入服务，VSS（Volume Shadow Copy Service）能够让存储基础设备（比如磁盘，阵列等）创建高保真的时间点映像，即映射拷贝（shadow copy）。它可以在多卷或者单个卷上创建映射拷贝，同时不会影响到系统的系统能。
::
::2. OracleDBConsoleorcl：（非必须启动，视情况启动）
::Oracle数据库控制台服务，orcl是Oracle的实例标识，默认的实例为orcl。在运行Enterprise Manager（企业管理器OEM）的时候，需要启动这个服务。
::
::3. OracleJobSchedulerORCL：（非必须启动）
::Oracle作业调度（定时器）服务，ORCL是Oracle实例标识。
::
::4. OracleMTSRecoveryService：（非必须启动）
::服务端控制。该服务允许数据库充当一个微软事务服务器MTS、COM/COM+对象和分布式环境下的事务的资源管理器。
::
::5. OracleOraDb11g_home1ClrAgent：（非必须启动）
::Oracle数据库，.NET扩展服务的一部分。 
::
::6. OracleOraDb11g_home1TNSListener：（非必须启动，建议启动）
::监听器服务，服务只有在数据库需要远程访问的时候才需要。
::
::7. OracleServiceORCL：(必须启动)
::数据库服务(数据库实例)，是Oracle核心服务该服务，是数据库启动的基础， 只有该服务启动，Oracle数据库才能正常启动。
::
::对新手来说，要是只用Oracle自带的sql*plus的话，只要启动OracleServiceORCL即可，要是使用PL/SQL Developer等第三方工具的话，OracleOraDb11g_home1TNSListener服务也要开启。OracleDBConsoleorcl是进入基于web的EM必须开启的，其余服务很少用。
::注：ORCL是数据库实例名，默认的数据库是ORCL，你可以创建其他的，即OracleService+数据库名。
:: 以下为安装oracle的默认启动顺序，建议全部修改为手动
::Oracle ORCL VSS Writer Service 手动
::OracleDBConsoleorcl 自动
::OracleJobSchedulerORCL 禁用
::OracleMTSRecoveryService 自动
::OracleOraDb11g_home1ClrAgent 手动
::OracleOraDb11g_home1TNSListener 自动
::OracleServiceORCL 自动
::OracleRemExecSrvice 未安装成功
@echo off
title Oracle服务管理
color 2f
:MENU
cls
echo. =-=-=-=-=Oracle服务管理=-=-=-=-=
echo.
echo. 1 开启服务
echo.
echo. 2 关闭服务
echo.
echo. 3 退 出
echo.
echo. 注意：请以管理员身份运行该脚本
echo.
echo. =-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
set /p choice=请输入:
::如果choice不为空，只取第一位字符
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if "%choice%"=="1" goto cmd1
if "%choice%"=="2" goto cmd2
if "%choice%"=="3" exit
echo.  
echo.  
echo 输入的选择不正确，请重新输入！  
echo.  
echo.  
GOTO MENU 
:cmd1
echo.
echo 开启Oracle服务中…
echo 启动em
net start|findstr /i /c:"OracleDBConsoleorcl">nul&&set k=1||set k=0
if %k%==0 (net start "OracleDBConsoleorcl")
::net start|findstr /i /c:"OracleOraDb11g_home1iSQL*Plus">nul&&set k=1||set k=0
::if %k%==0 (net start "OracleOraDb11g_home1iSQL*Plus")
echo 启动监听
net start|findstr /i /c:"OracleOraDb11g_home1TNSListener">nul&&set k=1||set k=0
if %k%==0 (net start "OracleOraDb11g_home1TNSListener")
echo 启动实例
net start|findstr /i /c:"OracleServiceORCL">nul&&set k=1||set k=0
if %k%==0 (net start "OracleServiceORCL")
echo.
echo Oracle服务已经成功开启…
echo.
echo.
echo 请使用https://localhost:1158/em访问控制台
echo 所有账号包括sys都是password
echo.
echo.
pause
exit
:cmd2
echo.
echo 关闭Oracle服务中…
echo 启动em
net start|findstr /i /c:"OracleDBConsoleorcl">nul&&set k=1||set k=0
if %k%==1 (net stop "OracleDBConsoleorcl")
::net start|findstr /i /c:"OracleOraDb11g_home1iSQL*Plus">nul&&set k=1||set k=0
::if %k%==1 (net stop "OracleOraDb11g_home1iSQL*Plus")
echo 启动监听
net start|findstr /i /c:"OracleOraDb11g_home1TNSListener">nul&&set k=1||set k=0
if %k%==1 (net stop "OracleOraDb11g_home1TNSListener")
echo 启动实例
net start|findstr /i /c:"OracleServiceORCL">nul&&set k=1||set k=0
if %k%==1 (net stop "OracleServiceORCL")
echo.
echo Oracle服务已经成功关闭…
echo.
pause
exit