mysql数据库
安装
下载
下载地址(mysql5.7),目前最新版本8.0
下载的是免安装版的zip文件,解压到安装目录,只需要几个命令就完成安装
开始安装
假如解压的目录是F:\mysql
那么我们呢先准备好配置文件my.ini,放到bin目录下
[client]
port=3306 #设置数据库监听3306端口
default-character-set=utf8 #设置mysql客户端默认编码字符集
[mysqld]
port=3306
character_set_server=utf8 #设置mysql服务端使用的默认字符集
basedir=F:\mysql #设置mysql的安装目录
datadir=F:\mysql\data #设置mysql数据库数据的存放目录
max_connections=200 #设置mysql允许的最大连接数
然后打开cmd,切换路径到F:\mysql\bin
# 执行命令,安装mysql
mysqld.exe -install
# 会按照my.ini里的配置初始化(初始化密码为空)
mysqld --initialize-insecure --user=mysql
# 接下来设置root密码123456
mysqladmin -u root -p password 123456
# 顺带一提卸载,运行以下命令即可
mysqld --remove
# 然后把mysq目录下的东西删除干净
安装完毕
这个时候,就可以通过net start mysql
来启动服务了
# 启动
net start mysql
# 用刚刚的账户登录
mysql -uroot -p123456
注意:如果不想每次登录mysql都切到F:\mysql\bin
,就去配置环境变量PATH,添加F:\mysql\bin
(注意前面有东西的话用";"隔开)
使用批处理脚本安装
我们发现,上面的几个命令一条一条的输入略微麻烦了,还容易错,这时可以写个批处理脚本(installMysql.bat)来完成安装
将脚本放到 F:\mysql\installMysql.bat
,执行即可
rem 关闭命令回显
@echo off
rem 清屏
cls
rem 设置bat窗口标题
title * mysql management *
rem 判断是否为管理员
Rd "%WinDir%\system32\test_permissions" >NUL 2>NUL
Md "%WinDir%\System32\test_permissions" 2>NUL||(Echo 请使用右键管理员身份运行!&&Pause >nul&&Exit)
Rd "%WinDir%\System32\test_permissions" 2>NUL
rem 设置颜色,和输出提示信息
color 2f
echo.
echo. Please choose
echo. -------------------------------
echo.
echo. 1.install mysql
echo.
echo. 2.uninstall mysql
echo.
echo. 3.Exit
echo.
echo.
rem 请用户输入选择
set /p c=Please:
if %c%==1 goto 1
if %c%==2 goto 2
if %c%==3 Exit
:1
echo being installed
rem 得到当前的路径(包含盘符和目录),"%~0"会得到"F:\mysql\installMysql.bat",加入参数dp,表示到盘符和文件路径("F:\mysql")
set location=%~dp0
rem 向F:\mysql\bin\min.ini 里写入配置
echo [client] >> %location%bin\my.ini
echo port=3306 >> %location%bin\my.ini
echo default-character-set=utf8 >> %location%bin\my.ini
echo [mysqld] >> %location%bin\my.ini
echo port=3306 >> %location%bin\my.ini
echo character_set_server=utf8 >> %location%bin\my.ini
echo basedir=%location% >> %location%bin\my.ini
echo datadir=%location%data >> %location%bin\my.ini
echo max_connections=200 >> %location%bin\my.ini
rem 配置环境变量(先拿到原来的,然后在加上mysql的路径)
setx path "%path%;%location%bin" /m
rem 安装mysql的三个命令,按照顺序执行
%location%bin\mysqld.exe -install
echo Please wait for initialization...
%location%bin\mysqld --initialize-insecure --user=mysql
net start mysql
echo Please enter the carriage directly.
%location%bin\mysqladmin -u root -p password 123456
echo Finish the installation
echo default password "123456"
pause
Exit
:2
echo being uninstalled
net stop mysql
mysqld --remove
echo Please manually delete the files in the installation directory and complete the unloading.
pause
Exit
考虑到步骤比较简单,这个脚本编写的时候没有考虑安装出错的情况,如果有兴趣也可以加上
比如: 在执行命令的语句后面 加上一句
if errorlevel 1 pause & echo '失败'
,如果上一条命令执行失败,那么输出“失败”,对错误进行处理
安装的坑
安装时若是提示msvcp120.dll错误,那么去安装相应的文件到系统目录上,或者直接去安装vcredist运行库
修改密码
可能时间长了,大家会忘记密码,那么该如何修改呢?
-
修改my.ini文件,添加一行
skip-grant-tables
,跳过登录命令,保存 -
重启mysq服务,在cmd窗口输入
net restart mysql
-
登录,此时无需输入密码
-
修改root密码
# 进入mysq数据库 use mysql; # 修改root密码,基于(mysql 5.7) update user set authentication_string = password('密码'), password_expired = 'N',password_last_changed = now() where user = 'root'; #如果你的mysql是5.6版本修改root密码(mysql5.6版本) update user set password=password('密码') where user='root'; # 刷新权限,使其生效 flush privileges; #退出 exit
-
最后将添加的
skip-grant-tables
,去掉
修改密码还有其他方式,这里就不说了
参考链接
https://www.runoob.com/mysql/mysql-administration.html