一个操作系统的实现（二）

对应原书第三章，与原书步骤大致相同（注意部分代码及代码解释在原书中有所以没有贴出，本系列博客需结合原书食用）

1. 阅读chpter3/a/pmtest1.asm，源码如下：

==========================================
pmtest1.asm
编译方法：nasm pmtest1.asm -o pmtest1.bin
==========================================

%include	"pm.inc"	; 常量，宏，以及一些说明

org		07c00h
		jmp		LABEL_BEGIN

[SECTION .gdt]
; GDT
;								段基址,		段界限,			属性
LABEL_GDT:			Descriptor		 0,				   0,	0				; 空描述符
LABEL_DESC_CODE32:	Descriptor		 0,	SegCode32Len - 1,	DA_C + DA_32	; 非一致代码段
LABEL_DESC_VIDEO:	Descriptor 0B8000h,			  0ffffh,	DA_DRW			; 显存首地址

; GDT 结束

GdtLen		equ		$ - LABEL_GDT	; GDT长度
GdtPtr		dw		GdtLen - 1		; GDT界限
			dd		0				; GDT基地址
			
; GDT选择子
SelectorCode32		equ		LABEL_DESC_CODE32		- LABEL_GDT
SelectorVideo		equ		LABEL_DESC_VIDEO		- LABEL_GDT
; END of [SECTION .gdt]

[SECTION .s16]		; 16位代码段
[BITS 16] 			
LABEL_BEGIN:
	mov		ax, cs
	mov		ds, ax
	mov		es, ax
	mov		ss, ax
	mov 	sp, 0100h
	
	; 初始化32位代码段描述符
	xor 	eax, eax
	mov 	ax, cs
	shl		eax, 4
	sdd		eax, LABEL_SEG_CODE32
	mov		word [LABEL_DESC_CODE32 + 2], ax
	shr		eax, 16
	mov 	byte [LABEL_DESC_CODE32 + 4], al
	mov 	byte [LABEL_DESC_CODE32 + 7], ah
	
	; 为加载 GDTR 做准备
	xor		eax, eax
	mov		ax, ds
	shl		eax, 4
	add		eax, LABEL_GDT			; eax <- gdt 基地址
	mov		dword [GdtPtr + 2], eax	; [GdtPtr + 2] <- gdt 基地址
	
	; 加载 GDTR
	lgdt	[GdtPtr]
	
	; 关中断
	cli
	
	; 打开地址线A20
	in 		al, 92h
	or		al, 00000010b
	out		92h, al
	
	; 准备切换到保护模式
	mov 	eax, cr0
	or 		eax, 1
	mov		cr0, eax
	
	; 真正进入保护模式
	jmp		dword SelectorCode32:0	; 执行这一句会把 SelectorCode32 装入cs
									; 并跳转到 Code32Selector:0 处
									
; END of [SECTION .s16]

[SECTION .s32] 		; 32位代码段，由实模式跳入
[BITS 32]

LABEL_SEG_CODE32:
	mov 	ax, SelectorVideo
	mov 	gs, ax					; 视频段选择子（目的）
	
	mov 	edi, (80 * 11 + 79) * 2	; 屏幕第 11 行，第 79 列
	mov 	ah, 0Ch					; 0000:黑底		1100:红字
	mov 	al, 'P'
	mov		[gs:edi], ax
	
	; 到此停止,无限循环
	jmp 	$
	
SegCode32Len	equ		$ - LABEL_SEG_CODE32
; END of [SECTION .s32]

2. 运行命令编译pmtest1.asm nasm pmtest1.asm -o pmtest1.bin
3. 复制第一章生成的a.img文件，并将生成的pmtest1.bin写入软盘镜像

dd if=pmtest1.bin of=a.img bs=512 count=1 conv=notrunc

4. 将生成的a.img挂到DOC虚拟机（a.img对应下图中的boot2.img）
   
   

为了更加贴合课本以及后面调试需要，从官网安装Bochs（本系列博客用的版本是2.6.11，课本中用的版本是2.3.5，不同版本之间的配置有略微差别），并在Bochs上安装freeDos，在新的freeDos上复现本系列博客一二（步骤类似不进行重复操作）

Bochs配置文件及实验截图如下

1. 第一个实验（Hello, OS world!）：

# Bochs版本为2.6.11，与课本上的配置文件略有不同
# 建立配置文件：Bochs所在目录下新建boshsrc文件，注意无后缀
###############################################################
# Configuration file for Bochs
###############################################################

cpu: model=core2_penryn_t9600, count=1, ips=50000000, reset_on_triple_fault=1, ignore_bad_msrs=1, msrs="msrs.def"
cpu: cpuid_limit_winnt=0

memory: guest=512, host=256

romimage: file=$BXSHARE/BIOS-bochs-latest, options