十二、分段程序

1. 使用db、dw、dd以及dup伪指令定义一段连续的数据空间：

    1) 对于前三个伪指令，前缀d表示define，而后面的三个字母分别表示byte、word、double word的意思，分别用于定义字节空间、字空间、双字空间；

    2) 示例：

assume cs:codesg

codesg segment
	db	0, 1, 2, 3
	dw	0, 1, 2, 3
	dd	0, 1, 2, 3

	mov		ax, 4C00H
	int		21H
codesg ends

end

！注意：该系列伪指令都是在编译阶段就已经写入，因此运行程序之前（就是在程序加载进内存的时候）这些定义好的数据就已经存在于程序的内存空间中了，因此这里不需要单步调试来观察；

    3) dup是duplicate（复制、拷贝的意思）的缩写，即如果想要使用上面的伪指令定义多个重复的值时可以使用dup伪指令，使用方法是：db/dw/dd 重复次数 dup(重复值列表)

请看示例：

assume cs:codesg

codesg segment
	db 3 dup(2) ; == 2 2 2 
	dw 2 dup(7, 9) ; == 7 9 7 9
	dd 3 dup(3, 1) ; == 3 1 3 1 3 1

	mov		ax, 4C00H
	int		21H
codesg ends

end

    4) 也可以定义字符（一个字符就是一个字节的ASCII码）：

assume cs:codesg

codesg segment
	db '1234', '7890'
	; dw '7777' ; Bad! Character can only defined by db!
	db 3 dup('123', 'Abc') ; == '123Abc123Abc123Abc'

	mov		ax, 4C00H
	int		21H
codesg ends

end

可以看到：

   *1. 字符以及字符串必须都用单引号' '括起来；

   *2. 字符型数据只能用db定义，用其它定义会直接编译报错！

2. 分段程序示例：

定义一个数据段和一个栈，然后利用栈将数据段中的内容的顺序反转（以字为单位）：

assume cs:codesg, ds:datasg, ss:stacksg

datasg segment
	dw 1234H, 5678H, 9ABCH, 0DEF0H
datasg ends

stacksg segment
	dw 10 dup(0)
stacksg ends

codesg segment
	dd 20 dup(0)

start:
	mov		ax, datasg
	mov		ds, ax
	mov		ax, stacksg
	mov		ss, ax
	mov		sp, 20

	mov		bx, 0
	mov		cx, 4
lp1:
	push	[bx]
	add		bx, 2
	loop	lp1

	mov		bx, 0
	mov		cx, 4
lp2:
	pop		[bx]
	add		bx, 2
	loop	lp2

	mov		ax, 4C00H
	int		21H
codesg ends

end start

！注意：

    i. 首先是标号start的作用，由于使用assume cs:codesg可以使程序在装载后cs指向codesg，但是这里也看到了，可以在代码段的开始处定义一段数据区域，因此在这种情况下cs:ip会指向这段数据区的开始处，如果直接从这里执行的话必然会造成程序出错，但是只要在最后end伪指令后指定一个标号并且将该标号作为程序真正的入口处地址就可以使程序在装载之后cs:ip指向该标号地址了，通常我们将该表好取名为start；

小结：我们可以利用end伪指令指定程序的入口处地址！在以上这段程序中codesg开始处的数据定义只是为了演示这个道理而已并没有实际意义；

    ii. 我们可以利用类似定义codesg的方式定义其它多个段，但不过能用的也就最都只有4个段了，即cs、ds、ss、es；

    iii. 但是assume只能真正改变cs:ip的指向，但是不能改变其它段寄存器的指向，因此其它段寄存器的指向需要在程序中手工指定！（这在前面讲到过）

*此程序的运行结果：

可以看到内容被反转了！

3. 段的物理大小：

    1) 程序加载后是以16个字节为单位分配空间的，因此如果程序的实际内容刚好是16字节的整数倍则刚好，如果不是16的整数倍，则余数部分必须补全16的字节；

    2) 具体说就是，如果段中的实际内容为N个字节，则需分两种情况讨论：

        i. N为16的倍数，则物理大小就是N字节；

        ii. 如果N不为16的倍数，则物理大小就是 ( N / 16 + 1 ) * 16；

        iii. 因此将两种情况合并起来得到一个归一化的公式就是 ( ( N + 15 ) / 16 ) * 16；

4. 示例：定义三个段，将前两个段中的单元依次对应相加存入第三个段中对应的单元（字节单元）

assume cs:cseg

aseg segment
	db 1, 2, 3, 4, 5, 6, 7
aseg ends

bseg segment
	db 7, 6, 5, 4, 3, 2, 1
bseg ends

cseg segment
	db 7 dup(9)

start:
	mov		ax, aseg
	mov		ss, ax
	mov		ax, bseg
	mov		es, ax
	mov		ax, cseg
	mov		ds, ax

	mov		bx, 0
	mov		cx, 7
lp:
	mov		al, ss:[bx]
	mov		[bx], al
	mov		al, es:[bx]
	add		[bx], al
	inc		bx
	loop	lp

	mov		ax, 4C00H
	int		21H
cseg ends

end start

！注意：可以看到除了代码段其它的段可以不用assume关联也可以随意定义；

运行结果：

5. 示例：将数据段中前8个字逆序存放在栈段的前8个字中

很简单，只需要push就行了，因为栈本来就是逆序扩张的

assume cs:codesg, ds:datasg, ss:stacksg

datasg segment
	dw 1, 2, 3, 4, 5, 6, 7, 8
datasg ends

stacksg segment
	dw 9 dup(0)
stacksg ends

codesg segment

start:
	mov		ax, datasg
	mov		ds, ax
	mov		ax, stacksg
	mov		ss, ax
	mov		bx, 0
	mov		sp, 16

	mov		cx, 8
lp:
	push	[bx]
	add		bx, 2
	loop	lp

	mov		ax, 4C00H
	int		21H
codesg ends

end start

运行结果：