WDA MIME 模板下载

METHOD data_download .

  DATA : lr_component TYPE REF TO if_wd_component.
  DATA : lr_component_info TYPE REF TO if_wd_rr_component.
  DATA : lr_mr_api TYPE REF TO if_mr_api.
  DATA : lv_wd_name TYPE string.
  DATA : lv_url TYPE string.
  DATA : lv_xstr TYPE xstring.

* 取得组件相关对象
  lr_component = wd_this->wd_get_api( ).
  lr_component_info = lr_component->get_component_info( ).
* 取得当前组件的名字
  lv_wd_name = lr_component_info->get_name( ).
* 取得excel模板的URL
  CALL METHOD cl_wd_utilities=>construct_wd_url(
    EXPORTING
      application_name = lv_wd_name
    IMPORTING
      out_local_url    = lv_url ).

  lv_url = lv_url && '/evaluate.xlsx'.
* 取得excel模板中的内容，保存为xstring格式
  lr_mr_api = cl_mime_repository_api=>get_api( ).
  lr_mr_api->get(
    EXPORTING
      i_url     = lv_url
      i_check_authority = ''
    IMPORTING
      e_content = lv_xstr ).
* 将excel打开
  cl_wd_runtime_services=>attach_file_to_response(
    EXPORTING
      i_filename = '导入模板.xlsx'
      i_content = lv_xstr
      i_mime_type = 'xlsx'
      i_in_new_window = abap_false
      i_inplace = abap_false ).

ENDMETHOD.