s5pv210学习<四>定位程序运行地址

一、程序运行
我们知道，任何程序都是运行在内存中的，而内存其实就是一段地址序列而已，每一个程序在运行的时候，系统都会把程序搬移到内存去运行，下面的程序我们要来实现一下如何搬移程序，以及运行。
二、内存
既然到这里，大概的介绍一下内存这个概念，裸机当中也有内存，这个内存叫做虚拟内存，也叫虚存，在裸机上基本随意操作，带系统的一般为堆栈bss data以及常量区和共享库。以32位操作系统为例，通常32位操作系统会为每一个进程分配4G的内存，而具体分布如下：
1G 系统使用 —-用户态无法访问
3G 栈 —-向下生长，系统分配，系统释放
共享库 —-链接共享库
堆 —-向上生长，用户申请分配，用户手动释放
（申请意味着有可能失败）
.text —-存放代码指令的区域
.data —-存放全局或者static修饰的初始化过的变量
.bss —-存放全局或者static修饰的未初始化变量
常量区 —-存放常量如字符串等
三、搬移程序
s5pv210在启动时候只会搬移前16k的程序至内存，如果一个程序超过了16k怎么办？
那么我们只需要在前16k执行一个动作，即是将我们的程序搬移至16k后面去执行即可。
1.链接脚本
链接脚本就是程序链接时指定程序存储位置的脚本，用于控制输出文件的存储布局。
其格式为
SECTIONS
{
sections-command
sections-command
…
}
以我们程序中的为例

SECTIONS 
{ 
    . = 0xD0030000; 
    .text : 
    { 
        start.o 
        * (.text) 
    }
    .data : 
    { 
        * (.data) 
    } 
    bss_start = .; 
    .bss : 
    { 
        * (.bss) 
    } 
    bss_end = .; 
}

在这里“ .”表示当前位置
2.汇编程序

.global _start

_start:
    ldr     r0, =0xE2700000
    mov     r1, #0
    str     r1, [r0]

    // 设置栈，以便调用c函数
    ldr sp, =0xD0037D80                 


    // 开始定向程序                       
    //adr表示引用的是相对地址
    adr r0, _start          
    // _start的链接地址:0xd0024000
    ldr r1, =_start     
    // bss段的起始地址
    ldr r2, =bss_start
    cmp r0, r1
    beq clean_bss
    //上面一段与下面一段的作用主要是定位运行位置，要将start定位到我们指定的位置。所以比较r0和r1，不相等的话就静茹下一段一直循环定位
copy_loop:
    ldr r3, [r0], #4    // 源
    str r3, [r1], #4    // 目的
    cmp r1, r2
    bne copy_loop


    // 清空bss段
clean_bss:
    ldr r0, =bss_start                  
    ldr r1, =bss_end
    cmp r0, r1
    beq run_on_dram
    mov r2, #0
clear_loop:
    str r2, [r0], #4
    cmp r0, r1
    bne clear_loop


    // 跳转
run_on_dram:             
    ldr pc, =main                       


halt:
    b halt

3.点灯程序

#define         GPJ2CON         (*(volatile unsigned long *) 0xE0200280)
#define         GPJ2DAT         (*(volatile unsigned long *) 0xE0200284)


void delay(unsigned long count)
{
        volatile unsigned long i = count;
        while (i--)
                ;
}

void main()                             
{
        GPJ2CON = 0x00001111;           
        while(1)                                       
        {
                GPJ2DAT = 0;                    // LED on
                delay(0x50000);
                GPJ2DAT = 0xf;                  // LED off
                delay(0x50000);
        }
}

详情见git上代码bareOS目录link目录

所有程序在github上，一直会更新至应用层，github地址https://github.com/kentGC/s5pv210，嵌入式交流学习qq群：363361058 欢迎各位大神交流！