Oracle—存储过程（转）

存储过程和函数—简介:

存储过程和函数也是一种PL/SQL块，是存入数据库的PL/SQL块。但存储过程和函数不同于已经介绍过的PL/SQL程序，我们通常把PL/SQL程序称为无名块，而存储过程和函数是以命名的方式存储于数据库中的。和PL/SQL程序相比，存储过程有很多优点，具体归纳如下：

* 存储过程和函数以命名的数据库对象形式存储于数据库当中。存储在数据库中的优点是很明显的，因为代码不保存在本地，用户可以在任何客户机上登录到数据库，并调用或修改代码。
* 存储过程和函数可由数据库提供安全保证，要想使用存储过程和函数，需要有存储过程和函数的所有者的授权，只有被授权的用户或创建者本身才能执行存储过程或调用函数。
* 存储过程和函数的信息是写入数据字典的，所以存储过程可以看作是一个公用模块，用户编写的PL/SQL程序或其他存储过程都可以调用它(但存储过程和函数不能调用PL/SQL程序)。一个重复使用的功能，可以设计成为存储过程，比如：显示一张工资统计表，可以设计成为存储过程；一个经常调用的计算，可以设计成为存储函数；根据雇员编号返回雇员的姓名，可以设计成存储函数。
* 像其他高级语言的过程和函数一样，可以传递参数给存储过程或函数，参数的传递也有多种方式。存储过程可以有返回值，也可以没有返回值，存储过程的返回值必须通过参数带回；函数有一定的数据类型，像其他的标准函数一样，我们可以通过对函数名的调用返回函数值。
   存储过程和函数需要进行编译，以排除语法错误，只有编译通过才能调用。

一、创建存储过程

创建存储过程，需要有CREATE PROCEDURE或CREATE ANY PROCEDURE的系统权限。该权限可由系统管理员授予。创建一个存储过程的基本语句如下：

CREATE [OR REPLACE] PROCEDURE 存储过程名[(参数[IN|OUT|IN OUT] 数据类型...)]
{AS|IS}
[说明部分]
BEGIN
可执行部分
[EXCEPTION
错误处理部分]
END [过程名];

其中：
可选关键字OR REPLACE 表示如果存储过程已经存在，则用新的存储过程覆盖，通常用于存储过程的重建。
参数部分用于定义多个参数(如果没有参数，就可以省略)。参数有三种形式：IN、OUT和IN OUT。如果没有指明参数的形式，则默认为IN。

关键字AS也可以写成IS，后跟过程的说明部分，可以在此定义过程的局部变量。

二、删除存储过程

一个存储过程在不需要时可以删除。删除存储过程的人是过程的创建者或者拥有DROP ANY PROCEDURE系统权限的人。删除存储过程的语法如下：

DROP PROCEDURE 存储过程名；

三、执行存储过程

执行(或调用)存储过程的人是过程的创建者或是拥有EXECUTE ANY PROCEDURE系统权限的人或是被拥有者授予EXECUTE权限的人。执行的方法如下：

方法1—适用于在SQL*Plus（命令语句）中调用存储过程：

EXECUTE 模式名.存储过程名[(参数...)];

方法2—在PL/SQL中调用存储过程：

BEGIN
模式名.存储过程名[(参数...)];
END;

或者
call 模式名.存储过程名[(参数...)] 

注意：存储过程没有参数时,exec和begin可以直接跟过程名（可以省略( )），但call则必须带上( )

传递的参数必须与定义的参数类型、个数和顺序一致(如果参数定义了默认值，则调用时可以省略参数)。参数可以是变量、常量或表达式。

如果是调用本账户下的存储过程，则模式名可以省略。要调用其他账户编写的存储过程，则模式名必须要添加。

以下是一个生成和调用简单存储过程的训练。注意要事先授予创建存储过程的权限。

四、授权其它账户使用存储过程

GRANT EXECUTE ON 存储过程名[(参数...)] TO 账户名

注意：如果验证存储过程是不是正确，可以在编辑界面编译一下。

案例：
案例1：创建基础存储过程——统计人数

----创建表
create table test_table
(
 id1   varchar2(12),
 name  varchar2(32)
);

----赋值
insert into test_table(id1,name)
values('1','zhangsan');

insert into test_table(id1,name)
values('2','lisi');

insert into test_table(id1,name)
values('3','wangwu');

insert into test_table(id1,name)
values('4','zhaoliu');

insert into test_table(id1,name)
values('5','laowu');

----创建存储过程
create or replace procedure test_count
as
v_total number(10); --声明变量
begin
  select count(*) into v_total from test_table;
  dbms_output.put_line('总人口数:'||v_total);
  end;

----运行存储过程
 begin
   test_count;
   end;
 
 set serveroutput on;
 EXECUTE test_count;

----删除存储过程
drop procedure test_count;

SQL语句执行结果：

命令语句执行结果：

案例2：创建一个带计算的有参数的存储过程

----创建存储过程
create or replace procedure test (     
p1 in out number,p2 in number,r1 out number,r2 out number) as  
begin    
  r1 := p1 + p2;  
  r2 := p1 - p2;   
  p1 := 888;  
end test; 

------调用存储过程 
   declare   --声明
      a number(3) := 100;  --“：=”是赋值
      b number(4) := 1000;  
      c number(5) := 100;   
      d number(4) := 100;  
    begin  
      test(a,b,c,d);   --在PL/SQL中可以<span style="color:#ff0000;"><strong>在语句块中</strong></span>直接引用，但在Sqlplus（或者commend中）需要call或者execute命令  
      dbms_output.put_line('a + b = ' || c);  
      dbms_output.put_line('a - b = ' || d);  
      dbms_output.put_line('但a的值为:' || a || ', b的值为：' || b);  
    end;  

----结果
a + b = 1100  
a - b = -900  
但a的值为:888, b的值为：1000

--IN 定义一个输入参数变量，用于传递参数给存储过程
--OUT 定义一个输出参数变量，用于从存储过程获取数据
--IN OUT 定义一个输入，输出参数变量，兼有两者功能

案例3：创建一个使用游标的存储过程：

--创建存储过程
create or replace procedure test_list
as
cursor test_cursor is select t.id1,t.name from test_table t; --使用游标
begin
   for test_record in test_cursor loop --遍历游标，再打印出来
     dbms_output.put_line(test_record.id1||test_record.name);
     end loop;
     test_count; --同时调用另外一个存储过程
     end;

--结果
1zhangsan
2lisi
3wangwu
4zhaoliu
5laowu
总人口数:5