前言
看源码可以让我们更加深入理解weak指针。
源码地址
weak源码分析流程图
weak 实现原理
下面的一段代码是我们在开发中常见的weak的使用
- (void)viewDidLoad {
[super viewDidLoad];
NSObject *obj = [[NSObject alloc] init];
__weak NSObject *weakp = obj;
}
转汇编
objc_initWeak
objc_initWeak(&weakp, obj)
源码
id objc_initWeak(id *location, id newObj)
{
if (!newObj) {
*location = nil;
return nil;
}
return storeWeak<DontHaveOld, DoHaveNew, DoCrashIfDeallocating>
(location, (objc_object*)newObj);
}
分析
-
当我们初始化一个weak变量时，runtime会调用 NSObject.mm 中的objc_initWeak函数
-
objc_initWeak函数前提条件: newObj必须是一个没有被注册为__weak对象的有效指针。而newObj则可以是null，或者指向一个有效的对象
-
参数location和newObj
location ：__weak指针自己的地址 也就是 &weakp 后面通过设置*location = nil 完成 弱指针 = nil
newObj ：所引用的对象，即例子中的obj
内存草图
storeWeak
objc_initWeak函数会调用storeWeak函数，该函数主要是更新指针指向，创建对应的弱引用表
storeWeak(&weakp, obj);
源码
template <HaveOld haveOld, HaveNew haveNew,
enum CrashIfDeallocating crashIfDeallocating>
static id storeWeak(id *location, objc_object *newObj)
{
ASSERT(haveOld || haveNew);
if (!haveNew) ASSERT(newObj == nil);
Class previouslyInitializedClass = nil;
id oldObj;
SideTable *oldTable;
SideTable *newTable;
retry:
// 如果weak指针变量 之前弱引用过一个对象 讲这个对象对应的SideTable从SideTables中取出来，赋值给oldTable
if (haveOld) {
oldObj = *location;
oldTable = &SideTables()[oldObj];
} else {
// 如果weak指针变量 之前没有弱引用过一个obj，则oldTable = nil
oldTable = nil;
}
// 如果weak指针变量要weak引用一个新的obj，则将该obj对应的SideTable取出，赋值给newTable
if (haveNew) {
newTable = &SideTables()[newObj];
} else {
// 如果weak指针变量不需要引用一个新obj，则newTable = nil
newTable = nil;
}
// 加锁操作，防止多线程中竞争冲突
SideTable::lockTwo<haveOld, haveNew>(oldTable, newTable);
if (haveOld && *location != oldObj) {
SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
goto retry;
}
// Prevent a deadlock between the weak reference machinery
// and the +initialize machinery by ensuring that no
// weakly-referenced object has an un-+initialized isa.
if (haveNew && newObj) {
Class cls = newObj->getIsa();
if (cls != previouslyInitializedClass &&
!((objc_class *)cls)->isInitialized()) // 如果cls还没有初始化，先初始化，再尝试设置weak
{
SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
class_initialize(cls, (id)newObj);
// If this class is finished with +initialize then we're good.
// If this class is still running +initialize on this thread
// (i.e. +initialize called storeWeak on an instance of itself)
// then we may proceed but it will appear initializing and
// not yet initialized to the check above.
// Instead set previouslyInitializedClass to recognize it on retry.
previouslyInitializedClass = cls;
goto retry; // 重新获取一遍newObj，这时的newObj应该已经初始化过了
}
}
// 如果weak指针变量之前弱引用过别的对象oldObj，则调用weak_unregister_no_lock，在oldObj的weak_entry_t中移除该weak_ptr地址
if (haveOld) {
weak_unregister_no_lock(&oldTable->weak_table, oldObj, location);
}
// 如果weak指针变量需要弱引用新的对象newObj
if (haveNew) {
// 1 调用weak_register_no_lock方法，weak_register_no_lock会将weak指针变量的地址 记录到newObj对应的weak_entry_t中
newObj = (objc_object *)
weak_register_no_lock(&newTable->weak_table, (id)newObj, location,
crashIfDeallocating ? CrashIfDeallocating : ReturnNilIfDeallocating);
// 2 更新newObj的isa的weakly_referenced bit标志位
if (!newObj->isTaggedPointerOrNil()) {
newObj->setWeaklyReferenced_nolock();
}
// 3 *location 赋值，也就是将weak指针变量直接指向了newObj 这里并没有将newObj的引用计数+1 ， 所以weak引用不会让newObj引用计数+1
*location = (id)newObj; // 也就是例子中 将weakp 指向obj
}
else {
// No new value. The storage is not changed.
}
// 解锁，其他线程可以访问oldTable, newTable了
SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
.
// 返回newObj，此时的newObj与刚传入时相比，weakly-referenced bit位置1
callSetWeaklyReferenced((id)newObj);
return (id)newObj;
}
分析
-
storeWeak方法实际上是接收了5个参数，分别是haveOld、haveNew和crashIfDeallocating ，这三个参数都是以模板的方式传入的，是三个bool类型的参数。 分别表示weak指针之前是否指向了一个弱引用，weak指针是否需要指向一个新的引用，若果被弱引用的对象正在析构，此时再弱引用该对象是否应该crash
-
该方法维护了oldTable 和newTable分别表示旧的引用弱表和新的弱引用表，它们都是SideTable的hash表。
-
对两个表进行加锁操作，防止多线程竞争冲突
-
判断其isa 是否为空，为空则需要进行初始化
-
如果存在旧值，调用 weak_unregister_no_lock 函数清除旧值
-
调用 weak_register_no_lock 函数分配新值 也就是将weak指针自己的地址添加到对象弱引用表中。
-
解锁两个表，其他线程可以访问oldTable, newTable
-
调用setWeaklyReferenced_nolock 方法修改weak指针变量新引用的对象的bit标志位
这个方法中重点是weak_unregister_no_lock 和weak_register_no_lock 这两个方法。而这两个方法都是操作 SideTable结构体 ，那么我们需要先来了解下SideTable 。
数据结构
SideTables
Q：SideTables里面的SideTable 和object是不是1对1关系？
SideTables是一个hash数组，里面存储了SideTable。SideTables的hash键值就是一个对象obj的address。 因此可以说，一个obj，对应了一个SideTable。但是一个SideTable，会对应多个obj。因为SideTable的数量有限，所以会有很多obj共用同一个SideTable
如图
Q:如何从sideTables里找到特定的sideTable?
这就用到了散列函数。runtime是通过下面一个函数来获取到相应的sideTable：
例如：oldTable = &SideTables()[oldObj];
table = &SideTables()[obj];
static StripedMap<SideTable>& SideTables() {
return *reinterpret_cast<StripedMap<SideTable>*>(SideTableBuf);
}
SideTable
struct SideTable {
spinlock_t slock;
RefcountMap refcnts;
weak_table_t weak_table;
}
分析
- spinlock_t slock : 自旋锁，用于上锁/解锁 SideTable。
- refcnts 用来存储OC对象的引用计数的hash表（未开启isa优化才会用，现在的isa 已经不是一个单纯的指针了 Tagged Pointer是苹果最新推出的指针优化，ISA其实并不单单是一个指针
如果该对象不是Tagged Pointer且关闭了Non-pointer，那该对象的引用计数就使用SideTable来存）查看Tagged Pointer 看我这篇文章 - weak_table_t weak_table : 存储对象弱引用指针的hash表，OC中weak功能实现都在这个数据结构中。
Q: 为什么不直接用一张SideTable，而是用SideTables去管理多个SideTable？
SideTable里有一个自旋锁，如果把所有的类都放在同一个SideTable，有任何一个类有改动都会对整个table做操作，并且在操作一个类的同时，操作别的类会被锁住等待，这样会导致操作效率和查询效率都很低。而有多个SideTable的话，操作的都是单个Table，并不会影响其他的table，这就是分离锁。
weak_table_t
struct weak_table_t {
// hash数组，用来存储弱引用对象的相关信息weak_entry_t
weak_entry_t *weak_entries;
//weak_entries的数目 即weak_table_t这个表被多少oc对象共同用
size_t num_entries;
uintptr_t mask;
uintptr_t max_hash_displacement;
};
分析
-
weak_table_t是一个典型的hash结构
-
weak_entries： hash数组，用来存储若干weak_entry_t，每一个弱引用对象的相关信息都被包装成一个weak_entry_t 结构体，数组可动态扩容、缩容
-
num_entries： hash数组中的元素个数
-
mask：hash数组长度-1，会参与hash计算。（注意，这里是hash数组的长度，而不是元素个数。比如，数组长度可能是64，而元素个数仅存了2个
-
max_hash_displacement：可能会发生的hash冲突的最大次数，用于判断是否出现了逻辑错误（hash表中的冲突次数绝不会超过改值）
weak_entry_t
#define WEAK_INLINE_COUNT 4
#define REFERRERS_OUT_OF_LINE 2
struct weak_entry_t {
DisguisedPtr<objc_object> referent; // 被弱引用的对象
// 引用该对象的对象列表，联合。 引用个数小于4，用inline_referrers数组。 引用个数大于4，用动态数组weak_referrer_t *referrers
union {
struct {
weak_referrer_t *referrers; // 弱引用该对象的对象指针地址的hash数组
uintptr_t out_of_line_ness : 2; // 是否使用动态hash数组标记位
uintptr_t num_refs : PTR_MINUS_2; // hash数组中的元素个数
uintptr_t mask; // hash数组长度-1，会参与hash计算。（注意，这里是hash数组的长度，而不是元素个数。比如，数组长度可能是64，而元素个数仅存了2个）素个数）。
uintptr_t max_hash_displacement; // 可能会发生的hash冲突的最大次数，用于判断是否出现了逻辑错误（hash表中的冲突次数绝不会超过改值）
};
struct {
// out_of_line_ness field is low bits of inline_referrers[1]
weak_referrer_t inline_referrers[WEAK_INLINE_COUNT];
};
};
bool out_of_line() {
return (out_of_line_ness == REFERRERS_OUT_OF_LINE);
}
weak_entry_t& operator=(const weak_entry_t& other) {
memcpy(this, &other, sizeof(other));
return *this;
}
weak_entry_t(objc_object *newReferent, objc_object **newReferrer)
: referent(newReferent) // 构造方法，里面初始化了静态数组
{
inline_referrers[0] = newReferrer;
for (int i = 1; i < WEAK_INLINE_COUNT; i++) {
inline_referrers[i] = nil;
}
}
};
分析
-
weak_entry_t的结构也是⼀个hash结构 对象的地址的 hash 化后的数值作为 key，⽤ weak_entry_t 类型的结构体对象作为 value
-
weak_entry_t的结构和weak_table_t很像，同样也是一个hash表，其存储的元素是weak_referrer_t，实质上是弱引用该对象的指针的指针，即 objc_object **new_referrer ， 通过操作指针的指针，就可以使得weak 引用的指针在对象析构后，指向nil。
-
可以看到在weak_entry_t 的结构定义中有联合体，在联合体的内部有定长数组inline_referrers[4]和动态数组weak_referrer_t *referrers两种方式来存储弱引用对象的指针地址。
-
通过out_of_line()这样一个函数方法来判断采用哪种存储方式。当弱引用该对象的指针数目小于等于4时，使用定长数组。当超过4时，会将定长数组中的元素转移到动态数组中，并之后都是用动态数组存储。
到这里我们已经清楚了弱引用表的结构是一个hash结构的表，Key是所指对象的地址，Value是weak_table_t类型的结构体 这个结构体内部也是一个hash结构的表，key是对象地址 Value是一个存放 weak指针自己地址的数组 。那么接下来看看这个弱引用表是怎么维护这些数据的。
weak_register_no_lock 添加弱引用
源码
id weak_register_no_lock(weak_table_t *weak_table, id referent_id,
id *referrer_id, bool crashIfDeallocating)
{
// referent指向是对象地址 referrer指向weak指针自己的地址
objc_object *referent = (objc_object *)referent_id;
objc_object **referrer = (objc_object **)referrer_id;
// 如果referent为nil 或 referent 采用了TaggedPointer计数方式，直接返回，不做任何操作
if (!referent || referent->isTaggedPointer()) return referent_id;
// 确保被引用的对象可用（没有在析构，同时应该支持weak引用）
bool deallocating;
if (!referent->ISA()->hasCustomRR()) {
deallocating = referent->rootIsDeallocating();
}
else {
BOOL (*allowsWeakReference)(objc_object *, SEL) =
(BOOL(*)(objc_object *, SEL))
object_getMethodImplementation((id)referent,
SEL_allowsWeakReference);
if ((IMP)allowsWeakReference == _objc_msgForward) {
return nil;
}
deallocating =
! (*allowsWeakReference)(referent, SEL_allowsWeakReference);
}
// 正在析构的对象，不能够被弱引用
if (deallocating) {
if (crashIfDeallocating) {
_objc_fatal("Cannot form weak reference to instance (%p) of "
"class %s. It is possible that this object was "
"over-released, or is in the process of deallocation.",
(void*)referent, object_getClassName((id)referent));
} else {
return nil;
}
}
// now remember it and where it is being stored
// 在 weak_table中找到referent对应的weak_entry,并将referrer加入到weak_entry中
weak_entry_t *entry;
if ((entry = weak_entry_for_referent(weak_table, referent))) { // 如果能找到weak_entry,则讲referrer插入到weak_entry中
append_referrer(entry, referrer); // 将referrer插入到weak_entry_t的引用数组中
}
else { // 如果找不到，就新建一个
weak_entry_t new_entry(referent, referrer);
weak_grow_maybe(weak_table);
weak_entry_insert(weak_table, &new_entry);
}
// Do not set *referrer. objc_storeWeak() requires that the
// value not change.
return referent_id;
}
这个方法需要传入四个参数，它们代表的意义如下：
- weak_table：weak_table_t 结构类型的弱引用表。
- referent_id：weak指针。
- *referrer_id：weak指针地址。
- crashIfDeallocating ：若果被弱引用的对象正在析构，此时再弱引用该对象是否应该crash。
分析
- 如果referent为nil 或 referent 采用了TaggedPointer计数方式，直接返回，不做任何操作。
- 如果对象正在析构，则抛出异常。
- 如果对象不能被weak引用，直接返回nil。
- 如果对象没有在析构且可以被weak引用，则调用weak_entry_for_referent 方法根据弱引用对象的地址从弱引用表中找到对应的weak_entry，如果能够找到则调用append_referrer 方法向其中插入weak指针自己的地址。否则新建一个weak_entry。
流程图
weak_entry_for_referent
在weak_table中找出referent对应的weak_entry_t
static weak_entry_t *
weak_entry_for_referent(weak_table_t *weak_table, objc_object *referent)
{
assert(referent);
weak_entry_t *weak_entries = weak_table->weak_entries;
if (!weak_entries) return nil;
size_t begin = hash_pointer(referent) & weak_table->mask; // 这里通过 & weak_table->mask的位操作，来确保index不会越界
size_t index = begin;
size_t hash_displacement = 0;
while (weak_table->weak_entries[index].referent != referent) {
index = (index+1) & weak_table->mask;
if (index == begin) bad_weak_table(weak_table->weak_entries); // 触发bad weak table crash
hash_displacement++;
if (hash_displacement > weak_table->max_hash_displacement) { // 当hash冲突超过了可能的max hash 冲突时，说明元素没有在hash表中，返回nil
return nil;
}
}
return &weak_table->weak_entries[index];
}
分析
-
size_t begin = hash_pointer(referent) & weak_table->mask;
来尝试确定hash的初始位置。注意，这里做了& weak_table->mask 位操作来确保index不会越界，这同我们平时用到的取余%操作是一样的功能。只不过这里改用了位操作，提升了效率。 -
然后，就开始对比hash表中的数据是否与目标数据相等
while (weak_table->weak_entries[index].referent != referent)，如果不相等，则index +1， 直到index == begin（绕了一圈）或超过了可能的hash冲突最大值
这是weak_table_t如何进行hash定位的相关操作。
append_referrer
讲referrer添加到weak_entry_t
static void append_referrer(weak_entry_t *entry, objc_object **new_referrer)
{
if (! entry->out_of_line()) { // 如果weak_entry 尚未使用动态数组，走这里
// Try to insert inline.
for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
if (entry->inline_referrers[i] == nil) {
entry->inline_referrers[i] = new_referrer;
return;
}
}
// 如果inline_referrers的位置已经存满了，则要转型为referrers，做动态数组。
// Couldn't insert inline. Allocate out of line.
weak_referrer_t *new_referrers = (weak_referrer_t *)
calloc(WEAK_INLINE_COUNT, sizeof(weak_referrer_t));
// This constructed table is invalid, but grow_refs_and_insert
// will fix it and rehash it.
for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
new_referrers[i] = entry->inline_referrers[I];
}
entry->referrers = new_referrers;
entry->num_refs = WEAK_INLINE_COUNT;
entry->out_of_line_ness = REFERRERS_OUT_OF_LINE;
entry->mask = WEAK_INLINE_COUNT-1;
entry->max_hash_displacement = 0;
}
// 对于动态数组的附加处理：
assert(entry->out_of_line()); // 断言： 此时一定使用的动态数组
if (entry->num_refs >= TABLE_SIZE(entry) * 3/4) { // 如果动态数组中元素个数大于或等于数组位置总空间的3/4，则扩展数组空间为当前长度的一倍
return grow_refs_and_insert(entry, new_referrer); // 扩容，并插入
}
// 如果不需要扩容，直接插入到weak_entry中
// 注意，weak_entry是一个哈希表，key：w_hash_pointer(new_referrer) value: new_referrer
// 细心的人可能注意到了，这里weak_entry_t 的hash算法和 weak_table_t的hash算法是一样的，同时扩容/减容的算法也是一样的
size_t begin = w_hash_pointer(new_referrer) & (entry->mask); // '& (entry->mask)' 确保了 begin的位置只能大于或等于 数组的长度
size_t index = begin; // 初始的hash index
size_t hash_displacement = 0; // 用于记录hash冲突的次数，也就是hash再位移的次数
while (entry->referrers[index] != nil) {
hash_displacement++;
index = (index+1) & entry->mask; // index + 1, 移到下一个位置，再试一次能否插入。（这里要考虑到entry->mask取值，一定是：0x111, 0x1111, 0x11111, ... ，因为数组每次都是*2增长，即8， 16， 32，对应动态数组空间长度-1的mask，也就是前面的取值。）
if (index == begin) bad_weak_table(entry); // index == begin 意味着数组绕了一圈都没有找到合适位置，这时候一定是出了什么问题。
}
if (hash_displacement > entry->max_hash_displacement) { // 记录最大的hash冲突次数, max_hash_displacement意味着: 我们尝试至多max_hash_displacement次，肯定能够找到object对应的hash位置
entry->max_hash_displacement = hash_displacement;
}
// 将ref存入hash数组，同时，更新元素个数num_refs
weak_referrer_t &ref = entry->referrers[index];
ref = new_referrer;
entry->num_refs++;
}
分析
首先确定是使用定长数组还是动态数组，如果是使用定长数组，则直接将weak指针地址添加到数组即可，如果定长数组已经用尽，则需要将定长数组中的元素转存到动态数组中。
grow_refs_and_insert
扩容动态数组添加referrer
__attribute__((noinline, used))
static void grow_refs_and_insert(weak_entry_t *entry,
objc_object **new_referrer)
{
assert(entry->out_of_line());
size_t old_size = TABLE_SIZE(entry);
size_t new_size = old_size ? old_size * 2 : 8;
size_t num_refs = entry->num_refs;
weak_referrer_t *old_refs = entry->referrers;
entry->mask = new_size - 1;
entry->referrers = (weak_referrer_t *)
calloc(TABLE_SIZE(entry), sizeof(weak_referrer_t));
entry->num_refs = 0;
entry->max_hash_displacement = 0;
这里可以看到，旧的数据需要依次转移到新的内存中
for (size_t i = 0; i < old_size && num_refs > 0; i++) {
if (old_refs[i] != nil) {
append_referrer(entry, old_refs[i]); // // 将旧的数据转移到新的动态数组中
num_refs--;
}
}
// Insert
append_referrer(entry, new_referrer);
if (old_refs) free(old_refs); // // 释放旧的内存
}
分析
- 每次扩容是之前的2倍
- 每一次动态数组的扩容，都需要将旧的数据重新插入到新的数组中。
weak_unregister_no_lock移除引用
如果weak指针之前指向了一个弱引用，则会调用weak_unregister_no_lock方法将旧的weak指针地址移除。
void weak_unregister_no_lock(weak_table_t *weak_table, id referent_id, id *referrer_id)
{
objc_object *referent = (objc_object *)referent_id;
objc_object **referrer = (objc_object **)referrer_id;
weak_entry_t *entry;
if (!referent) return;
if ((entry = weak_entry_for_referent(weak_table, referent))) { // 查找到referent所对应的weak_entry_t
remove_referrer(entry, referrer); // 在referent所对应的weak_entry_t的hash数组中，移除referrer
// 移除元素之后， 要检查一下weak_entry_t的hash数组是否已经空了
bool empty = true;
if (entry->out_of_line() && entry->num_refs != 0) {
empty = false;
}
else {
for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
if (entry->inline_referrers[i]) {
empty = false;
break;
}
}
}
if (empty) { // 如果weak_entry_t的hash数组已经空了，则需要将weak_entry_t从weak_table中移除
weak_entry_remove(weak_table, entry);
}
}
分析
- 在weak_table中找出referent对应的weak_entry_t
在weak_entry_t中移除referrer - 移除元素后，判断此时weak_entry_t中是否还有元素 （empty==true？）
如果此时weak_entry_t已经没有元素了，将weak_entry_t从weak_table中移除
remove_referrer
在weak_entry_t中移除referrer
weak_entry_remove
将当前weak_entry_t 从weak_table中移除
static void weak_entry_remove(weak_table_t *weak_table, weak_entry_t *entry)
{
// remove entry
if (entry->out_of_line()) free(entry->referrers);
bzero(entry, sizeof(*entry));
weak_table->num_entries--;
weak_compact_maybe(weak_table);
}
weak_compact_maybe
将weak_table减容
static void weak_compact_maybe(weak_table_t *weak_table)
{
size_t old_size = TABLE_SIZE(weak_table);
// Shrink if larger than 1024 buckets and at most 1/16 full.
if (old_size >= 1024 && old_size / 16 >= weak_table->num_entries) {
weak_resize(weak_table, old_size / 8);
// leaves new table no more than 1/2 full
}
}
weak_resize
static void weak_resize(weak_table_t *weak_table, size_t new_size)
{
size_t old_size = TABLE_SIZE(weak_table);
weak_entry_t *old_entries = weak_table->weak_entries;
weak_entry_t *new_entries = (weak_entry_t *)
calloc(new_size, sizeof(weak_entry_t));
weak_table->mask = new_size - 1;
weak_table->weak_entries = new_entries;
weak_table->max_hash_displacement = 0;
weak_table->num_entries = 0; // restored by weak_entry_insert below
if (old_entries) {
weak_entry_t *entry;
weak_entry_t *end = old_entries + old_size;
for (entry = old_entries; entry < end; entry++) {
if (entry->referent) {
weak_entry_insert(weak_table, entry);
}
}
free(old_entries);
}
}
weak_entry_insert
static void weak_entry_insert(weak_table_t *weak_table, weak_entry_t *new_entry)
{
weak_entry_t *weak_entries = weak_table->weak_entries;
ASSERT(weak_entries != nil);
size_t begin = hash_pointer(new_entry->referent) & (weak_table->mask);
size_t index = begin;
size_t hash_displacement = 0;
while (weak_entries[index].referent != nil) {
index = (index+1) & weak_table->mask;
if (index == begin) bad_weak_table(weak_entries);
hash_displacement++;
}
weak_entries[index] = *new_entry;
weak_table->num_entries++;
if (hash_displacement > weak_table->max_hash_displacement) {
weak_table->max_hash_displacement = hash_displacement;
}
}
流程图：
weak_entry_remove 到 weak_resize 的流程图
callSetWeaklyReferenced
static void callSetWeaklyReferenced(id obj) {
if (!obj)
return;
Class cls = obj->getIsa();
if (slowpath(cls->hasCustomRR() && !object_isClass(obj))) {
ASSERT(((objc_class *)cls)->isInitializing() || ((objc_class *)cls)->isInitialized());
void (*setWeaklyReferenced)(id, SEL) = (void(*)(id, SEL))
class_getMethodImplementation(cls, @selector(_setWeaklyReferenced));
if ((IMP)setWeaklyReferenced != _objc_msgForward) {
(*setWeaklyReferenced)(obj, @selector(_setWeaklyReferenced));
}
}
}
设置当前对象 weakly_referenced = true
到这里为止就是对于一个对象做weak引用时底层做的事情，用weak引用对象后引用计数并不会加1，当对象释放时，所有weak引用它的指针又是如何自动设置为nil的呢？
dealloc
当对象的引用计数为0时，底层会调用_objc_rootDealloc方法对对象进行释放，而在_objc_rootDealloc方法里面会调用rootDealloc方法。如下是rootDealloc方法的代码实现。
inline void
objc_object::rootDealloc()
{
if (isTaggedPointer()) return; // fixme necessary?
if (fastpath(isa.nonpointer &&
!isa.weakly_referenced &&
!isa.has_assoc &&
!isa.has_cxx_dtor &&
!isa.has_sidetable_rc))
{
assert(!sidetable_present());
free(this);
}
else {
object_dispose((id)this);
}
}
分析
- 首先判断对象是否是Tagged Pointer，如果是则直接返回。
- 如果对象是采用了优化的isa计数方式，且同时满足对象没有被weak引用!isa.weakly_referenced、没有关联对象!isa.has_assoc 、没有自定义的C++析构方法!isa.has_cxx_dtor、没有用到SideTable来引用计数!isa.has_sidetable_rc则直接快速释放。
- 如果不能满足2中的条件，则会调用object_dispose 方法。
object_dispose
object_dispose 方法很简单，主要是内部调用了objc_destructInstance方法。
void *objc_destructInstance(id obj)
{
if (obj) {
// Read all of the flags at once for performance.
bool cxx = obj->hasCxxDtor();
bool assoc = obj->hasAssociatedObjects();
// This order is important.
if (cxx) object_cxxDestruct(obj);
if (assoc) _object_remove_assocations(obj);
obj->clearDeallocating();
}
return obj;
}
分析
- 如果有自定义的C++析构方法，则调用C++析构函数。
- 如果有关联对象(比如类别)，则移除关联对象并将其自身从Association Manager的map中移除。
- 调用clearDeallocating 方法清除对象的相关引用。
clearDeallocating
源码
inline void
objc_object::clearDeallocating()
{
if (slowpath(!isa.nonpointer)) {
// Slow path for raw pointer isa.
sidetable_clearDeallocating();
}
else if (slowpath(isa.weakly_referenced || isa.has_sidetable_rc)) {
// Slow path for non-pointer isa with weak refs and/or side table data.
clearDeallocating_slow();
}
assert(!sidetable_present());
}
分析
- 判断对象是否采用了优化isa引用计数，如果没有的话则需要清理对象存储在SideTable中的引用计数数据。
- 如果对象采用了优化isa引用计数，则判断是否有使用SideTable的辅助引用计数(isa.has_sidetable_rc)或者有weak引用(isa.weakly_referenced)，符合这两种情况中一种的，调用clearDeallocating_slow 方法。
clearDeallocating_slow
NEVER_INLINE void
objc_object::clearDeallocating_slow()
{
assert(isa.nonpointer && (isa.weakly_referenced || isa.has_sidetable_rc));
SideTable& table = SideTables()[this]; // 在全局的SideTables中，以this指针为key，找到对应的SideTable
table.lock();
if (isa.weakly_referenced) { // 如果obj被弱引用
weak_clear_no_lock(&table.weak_table, (id)this); // 在SideTable的weak_table中对this进行清理工作
}
if (isa.has_sidetable_rc) { // 如果采用了SideTable做引用计数
table.refcnts.erase(this); // 在SideTable的引用计数中移除this
}
table.unlock();
}
在这里我们关心的是weak_clear_no_lock 方法。这里调用了weak_clear_no_lock来做weak_table的清理工作。
weak_clear_no_lock
源码
void
weak_clear_no_lock(weak_table_t *weak_table, id referent_id)
{
objc_object *referent = (objc_object *)referent_id;
// 找到referent在weak_table中对应的weak_entry_t
weak_entry_t *entry = weak_entry_for_referent(weak_table, referent);
if (entry == nil) {
/// XXX shouldn't happen, but does with mismatched CF/objc
//printf("XXX no entry for clear deallocating %p\n", referent);
return;
}
// zero out references
weak_referrer_t *referrers;
size_t count;
// 找出weak引用referent的weak指针地址数组以及数组长度
if (entry->out_of_line()) {
referrers = entry->referrers;
count = TABLE_SIZE(entry);
}
else {
referrers = entry->inline_referrers;
count = WEAK_INLINE_COUNT;
}
for (size_t i = 0; i < count; ++i) {
objc_object **referrer = referrers[i]; // 取出每个weak 指针变量的地址
if (referrer) {
if (*referrer == referent) { // 如果weak 指针变量确实weak引用了referent，则将weak指针变量设置为nil，这也就是为什么weak 指针会自动设置为nil的原因
*referrer = nil;
}
else if (*referrer) { // 如果所存储的weak 指针变量没有weak 引用referent，这可能是由于runtime代码的逻辑错误引起的，报错
_objc_inform("__weak variable at %p holds %p instead of %p. "
"This is probably incorrect use of "
"objc_storeWeak() and objc_loadWeak(). "
"Break on objc_weak_error to debug.\n",
referrer, (void*)*referrer, (void*)referent);
objc_weak_error();
}
}
}
weak_entry_remove(weak_table, entry); // 由于referent要被释放了，因此referent的weak_entry_t也要移除出weak_table
}
分析
- 移除关联对象
- 清理对象存储在SideTable中的引用计数
- 在全局的SideTables中，以this指针为key，找到对应的SideTable
- isa.weakly_referenced 如果对象被弱引用，在SideTable的weak_table中对this进行清理工作
- referent就是 this 就是弱引用对象
- 找到referent在weak_table中对应的weak_entry_t
- 在entry中找到referent的weak指针地址数组以及数组长度
- 取出每个weak指针变量的地址
- referrer是指针自己的地址 *referrer是对象地址 比较 *referrer ==referent 如果weak指针变量确实weak引用了referent，则将referrer指针变量=nil
寻址扩容
源码
weak_entry_t *entry;
// 如果能找到weak_entry,则讲referrer插入到weak_entry中
if ((entry = weak_entry_for_referent(weak_table, referent))) {
// 将referrer插入到weak_entry_t的引用数组中
append_referrer(entry, referrer); }
else { // 如果找不到，就新建一个
weak_entry_t new_entry(referent, referrer);
weak_grow_maybe(weak_table);
weak_entry_insert(weak_table, &new_entry);
}
往weak_table中插入weak_entry的逻辑在weak_entry_insert(…)中：
index = hash & (length-1)
在这个方法中，先用对象地址(referent)求hash，再和mask按位与计算的得到起始索引，mask的值为数组长度-1，这样求索引的值必然在数组的范围内。
比如： 某个对象的地址求得的hash为0x6a9f2be7，当前数组长度为16，mask为15（0b1111），则 0x6a9f2be7 & ob1111 = 0b0111（7），那么begin索引值为7。
那么，当在初始索引处已经被占用了，也就是发生了hash冲突，则index+1继续往后寻找，直到找到为止，这种处理hash冲突的方法叫做开放寻址法。
通过对象地址查找weak_entry的时候也是大同小异，具体逻辑在weak_entry_for_referent(…)中，这边不再赘述。
weak_entry_t *entry;
if ((entry = weak_entry_for_referent(weak_table, referent))) { // 如果能找到weak_entry,则讲referrer插入到weak_entry中
append_referrer(entry, referrer); // 将referrer插入到weak_entry_t的引用数组中
}
weak主要查找流程
寻找 SideTable
newTable = &SideTables()[newObj];
寻找 weak_table
&newTable->weak_table
寻找weak_entry_t
while (weak_table->weak_entries[index].referent != referent) {
index = (index+1) & weak_table->mask;
}
return &weak_table->weak_entries[index];
寻找weak_entry_t下 所有的 weak 指针
referrer = entry->inline_referrers[i]
概括一下weak引用的存储结构：
1、SideTable持有的weak_table_t，可以通过对象地址作为key找到， 一个SideTable多个对象用。
2、weak_table_t内部存放weak_entry_t类型的数组，一个对象对应一个weak_entry_t，一个weak_table_t多个对象用。
3、weak_entry_t中实际存放着被引用的对象和引用它的所有weak指针的地址。
weak面试问题
SideTable怎么从SideTables取出来的？
// StripedMap is a map of void* -> T, sized appropriately
StripedMap 是一个以void *为hash key， T为vaule的hash表
hash定位的算法如下
static unsigned int indexForPointer(const void *p) {
uintptr_t addr = reinterpret_cast<uintptr_t>(p);
return ((addr >> 4) ^ (addr >> 9)) % StripeCount;
}
把地址指针右移4位异或地址指针右移9位，为什么这么做，也不用关心。我们只要关心重点是最后的值要取余StripeCount，来防止index越界就好。
SideTable能不能被析构？
// 构造函数
SideTable() {
memset(&weak_table, 0, sizeof(weak_table));
}
//析构函数(看看函数体，苹果设计的SideTable其实不希望被析构，不然会引起fatal 错误)
~SideTable() {
_objc_fatal("Do not delete SideTable.");
}
通过析构函数可以知道，SideTable不能被析构。
&SideTables()[oldObj]这是什么?
实现了一个类 StripedMap 重载了[]操作符
public:
T& operator[] (const void *p) {
return array[indexForPointer(p)].value;
}
weak_table 是公用的吗？
weak_table_t weak_table 用来存储OC对象弱引用的相关信息。我们知道，SideTables一共只有64个节点，而在我们的APP中，一般都会不只有64个对象，因此，多个对象一定会重用同一个SideTable节点，也就是说，一个weak_table会存储多个对象的弱引用信息。因此在一个SideTable中，又会通过weak_table作为hash表再次分散存储每一个对象的弱引用信息。
如图
weak_table弱引用表谁是key 谁是value 怎么构成哈希表的？
使用不定类型对象的地址作为key ，用 weak_entry_t 类型结构体对象作为 value
weak_entry_t 的结构中 weak_referrer_t是什么？
weak_referrer_t 是二维 objc_object 的别名 是每一个weak指针自己的地址
NSObject *obj = [[NSObject alloc] init];
__weak NSObject *weakp = obj;
&weakp 就是一个 weak_referrer_t 对象 ，被装在静态数组或者动态数组中 ，通过 weak_entry_t 可以获取这个数组
objc_object *referent 和 referrer 都是什么？
referent 是对象地址
referrer 是weak指针自己的地址
我们要结合remove_referrer这个函数来理解
for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
if (entry->inline_referrers[i] == old_referrer) {
entry->inline_referrers[i] = nil;
return;
}
}
如图
// p对象
NSObject *p = [[NSObject alloc] init];
__weak NSObject *p1 = p;
referent_id 就是 p referrer_id 就是 &p1
objc_object *referent = (objc_object *)referent_id;
objc_object **referrer = (objc_object **)referrer_id;
referent 就是 p *referrer 就是 p1
*referrer=nil 也就是 p1=nil
weak_unregister_no_lock中 为什么不把referrer设置为nil？
这里不会设置 *referrer = nil，因为 objc_storeWeak() 函数会需要该指针
现在p和p2的弱引用个数分别是几？
NSObject *p = [[NSObject alloc] init];
__weak NSObject *weakp = p;
p对象弱引用个数是1
NSObject *p2 = [[NSObject alloc] init];
weakp = p2;
p对象弱引用个数是0 p2 对象弱引用个数是1
为什么不直接用一张SideTable，而是用SideTables去管理多个SideTable？？
SideTable里有一个自旋锁，如果把所有的类都放在同一个SideTable，有任何一个类有改动都会对整个table做操作，并且在操作一个类的同时，操作别的类会被锁住等待，这样会导致操作效率和查询效率都很低。而有多个SideTable的话，操作的都是单个Table，并不会影响其他的table，这就是分离锁
runtime如何实现weak变量的自动置nil？
runtime 对注册的类会进行布局，对于 weak 修饰的对象会放入一个 hash 表中。 用 weak 指向的对象内存地址作为key，当此对象的引用计数为0的时候会 dealloc，假如 weak 指向的对象内存地址是a，那么就会以a为键， 在这个 weak表中搜索，找到所有以a为键的 weak 对象，从而设置为 nil。
更细一点的回答：
1.初始化时：runtime会调用objc_initWeak函数，初始化一个新的weak指针指向对象的地址。
2.添加引用时：objc_initWeak函数会调用objc_storeWeak() 函数， objc_storeWeak()的作用是更新指针指向，创建对应的弱引用表。
3.释放时,调用clearDeallocating函数。clearDeallocating函数首先根据对象地址获取所有weak指针地址的数组，然后遍历这个数组把其中的数据设为nil，最后把这个entry从weak表中删除，最后清理对象的记录。
总结
- weak的原理在于底层维护了一张weak_table_t结构的hash表，key是对象的地址，value是weak指针的地址数组（其实是一个weak_entry_t结构体，里面有一个数组，数组里面存放的是全是weak指针变量自己的地址）。
- weak 关键字的作用是弱引用，所引用对象的计数器不会加1，并在引用对象被释放的时候自动被设置为 nil。
- 对象释放时，调用clearDeallocating函数根据对象地址获取所有weak指针地址的数组，然后遍历这个数组把其中的数据设为nil，最后把这个entry从weak表中删除。
- ⼀个weak引⽤的处理涉及各种查表、添加与删除操作，还是有⼀定消耗的。所以如果⼤量使⽤__weak变量的话，会对性能造成⼀定的影响
扫一扫
8124
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
