jfinal在windows系统用脚本启动

jfinal.bat启动脚本

@echo off
 
rem -------------------------------------------------------------------------
rem
rem 使用说明：
rem
rem 1: 该脚本用于别的项目时只需要修改 MAIN_CLASS 即可运行
rem
rem 2: JAVA_OPTS 可通过 -D 传入 undertow.port 与 undertow.host 这类参数覆盖
rem    配置文件中的相同值此外还有 undertow.resourcePath, undertow.ioThreads
rem    undertow.workerThreads 共五个参数可通过 -D 进行传入
rem
rem 3: JAVA_OPTS 可传入标准的 java 命令行参数,例如 -Xms256m -Xmx1024m 这类常用参数
rem
rem
rem -------------------------------------------------------------------------
 
setlocal & pushd
 
 
rem 启动入口类,该脚本文件用于别的项目时要改这里
set MAIN_CLASS=自己程序启动主类
 
rem Java 命令行参数,根据需要开启下面的配置,改成自己需要的,注意等号前后不能有空格
rem set "JAVA_OPTS=-Xms256m -Xmx1024m -Dundertow.port=8888 -Dundertow.host=0.0.0.0"
rem set "JAVA_OPTS=-Dundertow.port=8888 -Dundertow.host=0.0.0.0"
 
 
if "%1"=="start" goto normal
if "%1"=="stop" goto normal
if "%1"=="restart" goto normal
 
goto error
 
 
:error
echo Usage: jfinal.bat start | stop | restart
goto :eof
 
 
:normal
if "%1"=="start" goto start
if "%1"=="stop" goto stop
if "%1"=="restart" goto restart
goto :eof
 
 
:start
set APP_BASE_PATH=%~dp0
set CP=%APP_BASE_PATH%config;%APP_BASE_PATH%lib\*
echo starting jfinal undertow
java -Xverify:none %JAVA_OPTS% -cp %CP% %MAIN_CLASS%
goto :eof
 
 
:stop
set "PATH=%JAVA_HOME%\bin;%PATH%"
echo stopping jfinal undertow
for /f "tokens=1" %%i in ('jps -l ^| find "%MAIN_CLASS%"') do ( taskkill /F /PID %%i )
goto :eof
 
 
:restart
call :stop
call :start
goto :eof
 
endlocal & popd

通过命令窗口进去到项目启动脚本所在目录（在项目一级目录下，和lib,config目录同级）
call jfinal.bat start 启动
call jfinal.bat stop 停止