oracle的触发器

示例的数据表下载的地址：http://download.csdn.net/detail/u010342038/9506955

语法：

create or replace trigger 触发器名
before|after
delete|insert|update [of 列名]
on 表名
[for each row [when(条件)]]
PLSQL块

触发器的分类：

1.语句级触发（针对的是表）

只是做delete|insert|update的操作都是触发一次不管修改多少条纪录

2.行级触发（针对的是行）

只是做delete|insert|update的操作每修改一条纪录（一行数据）就触发一次

:old和:new伪记录变量，识别值的状态
:old和:new 代表同一条记录
:old 表示操作该行之前，这一行的值 
:new 表示操作该行之后，这一行的值

示例：1

create trigger sayemp
after insert
on emp
declare
begin
  dbms_output.put_line('成功插入新员工');
end;

set serveroutput on 

insert into emp (empno,ename,ejob，deptno,sal) values (8000,'Luffy','salesman',10,3000);

示例2：

--触发器应用场景1：实施复杂的安全性检查
--禁止在非工作时间插入新员工
/*
1.周末：to_char(sysdate,'day') in ('星期六','星期日')
2.上班前，下班后：to_number(to_char(sysdate,'hh24')) not between 9 and 18
*/
create or replace trigger securityemp
before insert
on emp
begin
  if to_char(sysdate,'day') in ('星期六','星期日') or
     to_number(to_char(sysdate,'hh24')) not between 9 and 18 then
     --禁止insert新员工（抛出异常就不会执行了,自定义的异常号的范围：-29999~-20000）
     raise_application_error(-20001,'禁止在非工作时间插入新员工');
  end if;
end;

示例3：

/*
触发器应用场景二：数据确认
涨后的薪水不能少于涨前的薪水
:old和:new 代表同一条记录
1 :old 表示操作该行之前，这一行的值 
2 :new 表示操作该行之后，这一行的值
*/
create or replace trigger checksal
before update
on emp
for each row
begin
  if :new.sal < :old.sal then
  raise_application_error(-20002,'涨后的薪水不能少于涨前的薪水,涨后的薪水:'||:new.sal||' ,涨前的薪水'||:old.sal);
  end if;
end;

示例4：

create table audit_info(
  information varchar2(200)
);

/*
  触发器应用场景三：数据库的审计--》基于值的审计功能
  给员工涨工资，当涨后员工的工资超6000，就审计该员工的信息
*/


create or replace trigger auditempsal
after update
on emp
for each row
begin
  if :new.sal > 6000 then
  insert into audit_info values (:new.empno||' '||:new.ename||' '||:new.sal);
  end if;
end;

示例5：

create table emp_back as select * from emp;

/*
  触发器的应用场景四：数据库的备份和同步
  当给员工涨完工资后，自动备份到备份表中
*/
create or replace trigger sync_emp
after update
on emp
for each row
begin
  --当主表更新后，自动更新到备份表
  update emp_back set sal=:new.sal where empno=:new.empno;
end;